10 REM **********************************************************************
20 REM *                                                                    *
30 REM *                   INV301 PARTS INQUIRY                             *
40 REM *                   CERBERUS ASSOCIATES                              *
50 REM *                                                                    *
60 REM **********************************************************************
70 REM
80 REM THIS PROGRAM ALLOWS VIEWING ALL DATA ON INDIVIDUAL PART NUMBERS
1000 REM OPEN FILES USED BY THE PROGRAM
1100 INVMAS$="INV.MAS"
1110 NARCTR$="NAR.CTR"
1200 FILE INVMAS$(192)
1210 FILE NARCTR$(16)
2000 REM DETERMINE WHICH PART IS TO BE DISPLAYED
2010 INPUT "WHAT PART NUMBER DO YOU WANT TO LOOK AT ENTER E TO END ";PTNUM$
2015 IF PTNUM$="E" THEN 9999
2020 IF END #1 THEN 3000
2030 READ #2,1;NARINV,NARTRS
2040 REM NARINV IS NEXT AVAILABLE INVENTORY MASTER FILE RECORD
2050 FOR I=1 TO NARINV
2060 READ #1,I;FLD01$,FLD02$,FLD03$,FLD04$,FLD05$,FLD06$,FLD07$,\
    FLD08$,FLD09$,FLD10$,FLD11$,FLD12$,FLD13$,FLD14$,FLD15$,FLD16$,FLD17$,\
    FLD18$,FLD19$,FLD20$,FLD21$,FLD22$,FLD23$,FLD24$
2070 IF PTNUM$=FLD01$ THEN 2200
2080 REM IF NO MATCH TRY THE NEXT RECORD
2090 NEXT I
2200 REM FOUND A MATCH NOW DISPLAY THE DATA
2210 PRINT "PART NUMBER   ",FLD01$
2220 PRINT "DESCRIPTION   ",FLD02$
2230 PRINT " "
2240 PRINT "LOCATION            ",FLD03$,"CATAGORY            ",FLD04$
2250 PRINT "AVERAGE COST        ",FLD05$,"SELLING PRICE       ",FLD06$
2260 PRINT "QUANTITY ON HAND    ",FLD07$,"QUANTITY ON ORDER   ",FLD08$
2270 PRINT "YEAR TO DATE ISSUE  ",FLD09$,"MONTH TO DATE ISSUE ",FLD10$
2280 PRINT "LAST ISSUE DATE     ",FLD11$,"UNIT OF MEASURE     ",FLD12$
2290 PRINT "VENDOR NUMBER       ",FLD13$,"TAX FLAG            ",FLD14$
2300 PRINT "LAST ORDER DATE     ",FLD15$,"YEAR TO DATE RETURN ",FLD16$
2310 PRINT "YEAR TO DATE RECEIPT",FLD17$,"MONTH TO DATE RECPT ",FLD18$
2320 PRINT "REORDER POINT       ",FLD19$,"WEIGHT              ",FLD20$
2330 PRINT "LEAD TIME           ",FLD21$,"YEAR TO DATE COST   ",FLD22$
2340 PRINT "YEAR TO DATE SALES  ",FLD23$,"ALLOCATED           ",FLD24$
2400 PRINT " "
2410 REM RETURN FOR NEXT PART NUMBER
2420 GOTO 2000
3000 REM PART NUMBER DOESNT EXIST
3010 PRINT "NO SUCH PART IN INVENTORY"
3020 GOTO 2000
9999 END