1000 R1=(360/33)/57.2958: R2=(360/28)/57.2958: R3=(360/23)/57.2958
1010 PRINT CHR$(26):PRINT
1020 PRINT "******************** BIO-RHYTHM ********************"
1030 PRINT:PRINT
1040 PRINT "TO GENERATE AND PRINT YOUR BIO-RHYTHM CHART:"
1050 PRINT
1055 PRINT "     - Ready your printer to accept 60 lines/page."
1060 PRINT "     - Enter the subject's birthday, a comma and the "
1070 PRINT "         current date, both in YYMMDD format."
1080 PRINT "     - Enter the number of days you want to cover."
1090 PRINT "     - Enter the name of the subject."
1100 PRINT:PRINT:PRINT
1110 DATA 0,31,59,90,120,151,181,212,243,273,304,334
1120 DATA 365
1130 DIM L$(50)
1140 GOTO 1180
1150 INPUT "Do you want another Bio-rhythm? (Y/y/N/n)",ANS$
1160 IF LEFT$(ANS$,1)="N" OR LEFT$(ANS$,1)="n" THEN END
1170 PRINT CHR$(26);:PRINT:PRINT:PRINT
1180 RESTORE
1190 INPUT"Enter birth date - comma - study date (YYMMDD,YYMMDD): ",D1,D2
1200 IF D1>D2 THEN PRINT" INVALID DATES: ";D1;D2: GOTO 1190
1210 P1=0: J6=1: D9=D2
1220 PRINT:INPUT"Enter duration of study (in days): ",J5
1230 PRINT:INPUT"Enter subject's full name: ",A$:PRINT
1240 GOSUB 1840
1250 X1=D1: GOSUB 1300
1260 Y1=X2: M1=X3: D1=X4
1270 X1=D2: GOSUB 1300
1280 Y2=X2: M2=X3: D2=X4
1290 GOSUB 1320
1300 X2=INT(X1/10000): X3=INT(X1/100)-(X2*100): X4=X1-((X3*100)+(X2*10000))
1310 RETURN
1320 D4=(INT((Y2-1)*365.25)-INT((Y1-1)*365.25))
1330 FOR I=1 TO M1: READ J1: NEXT I
1340 RESTORE
1350 FOR I =1 TO M2: READ J2: NEXT I
1360 J1=J1+D1: J2=J2+D2: L1=(Y1/4)-(INT(Y1/4))
1370 IF L1=0 THEN L1=1: GOTO 1390
1380 L1=0
1390 L2=(Y2/4)-(INT(Y2/4))
1400 IF L2=0 THEN L2=1:GOTO 1420
1410 L2=0
1420 IF M1>2 THEN J1=J1+L1
1430 IF M2>2 THEN J2=J2+L2
1440 D4=D4+J2-J1: D1=(D4-(INT(D4/33)*33))
1450 D2=(D4-(INT(D4/28)*28)): D3=(D4-(INT(D4/23)*23))
1460 FOR L3=1 TO 46 
1470 FOR I= 1 TO 50: L$(I)=" ": NEXT I
1480 X=SIN(R1*D1): Y=SIN(R2*D2): Z=SIN(R3*D3)
1490 L$(X*17+25)="M": L$(Y*20+25)="E": L$(Z*23+25)="P"
1500 LPRINT":  ";
1510 FOR I=1 TO 50: IF L$(25)=" " THEN L$(25)="|"
1515 LPRINT L$(I);: NEXT I
1520 LPRINT": ";
1530 GOSUB 1710: LPRINT D5;" :   ";
1535 IF D3= 0 THEN C=1:LPRINT TAB(69) "P";
1545 IF D3=12 THEN C=1:LPRINT TAB(69) "P";
1560 IF D2= 0 THEN C=1:LPRINT TAB(70) "E";
1570 IF D2=14 THEN C=1:LPRINT TAB(70) "E";
1575 IF D1= 0 THEN C=1:LPRINT TAB(71) "M";
1585 IF D1=16 THEN C=1:LPRINT TAB(71) "M";
1600 LPRINT TAB(76)":"
1610 IF C=1 THEN C=0
1620 D1=D1+1: D2=D2+1: D3=D3+1
1630 IF D1=33 THEN D1=0
1640 IF D2=28 THEN D2=0
1650 IF D3=23 THEN D3=0
1660 J2=J2+1: J6=J6+1: IF J5<J6 GOTO 1700
1670 NEXT L3
1680 P1=P1+1: GOSUB 1990
1690 LPRINT:LPRINT: GOSUB 1840: GOTO 1460
1700 P1=P1+1: GOSUB 1990: PRINT: GOTO 1150
1710 RESTORE
1720 FOR I =1 TO 13: J4=J3: READ J3
1730 IF J2>59 THEN J3=J3+L2
1740 IF J2<=J3 GOTO 1800
1750 NEXT I
1760 Y2=Y2+1: L2=(Y2/4)-(INT(Y2/4))
1770 IF L2=0 THEN L2=1:GOTO 1790
1780 L2=0
1790 J2=J2-365: GOTO 1710
1800 M2=I-1: D6=J2-J4
1810 IF J2=60 THEN D6=D6+L2
1820 D5=Y2*10000+(M2*100)+D6: RETURN
1830 REM --------------------------------
1840 FOR I=1 TO 76:LPRINT"-";:NEXT I:LPRINT
1850 LPRINT":  Elmer's Computerized Study of Biorhythms for ";A$;
1860 GOSUB 1980
1870 LPRINT":  Birth date:";D1;
1880 LPRINT "   Study Date:";D9;"   Duration:";J5;"days ";
1890 GOSUB 1980
1900 FOR I=1 TO 76:LPRINT"-";:NEXT I:LPRINT
1910 LPRINT":  P = PHYSICAL      E = EMOTIONAL       M = MENTAL  :";
1915 LPRINT"   DATE   : CRITICAL :"
1920 REM LPRINT TAB(76)":"
1930 FOR I=1 TO 53:LPRINT"-";:NEXT I:LPRINT":(YY/MM/DD):   FOR?   :"
1940 LPRINT":           LOW            :            HIGH         :";
1950 LPRINT"          :          :"
1960 FOR I=1 TO 76:LPRINT"-";:NEXT I:LPRINT
1970 RETURN
1980 LPRINT TAB(76)":": RETURN
1990 FOR I=1 TO 76:LPRINT"-";:NEXT I:LPRINT
2000 LPRINT":  HIGH    -    Days of full vitality, efficiency, ";  
2010 LPRINT"and high endurance";  
2020 GOSUB 1980
2030 LPRINT":  LOW     -    Days of reduced efficiency, recuperation, ";
2040 LPRINT"tiring easily";
2050 GOSUB 1980
2060 LPRINT":  CRITICAL  -  Days to avoid situations that might ";  
2070 LPRINT"lead to trouble";  
2080 GOSUB 1980
2090 FOR I=1 TO 76:LPRINT"-";:NEXT I:LPRINT
2100 LPRINT TAB(34);"PAGE ";P1
2110 RETURN
ead to trouble";  
2080 GOSUB 1980
2090 FOR I=1 TO 76:LPRINT"-";:NEXT I:LPRINT
2100