* **************************  DNLISTFI COMMAND FILE  *************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
STORE 0 TO thismany
STORE $(dsk,2,1)+':tfile' TO tfile
STORE $(dsk,2,1)+':xtfile' TO xtfile
STORE $(dsk,2,1)+':xtfile.ndx' to ndx
STORE $(dsk,2,1)+':temp' TO temp
DO CASE
 CASE !(srt)= 'Y' 
  USE &a1
  IF str1# ' ' .OR.str2# ' ' .OR.str3# ' ' .OR.str4# ' ' 
   COPY TO &tfile FOR &str1 &str2 &str3 &str4
   USE &tfile
  ENDIF
  IF srt2= ' ' 
   IF !(srt1)='NAME'
    INDEX ON $(name,1,20) TO &xtfile
   ELSE
    INDEX ON &srt1 TO &xtfile
   ENDIF
  ELSE
   IF !(srt2)='NAME'
    INDEX ON &srt1 + $(name,1,20) TO &xtfile
   ELSE
    INDEX ON &srt1 + &srt2 TO &xtfile
   ENDIF
  ENDIF
  IF str1# ' ' .OR.str2# ' ' .OR.str3# ' ' .OR.str4# ' ' 
   USE &tfile INDEX &xtfile
  ELSE
   USE &a1 INDEX &xtfile
  ENDIF
  COPY TO &temp
  USE &temp
  GO BOTTOM
  STORE # TO thismany
  IF str1# ' ' .OR.str2# ' ' .OR.str3# ' ' .OR.str4# ' ' 
   DELETE FILE &tfile
  ENDIF
  DELETE FILE &ndx
  STORE t TO tempfile
 CASE !(srt)# 'Y' 
  USE &a1
  STORE f TO tempfile
 OTHERWISE
  LOOP
ENDCASE 
RELE temp,xtfile,tfile,ndx
IF tempfile.OR.noloca
 GO TOP
ELSE
 LOCATE FOR &str1 &str2 &str3 &str4 
ENDIF
IF eof
 SET inte OFF
 @ 11,4 SAY "I can't find any records that meet those specifications." 
 @ 12,4 SAY "Press any key to continue.                              " 
 SET inte ON 
 SET consol OFF
 WAIT
 SET consol ON
 RETURN
ELSE
 STORE ' ' TO abort
 IF !(typ)# 'E' 
  ERASE
 ENDIF
ENDIF
SET colon OFF
IF !(typ)# 'E' 
 ERASE
ENDIF
IF !(prn)= 'Y' .OR.!(typ)= 'B' 
 ERASE
 SET inte ON
 STORE 0 TO printed
 IF thismany#0
  @ 10,27 SAY 'TOTAL TO PRINT-' 
  @ 11,26 SAY 'TOTAL REMAINING-' 
  SET inte OFF
  @ 10,42 SAY str(thismany,5)
  @ 11,42 SAY str(thismany-printed,5)
  SET inte ON
 ENDIF
 @ 12,28 SAY 'TOTAL PRINTED-' 
 SET inte OFF
 @ 12,42 SAY str(printed,5)
 SET inte ON
 IF !(typ)= 'B' .OR.!(typ)= 'C' .OR.!(typ)= 'D' 
  STORE 1 TO page
  STORE ' ' TO pgbreak
  @ 13,37 SAY 'PAGE-' 
  @ 14,32 SAY 'PAGEBREAK-' 
  SET colon ON
  @ 16,0 SAY 'Would you like to pause at page breaks? ---(N)- ' GET pgbreak
  &con
  READ
  &coff
  @ 16,0
  SET inte OFF
  @ 13,42 SAY str(page,5)
  IF !(pgbreak)= 'Y' 
   @ 14,45 SAY 'ON' 
  ELSE
   @ 14,44 SAY 'OFF' 
  ENDIF
 ENDIF
 IF !(typ)= 'A' 
  STORE 0 TO batch
  SET colon ON
  @ 15,0 SAY 'You may print these labels in smaller increments if neccesary.' 
  @ 16,0 SAY 'How many labels would you like to print first? <RET> for all. ' ;
  GET batch
  &con
  READ
  &coff
  IF batch#0
   @ 13,23 SAY 'REMAINING OF BATCH-' 
   SET inte OFF
   @ 13,42 SAY str(batch,5)
  ENDIF
  @ 15,0
  @ 16,0
 ENDIF
 @ 15,23 SAY '(MAKE SURE PRINTER IS ON)' 
 SET colon ON
 STORE t TO correct
 DO WHILE correct
  STORE ' ' TO quest
  SET inte ON
  @ 17,0 SAY 'Print a sample type "T", abort printing type "A",' 
  @ 18,0 SAY 'or start printing type <RET>.  Enter your choice. ' GET quest
  &con
  READ
  &coff
  SET cons OFF
  IF !(quest)= 'A' 
   SET consol ON
   SET colon OFF
   RETURN
  ENDIF
  IF !(typ)= 'B' 
   SET PRINT ON
   ?? &pr96
   SET PRINT OFF
  ENDIF
  SET conso ON
  IF !(quest)= 'T' 
   DO dnlistt
   @ 15,0
  ELSE
   @ 15,0 
   @ 17,0
   @ 18,0
   STORE f TO correct
  ENDIF 
 ENDDO 
 SET cons OFF
 SET inte OFF
 SET PRINT ON
ENDIF
IF &pron = ' ' .AND.!(prn)# 'Y' 
 STORE t TO nohead
ELSE
 STORE f TO nohead
ENDIF
IF !(typ)# 'A' .AND.!(typ)# 'B' .AND.!(typ)# 'E' .AND..not.nohead
 ? '|===========================================================' +;
 '=================|' 
 IF !(prn)= 'Y' 
  ? '| ' +tophead+ ' DATE- '+DATE()+'  PAGE- ' +str(page,4)+ ' |' 
 ELSE 
  ? '| ' +tophead+ '                            |' 
 ENDIF
 IF !(typ)= 'C' 
  ? '|           RECORD NAME            |     PHONE     | ZIP  |  ' +;
  'DATE  | UPDATE  |' 
 ENDIF
 IF !(typ)= 'D' 
  ? '|               RECORD NAME                |        ADDRESS' +;
  '                  |' 
  ? '|        PHONE      |  ENTERED | UPDATED   |        CITY, ' +;
  'STATE  ZIP         |' 
  ? '|                               COMMENTS                  ' +;
  '                   |' 
 ENDIF
 ? '|============================================================' +;
 '================|' 
ENDIF
STORE t TO stop
STORE ' ' TO abort
DO CASE
 CASE !(typ)= 'A' 
  DO dnlista
 CASE !(typ)= 'B' 
  DO dnlistb
 CASE !(typ)= 'C' 
  DO dnlistc
 CASE !(typ)= 'D' 
  DO dnlistd
 CASE !(typ)= 'E' 
  DO dnliste
 OTHERWISE
  LOOP
ENDCASE 
SET PRINT OFF
IF !(typ)# 'B' .AND.!(abort)# 'A' .AND.!(prn)# 'Y' 
 ? 'This is the end of the file. Press any key.' 
 SET cons OFF
 WAIT
 SET cons ON
ENDIF
SET consol ON
RETURN