10 REM *********************************************************************
20 REM *                                                                   *
30 REM *                INV201 ENTER TRANSACTIONS                          *
40 REM *                CERBERUS ASSOCIATES                                *
50 REM ******                                                              *
60 REM *********************************************************************
70 REM
80 REM THIS PROGRAM ACCEPTS KEYBOARD DATA AND BUILDS THE INVENTORY
90 REM TRANSACTION FILE
1000 REM THIS SECTION OPENS THE FILES USED BY THE PROGRAM
1010 INVTRS$="INV.TRS"
1020 NARCTR$="NAR.CTR"
1030 FILE INVTRS$(64)
1040 FILE NARCTR$(16)
1050 REM INV.TRS IS FILE #1 AND NAR.CTR IS FILE #2
2000 REM THIS SECTION DOES THE WORK
2010 READ #2,1;NARINV,NARTRS
2020 INPUT "TRANSACTION CODE  ";TC$
2030 REM CHECK IF VALID
2040 IF TC$="E" THEN 9999
2050 IF TC$="O" THEN 2300
2060 IF TC$="A" THEN 2300
2070 IF TC$="X" THEN 2300
2080 IF TC$="I" THEN 2300
2090 IF TC$="R" THEN 2300
2100 PRINT "YOU HAVE ENTERED AN INVALID TRANSACTION CODE"
2110 PRINT "ENTER ONE OF THE FOLLOWING"
2120 PRINT " "
2130 PRINT "E FOR END-NO MORE TRANSACTIONS TO BE ENTERED"
2140 PRINT "O FOR ORDERED"
2150 PRINT "R FOR RECEIVED"
2160 PRINT "X FOR RETURNED"
2170 PRINT "A FOR ALLOCATED"
2180 PRINT "I FOR ISSUED"
2190 GOTO 2020
2300 INPUT "ENTER PART NUMBER     ";TRS01$
2310 INPUT "ENTER LOCATION        ";TRS02$
2320 INPUT "ENTER QUANTITY        ";TRS03$
2340 INPUT "ENTER DATE            ";TRS04$
2350 IF TC$="O" THEN 2600
2360 IF TC$="R" THEN 2400
2370 INPUT "ENTER CUSTOMER NUMBER  ";TRS05$
2380 GOTO 2450
2400 INPUT "ENTER VENDOR NUMBER    ";TRS05$
2410 INPUT "COST PER UNIT          ";TRS06$
2420 INPUT "PREVIOUSLY ORDERED ENTER Y OR N   ";TRS07$
2430 GOTO 2600
2450 REM
2460 IF TC$="A" THEN 2600
2470 INPUT "ENTER PRICE PER UNIT   ";TRS06$
2480 IF TC$="X" THEN 2600
2490 INPUT "PREVIOUSLY ALLOCATED ENTER Y OR N   ";TRS07$
2600 REM THE DATA HAS BEEN ENTERED NOW WRITE TO DISC
2610 PRINT #1,NARTRS;TC$,TRS01$,TRS02$,TRS03$,TRS04$,TRS05$,TRS06$,TRS07$
2620 NARTRS=NARTRS+1
2630 PRINT #2,1;NARINV,NARTRS
2640 GOTO 2000
9999 END