* GENL.CMD - GENERAL LEDGER (TRIAL BALANCE) REPORT
*
STORE TRIM(TITLE) TO MTITLE
ERASE
@ 1,10 SAY TMARK + "  " + CNAME
SET INTE OFF
@ 3,10 SAY MTITLE
SET INTE ON
STORE 5 TO ROW
STORE "        " TO EDATE
@ ROW,10   SAY "You may print this report as of a certain date. Transactions"
@ ROW+1,10 SAY "dated after this date will not be included. Enter date as (MM/DD/YY)"
@ ROW+2,10 SAY "or just a RETURN if you do not wish to limit the report. " ;
GET EDATE PICTURE "99/99/99"
READ
STORE 4 + ROW TO ROW
IF EDATE = "  /  /  "
   STORE "99/99/99" TO TDATE
   ELSE
   STORE $(EDATE,7,2) + $(EDATE,1,5) TO TDATE
ENDIF
STORE "                                        " TO HEADING
@ ROW,10 SAY "You may now enter a report heading for later identification."
@ ROW+1,10 SAY "RETURN only for no heading. " GET HEADING
READ
STORE ROW + 3 TO ROW
@ ROW,10 SAY "Please ensure that your printer is ready to print."
STORE ROW + 1 TO ROW
STORE " " TO READY
@ ROW,10 SAY "Enter (P)rint or (Q)uit followed by RETURN " GET READY
READ
IF !(READY) = "Q"
   RETURN
ENDIF
@ ROW+3,10 SAY "Your report is now printing!"
SELECT SECONDARY
USE DATRAN INDEX DATRAN1
SELECT PRIMARY
USE DAACCT INDEX DAACCT1
STORE 0.00 TO TOT:CUR
STORE 0.00 TO TOT:BAL
SET FORMAT TO PRINT
STORE 60 TO ROW
DO WHILE .NOT. EOF
STORE ACCT:NUMB TO ACCT
IF ACCT = YTDEARN
   SKIP
   LOOP
ENDIF
STORE ROW + 3 TO ROW
IF ROW > 56
   EJECT
   @ 1,25 SAY CNAME
   @ 2,25 SAY MTITLE
   @ 4,25 SAY HEADING
   @ 6,1  SAY "Account                                                            Prev Balance         Current"
   @ 7,1  SAY "Number     Description                      Date    Reference      Curr Entries         Balance"
   @ 8,1  SAY "-----------------------------------------------------------------------------------------------"
   STORE 10 TO ROW
ENDIF
@ ROW,1  SAY ACCT
@ ROW,12 SAY ACCT:NAME
@ ROW,64 SAY AMOUNT USING '  999,999,999.99'
STORE AMOUNT TO EBAL
SELECT SECONDARY
FIND &ACCT
IF # = 0
   STORE ROW + 1 TO ROW
   @ ROW,80 SAY EBAL USING '  999,999,999.99'
   SELECT PRIMARY
   STORE TOT:BAL + AMOUNT TO TOT:BAL
   SKIP
   LOOP
ENDIF
STORE ROW + 1 TO ROW
DO WHILE ACCT:NUMB = ACCT .AND. .NOT. EOF
   IF $(PDATE,7,2) + $(PDATE,1,5) > TDATE
      SKIP
      LOOP
   ENDIF
   STORE ROW + 1 TO ROW
   IF ROW > 62
      EJECT
      @ 1,25 SAY CNAME
      @ 2,25 SAY MTITLE
      @ 4,25 SAY HEADING
      @ 6,1  SAY "Account                                                            Prev Balance         Current"
      @ 7,1  SAY "Number     Description                      Date    Reference      Curr Entries         Balance"
      @ 8,1  SAY "-----------------------------------------------------------------------------------------------"
      STORE 12 TO ROW
      @ 10,1 SAY ACCT + " continued"
   ENDIF
   @ ROW,12 SAY REFERENCE
   @ ROW,43 SAY PDATE
   @ ROW,52 SAY SOURCE
   @ ROW,55 SAY REF:NO
   @ ROW,64 SAY AMOUNT USING '  999,999,999.99'
   STORE EBAL + AMOUNT TO EBAL
   STORE TOT:CUR + AMOUNT TO TOT:CUR
   SKIP
ENDDO 
STORE ROW + 1 TO ROW
@ ROW,80 SAY EBAL USING '  999,999,999.99'
STORE TOT:BAL + EBAL TO TOT:BAL
SELECT PRIMARY
SKIP
ENDDO EOF
STORE ROW + 2 TO ROW
@ ROW-1,69 SAY "-----------     -----------"
@ ROW,12 SAY "TOTALS ARE:"
@ ROW,64 SAY TOT:CUR USING '  999,999,999.99'
@ ROW,80 SAY TOT:BAL USING '  999,999,999.99'
@ ROW+1,69 SAY "===========     ==========="
EJECT
SET FORMAT TO SCREEN
RETURN