10 REM ***********************************************************************
20 REM *                                                                     *
30 REM *                      INV103 NEW YEAR/MONTH                          *
40 REM *                      CERBERUS ASSOCIATES                            *
50 REM *                                                                     *
60 REM ***********************************************************************
70 REM 
80 REM THIS PROGRAM IS USED TO CLEAR THE YEAR OR MONTH TO DATE TOTALS AT THE
90 REM START OF A NEW ACCOUNTING PERIOD
1000 REM OPEN FILES USED BY THE PROGRAM
1010 INVMAS$="INV.MAS"
1020 NARCTR$="NAR.CTR"
1100 FILE INVMAS$(192)
1110 FILE NARCTR$(16)
1200 ZERO$="00000000"
1210 SP$="                                "
1220 ZERD$="000000.00"
1500 READ #2,1;NARINV,NARTRS
1510 IF NARTRS=1 THEN 2000
1520 REM TRANSACTION FILE IS NOT EMPTY SHOULD IT BE?
1530 PRINT "THERE ARE TRANSACTIONS IN THE TRANSACTION FILE "
1540 INPUT "DO YOU WANT TO PROCEDE WITH NEW YEAR/MONTH ";ANS$
1550 IF ANS$="YES" THEN 2000
1560 IF ANS$="NO" THEN 9999
1570 PRINT "INCORRECT INPUT ENTER YES OR NO "
1580 GOTO 1530
2000 INPUT "ENTER MONTH OR YEAR ";TIME$
2010 IF TIME$="MONTH" THEN 3000
2020 IF TIME$="YEAR" THEN 4000
2030 PRINT "INCORRECT INPUT ENTER MONTH OR YEAR "
2040 GOTO 2000
3000 REM NEW MONTH
3010 INPUT "NEW MONTH YES OR NO ";ANS$
3020 IF ANS$="NO" THEN 5000
3030 IF ANS$="YES" THEN 3100
3040 REM TRY AGAIN
3050 PRINT "INCORRECT INPUT ENTER YES OR NO "
3060 GOTO 3000
3100 IF END #1 THEN 3900
3110 PRINT "NEW MONTH"
3120 PRINT " "
3130 PRINT "PART NUMBER         MTD ISSUE           MTD RECEIPT "
3140 FOR I=1 TO NARINV
3150 READ #1,I;FLD01$,FLD02$,FLD03$,FLD04$,FLD05$,FLD06$,FLD07$,FLD08$,\
     FLD09$,FLD10$,FLD11$,FLD12$,FLD13$,FLD14$,FLD15$,FLD16$,FLD17$,FLD18$,\
     FLD19$,FLD20$,FLD21$,FLD22$,FLD23$,FLD24$
3160 PRINT FLD01$,FLD10$,FLD18$
3170 FLD10$=ZERO$
3180 FLD18$=ZERO$
3200 GOSUB 6000
3210 NEXT I
3900 PRINT " "
3910 PRINT "ALL MTD TOTALS HAVE BEEN ZEROED "
3920 GOTO 9999
4000 REM NEW YEAR
4010 INPUT "NEW YEAR YES OR NO ";ANS$
4020 IF ANS$="YES" THEN 4100
4030 IF ANS$="NO" THEN 5000
4040 REM TRY AGAIN
4050 PRINT "INCORRECT INPUT ENTER YES OR NO "
4060 GOTO 4000
4100 IF END #1 THEN 4900
4110 PRINT "NEW YEAR "
4120 PRINT " "
4140 FOR I=1 TO NARINV
4150 READ #1,I;FLD01$,FLD02$,FLD03$,FLD04$,FLD05$,FLD06$,FLD07$,FLD08$,\
     FLD09$,FLD10$,FLD11$,FLD12$,FLD13$,FLD14$,FLD15$,FLD16$,FLD17$,FLD18$,\
     FLD19$,FLD20$,FLD21$,FLD22$,FLD23$,FLD24$
4160 PRINT FLD01$,FLD09$,FLD10$,FLD16$,FLD17$,FLD18$,FLD22$,FLD23$
4170 FLD09$=ZERO$
4180 FLD10$=ZERO$
4190 FLD16$=ZERO$
4200 FLD17$=ZERO$
4210 FLD18$=ZERO$
4220 FLD22$=ZERD$
4230 FLD23$=ZERD$
4240 GOSUB 6000
4250 NEXT I
4900 PRINT " "
4910 PRINT "ALL YTD AND MTD TOTALS HAVE BEEN ZEROED "
4920 GOTO 9999
5000 PRINT "DO YOU WANT TO END THE PROGRAM "
5010 INPUT "ENTER YES OR NO ";ANS$
5020 IF ANS$="YES" THEN 9999
5030 GOTO 2000
6000 REM FORMAT THE DATA AND WRITE TO DISC
6010 FLD01$=RIGHT$(SP$+FLD01$,12)
6020 FLD02$=RIGHT$(SP$+FLD02$,32)
6030 FLD03$=RIGHT$(SP$+FLD03$,2)
6040 FLD04$=RIGHT$(SP$+FLD04$,2)
6050 FLD05$=RIGHT$(SP$+FLD05$,7)
6060 FLD06$=RIGHT$(SP$+FLD06$,7)
6070 FLD07$=RIGHT$(SP$+FLD07$,6)
6080 FLD08$=RIGHT$(SP$+FLD08$,6)
6090 FLD09$=RIGHT$(SP$+FLD09$,6)
6100 FLD10$=RIGHT$(SP$+FLD10$,6)
6110 FLD11$=RIGHT$(SP$+FLD11$,6)
6120 FLD12$=RIGHT$(SP$+FLD12$,6)
6130 FLD13$=RIGHT$(SP$+FLD13$,4)
6140 FLD14$=RIGHT$(SP$+FLD14$,1)
6150 FLD15$=RIGHT$(SP$+FLD15$,6)
6160 FLD16$=RIGHT$(SP$+FLD16$,6)
6170 FLD17$=RIGHT$(SP$+FLD17$,6)
6180 FLD18$=RIGHT$(SP$+FLD18$,6)
6190 FLD19$=RIGHT$(SP$+FLD19$,6)
6200 FLD20$=RIGHT$(SP$+FLD20$,6)
6210 FLD21$=RIGHT$(SP$+FLD21$,2)
6230 FLD22$=RIGHT$(SP$+FLD22$,8)
6240 FLD23$=RIGHT$(SP$+FLD23$,8)
6250 FLD24$=RIGHT$(SP$+FLD24$,6)
6260 REM DATA IS FORMATTED WRITE TO DISC
6300 PRINT USING "&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&,&";#1,I;\
     FLD01$,FLD02$,FLD03$,FLD04$,FLD05$,FLD06$,FLD07$,FLD08$,FLD09$,FLD10$,\
     FLD11$,FLD12$,FLD13$,FLD14$,FLD15$,FLD16$,FLD17$,FLD18$,FLD19$,FLD20$,\
     FLD21$,FLD22$,FLD23$,FLD24$
6310 RETURN
9999 END