100 REM Program: OKI92M.BAS    In MBASIC    By Tom Sarbeck    May, 1985
110 REM
120 REM Controls print options of the OKI92/93 printer.  Each selection
130 REM (1 thru 9) sends one control to the printer.  Some processors
140 REM may send their own controls and override those selected here.
150 REM
160 REM var branch=integer
170 PRINT CHR$(26)
180 PRINT"Enter the number of the printing feature you desire.  You may"
190 PRINT"enter more than one control (e.g., 1 <CR> 4 <CR> 6 <CR> 0 <CR>"
200 PRINT"to set corresponding mode print at 3 CPI for a max 48 CPL)."
210 PRINT
220 PRINT" 0  -  Exit As You Have Set It"
230 PRINT" 1  -  Correspondence Mode"
240 PRINT" 2  -  Data Processing Mode (Default)"
250 PRINT
260 PRINT" 3  -  Pica type (10 CPI, 80 CPL.  Default)"
270 PRINT" 4  -  Elite type (12 CPI, 96 CPL)"
280 PRINT" 5  -  Condensed type (17.1 CPI) [dp mode only]"
290 PRINT" 6  -  Double width (Half the current CPI/CPL)"
300 PRINT"      (Caution: this halves the Characters per Line)"
310 PRINT
320 PRINT" 7  -  Six lines per vertical inch (Default)"
330 PRINT" 8  -  Eight lines per vertical inch"
340 PRINT
350 PRINT" 9  -  Print a four-line test, max 29 char per line"
360 PRINT">9  -  Reset to default and exit"
370 PRINT
380 INPUT "       Your selection";BRANCH
390 IF BRANCH < 1 THEN END
400 IF BRANCH < 10 THEN GOTO 450
410 REM 				Reset to default and end
420 LPRINT CHR$(24);
430 END
440 REM        				Branch
450 ON BRANCH GOTO 470,500,530,560,590,620,650,680,700
460 REM 				Correspondence mode
470 LPRINT CHR$(27);CHR$(49);
480 GOTO 170
490 REM 				Data processing mode
500 LPRINT CHR$(27);CHR$(48);
510 GOTO 170
520 REM 				Ten CPHI
530 LPRINT CHR$(30);
540 GOTO 170
550 REM 				Twelve CPHI
560 LPRINT CHR$(28);
570 GOTO 170
580 REM        				Seventeen CPHI
590 LPRINT CHR$(29);
600 GOTO 170
610 REM        				Double width
620 LPRINT CHR$(31);
630 GOTO 170
640 REM 				Six LPVI
650 LPRINT CHR$(27);CHR$(54);
660 GOTO 170
670 REM        				Eight LPVI
680 LPRINT CHR$(27);CHR$(56);
690 GOTO 170
700 LPRINT "Mary had a little lamb;"
710 LPRINT "Its fleece was white as snow."
720 LPRINT "Everywhere that Mary went"
730 LPRINT "That damn lamb left a pile."
740 GOTO 170
750 END
 was white as snow."
720 LPRINT "Eve