* **************************  DNLISTD COMMAND FILE  **************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
RELEASE specs,mname,looking,noshow,srt,srt1,srt2,sure,correct
? '|                                                   ' +;
'                         | ' 
IF !(prn)<> 'Y' .AND..not.nohead
 @ 0,0 SAY &pron
 @ 0,0 SAY &pron
 @ 0,0 SAY &pron
 @ 0,0 SAY &pron
 @ 0,0 SAY &pron
 @ 0,0 SAY &pron
 @ 0,0 SAY &pron
ENDIF
STORE t TO dotline
STORE t TO yes
STORE 0 TO printed
STORE 0 TO number
STORE 0 TO where
STORE 0 TO lno
IF nohead
 STORE 19 TO newpage
ELSE
 STORE 14 TO newpage
ENDIF 
DO WHILE .not. eof
 IF number+7>=newpage .AND. !(prn)<> 'Y' 
  IF where=0
   IF nohead
    STORE number+lno TO where
   ELSE
    STORE number+lno+1 TO where
   ENDIF 
  ELSE
   STORE 23 TO where
  ENDIF
  IF nohead
   STORE where+2 TO where
  ENDIF
  STORE f TO yes
  SET inte OFF
  ? '           Press "A" to ABORT listing or SPACE BAR to continue ' 
  SET cons OFF
  WAIT TO abort
  SET cons ON
  IF !(abort)= 'A' 
   RELEASE nohead,dotline,yes,printed,number,where,lno,newpage,page,;
   shouldi,pgbreak,tophead,date1,date2,nnn,thismany,tempfile,noloca
   ?? &proff
   RETURN
  ENDIF
  STORE 0 TO number
  STORE 0 TO lno
 ENDIF
 IF !(prn)= 'Y' .AND.lno+number>=47
  STORE page+1 TO page
  STORE 0 TO number
  STORE 0 TO lno
  ? '|===================================================' +;
  '=========================|' 
  EJECT
  IF !(pgbreak)= 'Y' 
   SET cons ON
   STORE ' ' TO shouldi
   @ 18,0 SAY 'Type "A" to abort printing or <RET> to continue. ' GET shouldi
   &con
   READ
   &coff
   IF !(shouldi)= 'A' 
    RELEASE nohead,dotline,yes,printed,number,where,lno,newpage,page,;
    shouldi,pgbreak,tophead,date1,date2,nnn,thismany,tempfile,noloca
    SET colon OFF
    RETURN
   ENDIF
   @ 18,0
  ENDIF
  @ 13,42 SAY str(page,5)
  SET cons OFF
  ? '|===================================================' +;
  '=========================|' 
  ? '| ' +tophead+ ' DATE- '+DATE()+'  PAGE- ' +str(page,4)+ ' |' 
  ? '|               RECORD NAME                |        ADDRESS' +;
  '                  |' 
  ? '|        PHONE      |  ENTERED | UPDATED   |        CITY, ' +;
  'STATE  ZIP         |' 
  ? '|                               COMMENTS                  ' +;
  '                   |' 
  ? '|===================================================' +;
  '=========================|' 
  ? '|                                                   ' +;
  '                         |' 
 ENDIF
 STORE lno+number TO number
 STORE no TO recno
 SELECT seco
 GO recno
 STORE ' ' +$(DATE,1,2)+ '-' +$(DATE,3,2)+ '-' +$(DATE,5,2)+ '   ' TO DATE1
 STORE $(UPDATE,1,2)+ '-' +$(UPDATE,3,2)+ '-' +$(UPDATE,5,2)+ '   ' TO DATE2
 IF yes
  ? '| ' +$(name+'        ',1,42)+$(ADD+'     ',1,33)+ '|' 
 ELSE
  SET inte OFF
  @ where,0 SAY '| ' +$(name+'        ',1,42)+$(ADD+'     ',1,33)+ '|' 
  SET inte ON
 ENDIF
 ? '|  ' +$( '(' +$(phone,1,3)+ ') ' +$(phone,4,3)+ '-' +$(phone,7,4)+;
 '          ',1,18)+DATE1+DATE2+$(city+ '  ' +state+ '   ' +;
 zip+'   ',1,33)+ '|' 
 STORE 2 TO lno
 IF com<> ' ' 
  ? '|  ' +$(com+'            ',1,74)+ '|' 
  STORE lno+1 TO lno
 ENDIF
 IF $(code,1,1)= '*' 
  USE &c1 INDEX &c2
  STORE str(recno,5) TO nnn
  FIND &nnn
  ? '|  ' +line1+ '|' 
  STORE lno+1 TO lno
  IF line2<> ' ' 
   ? '|  ' +line2+ '|' 
   STORE lno+1 TO lno
  ENDIF
  IF line3<> ' ' 
   ? '|  ' +line3+ '|' 
   STORE lno+1 TO lno
  ENDIF
  RELEASE nnn
  USE &b1
 ENDIF
 SELECT PRIMARY
 STORE printed+1 TO printed
 IF !(prn)= 'Y' 
  SET cons ON
  IF thismany#0
   @ 11,42 SAY str(thismany-printed,5)
  ENDIF
  @ 12,42 SAY str(printed,5)
  SET conso OFF
 ENDIF
 IF tempfile.OR.noloca
  SKIP
 ELSE
  CONTINUE
 ENDIF
 IF .not.eof.AND.lno+number<=47
  ? '|---------------------------------------------------' +;
  '-------------------------|' 
  STORE lno+1 TO lno
 ENDIF
 STORE t TO yes
ENDDO WHILE .not. eof
? '|===================================================' +;
'=========================|' 
EJECT
IF !(prn)= 'Y' 
 SET PRINT OFF
 @ 16,0 SAY 'Press any key to Return to REPORT MENU' 
 SET cons OFF
 WAIT
 SET cons ON
 STORE ' ' TO abort
ENDIF
SET colon OFF
SET inte ON
?? &proff
RELEASE nohead,dotline,yes,printed,number,where,lno,newpage,page,;
shouldi,pgbreak,tophead,date1,date2,nnn,thismany,tempfile,noloca
RETURN