10 REM ***********************************************************************
20 REM *                                                                     *
30 REM *                   INV101 NEW SYSTEM STARTUP                         *
40 REM *                   CERBERUS ASSOCIATES                               *
50 REM *                                                                     *
60 REM ***********************************************************************
70 REM
80 REM THIS PROGRAM ESTABLISHES THE FILES USED IN THE INVENTORY SYSTEM. INV101
90 REM MUST BE RUN PRIOR TO ANY OTHER INVENTORY PROGRAMS. INV101 IS RUN ONLY
100 REM ONCE DURING THE LIFE OF A SYSTEM
110 REM
120 REM SEE THE SYSTEMS MANUAL FOR DETAILED INSTRUCTIONS ON MODIFYING THE
130 REM INVENTORY PROGRAMS IF DESIRED
140 REM
1000 REM THIS SECTION OF THE PROGRAM CREATES THE FILES TO BE USED IN ALL
1010 REM INVENTORY SYSTEM PROGRAMS
1100 INVMAS$="INV.MAS"
1110 INVTRS$="INV.TRS"
1120 NARCTR$="NAR.CTR"
1130 FILE INVMAS$(192)
1140 FILE INVTRS$(64)
1150 FILE NARCTR$(16)
1200 REM
2000 REM THIS SECTION OF THE PROGRAM CREATES THE INVENTORY MASTER FILE WITH
2010 REM DATA INPUT FROM THE KEYBOARD
2020 REM INVENTORY MASTER FILE FIELD DESCRIPTIONS ARE ON THE FILE INVMAS.DES
2030 INVDES$="INVMAS.DES"
2040 FILE INVDES$(32)
2050 REM
2060 DIM INV$(24)
2070 REM
2080 NARINV=1
2090 NARTRS=1
2100 REM ENTER THE 24 ITEMS FOR EACH INVENTORY PART
2110  FOR I=1 TO 24
2120 READ #4,I;DES$
2130 PRINT "ENTER ",DES$
2140 INPUT LINE INV$(I)
2145 PRINT " "
2150 NEXT I
2160 REM
2170 REM THIS SECTION FORMATS THE DATA TO WRITE TO THE INVENTORY FILE
2180 FLD01$=RIGHT$("            "+INV$(1),12)
2190 FLD02$=RIGHT$("                                "+INV$(2),32)
2200 FLD03$=RIGHT$("  "+INV$(3),2)
2210 FLD04$=RIGHT$("  "+INV$(4),2)
2220 FLD05$=RIGHT$("       "+INV$(5),7)
2230 FLD06$=RIGHT$("       "+INV$(6),7)
2240 FLD07$=RIGHT$("      "+INV$(7),6)
2250 FLD08$=RIGHT$("      "+INV$(8),6)
2260 FLD09$=RIGHT$("      "+INV$(9),6)
2270 FLD10$=RIGHT$("      "+INV$(10),6)
2280 FLD11$=RIGHT$("      "+INV$(11),6)
2290 FLD12$=RIGHT$("      "+INV$(12),6)
2300 FLD13$=RIGHT$("    "+INV$(13),4)
2310 FLD14$=RIGHT$(" "+INV$(14),1)
2320 FLD15$=RIGHT$("      "+INV$(15),6)
2340 FLD16$=RIGHT$("      "+INV$(16),6)
2350 FLD17$=RIGHT$("      "+INV$(17),6)
2360 FLD18$=RIGHT$("      "+INV$(18),6)
2370 FLD19$=RIGHT$("      "+INV$(19),6)
2380 FLD20$=RIGHT$("      "+INV$(20),6)
2390 FLD21$=RIGHT$("  "+INV$(21),2)
2400 FLD22$=RIGHT$("        "+INV$(22),8)
2410 FLD23$=RIGHT$("        "+INV$(23),8)
2420 FLD24$=RIGHT$("      "+INV$(24),6)
2430 REM
2440 REM DATA IS FORMATTED NOW WRITE TO DISC
2450 REM
2460 PRINT USING "&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&";#1;\
     FLD01$,FLD02$,FLD03$,FLD04$,FLD05$,FLD06$,FLD07$,FLD08$,FLD09$,FLD10$,\
     FLD11$,FLD12$,FLD13$,FLD14$,FLD15$,FLD16$,FLD17$,FLD18$,FLD19$,FLD20$,\
     FLD21$,FLD22$,FLD23$,FLD24$
2500 NARINV=NARINV+1
2510 PRINT #3,1;NARINV,NARTRS
2600 INPUT "MORE INVENTORY ENTER Y OR N    ";MORE$
2610 IF MORE$="Y" THEN 2100
2620 IF MORE$="N" THEN 9999
2630 PRINT "INCORRECT INPUT"
2640 GOTO 2600
9999 END