* CAY.CMD - Close Accounting Year                       
*
STORE TRIM(TITLE) TO MTITLE
ERASE
@ 1,10 SAY TMARK + "  " + CNAME
SET INTE OFF
@ 3,10 SAY MTITLE
SET INTE ON
STORE 5 TO ROW
@ ROW,10    SAY "You may use this program to close the year. This process involves"
@ ROW+1,10  SAY "zeroing YTD amounts on income statement accounts and tranferring"
@ ROW+2,10  SAY "earnings year-to-date to retained earnings. Before this program"
@ ROW+3,10  SAY "is run, you should close all months within the accounting year"
@ ROW+4,10  SAY "and print all associated reports. Also, make several copies of"
@ ROW+5,10  SAY "your chart of accounts and label them as of the end of the year"
@ ROW+6,10  SAY "for reference. Closing a year requires that the computer know"
@ ROW+7,10  SAY "some account numbers in order to transfer earnings. Make certain"
@ ROW+8,10  SAY "that the following account numbers are correct. If they are not"
@ ROW+9,10  SAY "use the initialization procedure to correct them:"
@ ROW+11,10 SAY "     Retained earnings account  - " GET RETEARN
@ ROW+12,10 SAY "     Earnings, Year-to-date     - " GET YTDEARN
@ ROW+13,10 SAY "     First Income Account       - " GET FIRSTINC
CLEAR GETS
STORE 20 TO ROW
STORE " " TO ANSWER
@ ROW,10    SAY "Enter just a RETURN to close or (Q)uit " GET ANSWER PICTURE "!"
READ
IF ANSWER = "Q"
   RETURN
ENDIF
STORE ROW + 2 TO ROW
@ ROW,10    SAY "Standby while we close out this year."
SELECT PRIMARY
USE DAACCT INDEX DAACCT1
FIND &RETEARN
IF # = 0
   @ ROW,10  SAY "The Retained Earnings Account is wrong, please correct and rerun"
   WAIT
   RETURN
ENDIF
FIND &YTDEARN
IF # = 0
   @ ROW,10  SAY "The Earnings, Year-to-date Account is wrong, please correct and rerun"
   WAIT
   RETURN
ENDIF
STORE AMOUNT TO EARNINGS
REPLACE AMOUNT WITH 0.00
FIND &RETEARN
REPLACE AMOUNT WITH AMOUNT + EARNINGS
REPLACE ALL AMOUNT WITH 0.00 FOR ACCT:NUMB >= FIRSTINC
RETURN