* **************************  DNLISTS COMMAND FILE  **************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
@ 7, 0 SAY "||  Do you want to sort this list? Y or N --(N)-" 
@ 7,78 SAY "||" 
@ 7,49 GET srt
&con
READ
&coff
IF srt= ' ' 
 SET inte OFF
 @ 7,49 SAY 'N' 
 SET inte ON
ENDIF
STORE '    ' TO srt1
STORE '    ' TO srt2
IF !(srt)= 'Y' 
 SET colon ON
 @ 13,4 SAY 'Enter the primary field you would like this list sorted on:' 
 @ 14,4 SAY 'Name, Zip, or Date- ' 
 STORE t TO correct
 DO WHILE correct
  @ 14,23 GET srt1
  &con
  READ
  &coff
  IF !(srt1)# 'NAME' .AND.!(srt1)# 'ZIP' .AND.!(srt1)# 'DATE' 
   SET inte OFF
   @ 14,31 SAY 'INVALID ENTRY' 
   SET inte ON
   LOOP
  ELSE
   STORE f TO correct
   SET inte OFF
   @ 7,55 SAY 'Sort on: ' +!(srt1)
   SET inte ON
  ENDIF
 ENDDO WHILE correct 
 &era
 STORE ' ' TO quest
 @ 13,4 SAY 'If you would like this list to be sorted on an ' +;
 'additional field' 
 @ 14,4 SAY 'type "Y" or <RET> to continue ' GET quest
 &con
 READ
 &coff
 &era
 STORE '    ' TO srt2
 IF !(quest)= 'Y' 
  @ 13,4 SAY 'Enter the secondary field you would like this list ' +;
  'sorted on:' 
  @ 14,4 SAY 'Name, Zip, or Date ' 
  STORE t TO correct
  DO WHILE correct
   @ 14,23 GET srt2
   &con
   READ
   &coff
   IF !(srt2)# 'NAME' .AND.!(srt2)# 'ZIP ' .AND.!(srt2)# 'DATE' 
    SET inte OFF
    @ 14,31 SAY 'INVALID ENTRY' 
    SET inte ON
    LOOP
   ELSE
    STORE f TO correct
    SET inte OFF
    @ 7,55 SAY 'Sort on: ' +!(srt1)+ ' + ' +!(srt2)
    SET inte ON
   ENDIF
  ENDDO WHILE correct 
  RELEASE correct
 ENDIF
 SET colon OFF
 &era
ENDIF
@ 8, 0 SAY "||  Enter type of list desired. ----------------" 
@ 8,78 SAY "||" 
@ 12,20 SAY 'Enter your choice of list formats.' 
@ 14,4 SAY 'A> Labels - 3 lines single column - Name, Add, ' +;
'City, State, and Zip.' 
@ 15,4 SAY 'B> Labels - Avery 3 columns.(PRINT ONLY)' 
@ 16,4 SAY 'C> 1 line - Name, Phone, Zip , Entry and Update.' 
@ 17,4 SAY 'D> 2-6 lines - All Information.' 
@ 18,4 SAY 'E> Mailmerge data file - Name, Salutation, Add, ' +;
'City, State, and Zip.' 
STORE t TO correct
DO WHILE correct
 @ 8,49 GET typ
 &con
 READ
 &coff
 IF !(typ)#'A'.AND.!(typ)#'B'.AND.!(typ)#'C'.AND.!(typ)#'D'.AND.!(typ)#'E'
  SET inte OFF
  @ 12,56 SAY 'INVALID ENTRY' 
  SET inte ON
  LOOP
 ELSE
  STORE f TO correct
 ENDIF
ENDDO WHILE correct 
RELEASE correct
&era
IF !(typ)= 'E' 
 STORE '        ' TO datafile
 SET colon OFF
 @ 9,4 SAY 'Enter Mailmerge Data File name -------------         .DAT' 
 STORE t TO correct
 DO WHILE correct
  @ 9,49 GET datafile PICTURE 'XXXXXXXX' 
  &con
  READ
  &coff
  IF datafile= ' ' 
   SET inte OFF
   @ 13,51 SAY 'INVALID FILE NAME' 
   SET inte ON
   LOOP
  ELSE
   STORE f TO correct
   STORE !(trim(datafile))+ '.DAT' TO datafile
  ENDIF
 ENDDO WHILE correct
 RELEASE correct
 &era
ENDIF
IF !(typ)# 'B' .AND.!(typ)# 'E' 
 @ 9, 4 SAY "Do want a hardcopy? Y or N -------------(N)-" 
 @ 9,49 GET prn
 &con
 READ
 &coff
 IF prn= ' ' 
  SET inte OFF
  @ 9,49 SAY 'N' 
  SET inte ON
 ENDIF
ENDIF
SET inte OFF
STORE ' ' TO quest
SET colon ON
SET inte ON
STORE '                                               ' TO tophead
IF !(typ)# 'A' .AND.!(typ)# 'B' .AND.!(typ)# 'E' .AND.!(prn)='Y'
 @ 12,4 SAY 'Enter heading if needed. ' GET tophead
 &con
 READ
 &coff
ENDIF
@ 14,4 SAY 'If incorrect or you would like to abort type "A" ' +;
'or <RET> to continue. ' GET quest
&con
READ
&coff
@ 12,0
@ 14,0 
SET colon OFF
RETURN