* **************************  DNINSTAL COMMAND FILE  *************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
CLEAR
USE dndate
SET talk OFF
SET confirm ON
SET colon ON
ERASE
? '                     dNAMES  I N S T A L L  PROGRAM' 
? '                            for version 1.1' 
?
? '       Please refer to dNAMES manual for instructions on installing.' 
STORE t TO correct
DO WHILE correct
 STORE ' ' TO answer
 @ 8,17 SAY 'Is this a re-install of dNAMES? Y/N ' GET answer
 READ
 IF !(answer)= 'Y' .OR.!(answer)= 'N' 
  STORE f TO correct
 ENDIF 
ENDDO WHILE 
IF !(answer)= 'Y' 
 STORE data+ ':dnmem' TO mem
 RESTORE FROM &mem
 STORE 'Y' TO answer
ENDIF 
STORE deop TO meop
STORE dpr96 TO mpr96
STORE dpreset TO mpreset
STORE dpron TO mpron
STORE dproff TO mproff
STORE disk TO mdisk
STORE data to mdata
STORE dcoff TO mcoff
STORE dcon TO mcon
CLEAR GETS
@ 12,17 SAY 'Enter code A ' GET meop
@ 13,17 SAY 'Enter code B ' GET mpr96
@ 14,17 SAY 'Enter code C ' GET mpreset
@ 15,17 SAY 'Enter code D ' GET mpron
@ 16,17 SAY 'Enter code E ' GET mproff
@ 17,17 SAY 'Enter code F ' GET mcoff
@ 18,17 SAY 'Enter code G ' GET mcon
IF !(answer)<> 'Y' 
 @ 19,17 SAY 'Enter code H ' GET mdisk PICTURE '!' 
 @ 20,17 SAY 'Enter code I ' GET mdata PICTURE '!'
ENDIF 
@ 23,0 SAY '  ctl-X down | ctl-E up | ctl-D -> | ctl-S <- ' +;
'| ctl-G del char | ctl-V insert' 
SET inte OFF
READ
STORE mdata+ ':dnmem' TO mem
IF meop=' '
 STORE 'CALL' TO eop
ELSE
 REPLACE deop WITH meop
 STORE trim(deop) TO eop
ENDIF
IF MPR96=' '
 REPL dPR96 WITH "' '"
ELSE
 REPL dPR96 WITH MPR96
ENDIF
IF MPRESET=' '
 REPL dPRESET WITH "' '"
ELSE
  REPL dPRESET WITH MPRESET
ENDIF
IF MPRON=' '
 REPL dPRON WITH "' '"
ELSE
 REPL dPRON WITH MPRON
ENDIF
IF MPROFF=' '
 REPL dPROFF WITH "' '"
ELSE
 REPL dPROFF WITH MPROFF
ENDIF
IF MCOFF=' '
 REPL dCOFF WITH "' '"
 STORE '@ 0,0 SAY " "' TO COFF
ELSE
 REPL dCOFF WITH MCOFF
 STORE '@ 0,0 SAY '+TRIM(dCOFF) TO COFF
ENDIF
IF MCON=' '
 STORE '@ 0,0 SAY " "' TO CON
ELSE
 REPL dCON WITH MCON
 STORE '@ 0,0 SAY '+TRIM(dCON) TO CON
ENDIF
IF !(answer)= 'N' 
 REPLACE disk WITH mdisk,DATE WITH DATE(),data WITH mdata
 STORE mdisk+mdata TO dsk
 STORE ' ' TO mcl1
 STORE ' ' TO mcl2
 STORE ' ' TO mcl3
 STORE ' ' TO mcl4
 STORE ' ' TO mcl5
 STORE ' ' TO mcl6
 STORE ' ' TO mcl7
 STORE ' ' TO mcl8
 STORE ' ' TO mcl9
 STORE ' ' TO mcl10
 STORE 1 TO mno
 STORE data+ ':dnn' TO a1
 STORE data+ ':dnxn' TO a2
 STORE data+ ':dnc' TO b1
 STORE data+ ':dnxc' TO b2
 STORE data+ ':dnmc' TO c1
 STORE data+ ':dnxmc' TO c2
 STORE data+ ':dnrecl' TO recl
 STORE data+ ':dncl' TO file
 ERASE
 @ 15,20 SAY '*** CREATING NEW dNAMES FILES *** ' 
 USE dninstn
 STORE trim(name) TO headname
 STORE '11/30/82' TO headdate
 COPY TO &a1
 USE &a1
 INDEX ON $(name,1,20) TO &a2
 USE dninstc
 COPY TO &b1
 USE &b1
 INDEX ON phone TO &b2
 USE dninstmc
 COPY TO &c1
 USE &c1
 INDEX ON cno TO &c2
 USE dninstre
 COPY TO &recl
 USE dninstcl
 COPY TO &file
 USE
ELSE
 ERASE
 @ 15,14 SAY '*** SAVING NEW CONTROL CODES TO '+mdata+':DNMEM.MEM *** ' 
ENDIF 
RELEASE mbon,moff,meop,mproff,mpron,mpr96,mpreset,mdisk,answer,mcoff,mcon,;
mdata,recl,file,pr96,preset,pron,proff
SAVE TO &mem
ERASE
QUIT