;************************************************************************
;									*
;COPYRIGHT 1982								*
;GTEK, INC.								*
;307-D COLEMAN AVENUE							*
;P.O. BOX 289								*
;WAVELAND, MS. 39576							*
;									*
;THIS SOURCE CODE IS THE PROPERTY OF GTEK, INC.				*
;WHAT YOU HAVE PURCHASED IS THE RIGHT TO USE THE SOFTWARE		*
;ANY UNAUTHORIZED DISTRIBUTION OF THIS SOFTWARE IS STRICTLY FORBIDDEN	*
;									*
;************************************************************************
;
;
;PROGRAM NAME 	IOB.ASM
;BY		BILL GROVES	9/10/82
;

IOBYTE	EQU	3		;LOCATION OF IOBYTE
; POSSIBLE CONSOLE ASSIGNMENTS
TTY	EQU	00H		;BITS 1,0 = 00
CRT	EQU	01H		;BITS 1,0 = 01
BAT	EQU	02H		;BITS 1,0 = 10
UC1	EQU	03H		;BITS 1,0 = 11


;
;THE FOLLOWING ROUTINES ARE THE SERIAL INTERFACE DRIVERS FOR THE PROGRAMMER
;BINCHK MUST RETURN 00 IN THE ACCUMULATOR IF NOTHING HAS BEEN RECEIVED
;	OR IF A CHARACTER HAS BEEN RECEIVED, THEN RETURN IT IN THE
;	ACCUMULATOR.
;BOUT SIMPLY OUTPUTS THE ACCUMULATOR TO THE PROGRAMMER









;******* MAKE THE FOLLOWING ASSIGNMENT FOR YOUR SYSTEM *****
PPIO	EQU	CRT	;				   *
;***********************************************************


	ORG	100H		;START OF TPA
;THE FOLLOWING FOUR VECTORS MUST BE LEFT IN THIS SOURCE
	JMP	START
	JMP	INIT		;COMPUTER INITIALZATION FOR BAUD,UART,ETC
	JMP	BINCHK
	JMP	BOUT

START:	LXI	H,1000		;TIMOUT VALUE FOR BINCHK
	JMP	203H		;PROGRAM CONTINUES AT 203


BINCHK:	;RETURN A CHAR OR A=00 IF NOTHING AVAILABLE
	LDA	IOBYTE
	STA	IOBSAV
	ANI	0FCH		;CLEAR BITS 0 AND 1
	ORI	PPIO		;SET CONSOLE TO PROGRAMMER PORT
	STA	IOBYTE
	MVI	A,0FFH		;INPUT FUNCTION
	CALL	DCIOF
BIORET:	PUSH	PSW
	LDA	IOBSAV
	STA	IOBYTE		;RESTORE CONSOLE
	POP	PSW
	RET

BOUT:	;ENTER WITH CHAR IN A
	PUSH PSW
	LDA	IOBYTE
	STA	IOBSAV
	ANI	0FCH		;CLEAR CONSOLE FIELD
	ORI	PPIO		;ASSIGN PROGRAMMER TO CONSOLE
	STA	IOBYTE
	POP	PSW
	CALL	DCIOF
	JMP	BIORET		;RESTORE IOBYTE AND RETURN

IOBSAV:	DS	1		;SAVE LOCATION FOR IOBYTE
DCIOF:	PUSH	B
	PUSH	D
	PUSH	H
	MOV	E,A
	MVI	C,6
	CALL	5
	POP	H
	POP	D
	POP	B
	ORA	A		;SET FLAGS
	RET


INIT:	RET			;NO INITILIZATION KNOWN