* ***************************  DNFAST COMMAND FILE  **************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
ERASE
DO WHILE correct
 SET inte ON
 SET colon ON
 STORE '                                   ' TO mname
 STORE '               ' TO mphone
 IF !(answer)= 'N' 
  @ 13,10 SAY 'TO FIND A NAME, Enter enough of record name to ' +;
  'make it unique.' 
  @ 14,10 SAY 'To return to main menu type <RET>.' 
  @ 17,20 GET mname
 ELSE
  @ 13,10 SAY 'TO FIND A PHONE NUMBER, Enter Area Code and Phone ' +;
  'Number.' 
  @ 14,10 SAY 'To return to main menu type <RET>.' 
  @ 17,27 GET mphone PICTURE '(999) 999-9999' 
 ENDIF 
 @ 23,0 SAY '  ctl-X down | ctl-E up | ctl-D -> | ctl-S <- ' +;
 '| ctl-G del char | ctl-V insert' 
 &con
 READ
 &coff
 IF mname= '  ' .AND.$(mphone,2,3)= '   ' 
  SET colon OFF
  RELEASE mname,mphone,point,more,l,nam,noloca,recno,stop,nnn
  STORE f TO open
  RETURN
 ENDIF 
 IF !(answer)= 'N' 
  SELECT PRIMARY
  STORE len(trim(mname)) TO l
  STORE $(mname,1,l) TO nam
  FIND &nam
  IF #<>0
   STORE t TO noloca
   STORE # TO recno
   STORE str(no,5) TO nnn
   SELECT seco
   GO recno
   SELECT PRIMARY
   DO dnscan
   ERASE
  ENDIF 
 ELSE
  STORE $(mphone,2,3)+$(mphone,7,3)+$(mphone,11,4) TO mphone
  SELECT seco
  FIND &mphone
  IF #<>0
   STORE t TO noloca
   STORE # TO recno
   STORE str(nno,5) TO nnn
   SELECT PRIMARY
   GO recno
   DO dnscan
   ERASE
  ENDIF 
 ENDIF 
 IF #=0
  SET inte OFF
  IF !(answer)= 'N' 
   @ 16,7 SAY "I CAN'T FIND THAT NAME. Retry or type <RET> " +;
   "to return to main menu." 
  ELSE
   @ 16,3 SAY "I CAN'T FIND THAT PHONE NUMBER. Retry or type <RET> " +;
   "to return to main menu." 
  ENDIF 
 ELSE
  @ 16,3
 ENDIF 
ENDDO WHILE 
SET colon OFF
RETURN