* **************************  DNLISTB COMMAND FILE  **************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
RELEASE srt,correct,wanted,specs,srt2,nohead,srt1,nnn,point
SAVE TO &mem
RELEASE a1,a2,b1,b2,c1,c2,lno,mcl1,mcl2,mcl3,mcl4,mcl5,mcl6,;
mcl7,mcl8,mcl9,mcl10
DO WHILE .not.eof
 STORE t TO stop
 STORE 1 TO howmany
 STORE ' ' TO lb1
 STORE ' ' TO lb2
 STORE ' ' TO lb3
 STORE ' ' TO la1
 STORE ' ' TO la2
 STORE ' ' TO la3
 STORE ' ' TO lc1
 STORE ' ' TO lc2
 STORE ' ' TO lc3
 STORE ' ' TO lz1
 STORE ' ' TO lz2
 STORE ' ' TO lz3
 DO WHILE .not. eof.AND.stop
  STORE str(howmany,1) TO which
  STORE no TO recno
  SELECT seco
  GO recno
  RELEASE recno
  STORE @( '*' ,name) TO where
  IF where=0
   STORE $(name,1,30) TO lb&which
  ELSE
   STORE $($(name,where+1,len(trim(name))-where)+ ;
   ' ' +$(name,1,where-1)+ '                              ' ,1,30);
   TO lb&which
  ENDIF
  RELEASE where
  IF '@' $com
   STORE $($(com,1,@( '@' ,com)-1)+ '                              ' ;
   ,1,30) TO la&which
   STORE $(ADD,1,30) TO lc&which
   STORE $(trim(city)+ '  ' +state+ '                             ' ;
   ,1,24)+zip TO lz&which
  ELSE
   STORE $(ADD,1,30) TO la&which
   STORE $(trim(city)+ '  ' +state+ '                             ' ;
   ,1,24)+zip TO lc&which
   STORE '                              ' TO lz&which
  ENDIF
  SELECT PRIMARY
  STORE howmany+1 TO howmany
  IF noloca
   SKIP
  ELSE
   CONTINUE
  ENDIF
  STORE printed+1 TO printed
  IF howmany=4
   STORE f TO stop
  ELSE
   LOOP
  ENDIF
 ENDDO WHILE .not. eof
 ? lb1+ '    ' +lb2+ '    ' +lb3
 ? la1+ '    ' +la2+ '    ' +la3
 ? lc1+ '    ' +lc2+ '    ' +lc3
 ? lz1+ '    ' +lz2+ '    ' +lz3
 ?
 ?
 SET cons ON
 IF thismany#0
  @ 11,42 SAY str(thismany-printed,5)
 ENDIF
 @ 12,42 SAY str(printed,5)
 IF printed/33=page.AND..not.eof
  IF !(pgbreak)= 'Y' 
   STORE ' ' TO shouldi
   @ 18,0 SAY 'Type "A" to abort printing or <RET> to continue. ' GET shouldi
   &con
   READ
   &coff
   IF !(shouldi)= 'A' 
    RELEASE shouldi,printed,thismany,pgbreak,lb1,lb2,lb3,la1,la2,;
    la3,lc1,lc2,lc3,lz1,lz2,lz3,stop,where,recno,tempfile,noloca,page,;
    howmany,which
    SET colon OFF
    RESTORE FROM &mem
    RETURN
   ENDIF
   @ 18,0
  ENDIF
  STORE page+1 TO page
  @ 13,42 SAY str(page,5)
 ENDIF
 SET cons OFF
ENDDO WHILE .not.eof
?? &preset
EJECT
SET PRINT OFF
SET conso ON
RELEASE shouldi,printed,thismany,pgbreak,lb1,lb2,lb3,la1,la2,la3,lc1,lc2,;
lc3,lz1,lz2,lz3,stop,where,recno,tempfile,noloca,page,howmany,which
RESTORE FROM &mem
@ 16,0 SAY 'Press any key to Return to REPORT MENU' 
SET cons OFF
WAIT
SET cons ON
SET colon OFF
SET inte ON
RETURN