* **************************  DNSRCH COMMAND FILE  ***************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
ERASE
SET colon OFF
RELEASE open
SELECT seco
USE dndate
STORE trim(dproff) TO proff
STORE trim(dpron) TO pron
STORE trim(dpr96) TO pr96
STORE trim(dpreset) TO preset
SELECT PRIMARY
DO WHILE t
IF eop#'CALL'
 STORE "@ 11,0 SAY "+eop TO era
ELSE
 STORE 'CALL' TO era 
 POKE 42000,10
ENDIF
 STORE t TO specs
 DO WHILE specs
  RELEASE specs,z1,z2,d1,d2,l1,l2,srt,locstring,showit,checkthis,;
  open,quest,wanted,correct,srt1,srt2
  SELECT PRIMARY
  ERASE
  STORE "                                                       " +;
  "                 " TO locstring
  STORE '      ' TO z1
  STORE '        ' TO d1
  STORE ' ' TO l1
  STORE ' ' TO srt
  STORE ' ' TO typ
  STORE ' ' TO prn
  STORE t TO showit
  STORE t TO checkthis
  DO WHILE checkthis
   IF showit
    ERASE
    SET inte OFF
    IF answer= '2' 
     @ 0,25 SAY 'R E P O R T  G E N E R A T O R' 
    ELSE
     @ 0,25 SAY 'S E L E C T I V E   E D I T' 
    ENDIF
    SET inte ON
    @ 1, 0 SAY "|===============================================" +;
    "===============================|" 
    @ 2,0 SAY '||  Enter initial ranges if desired. -----(ALL)- ' +;
    '  Type "?" to see examples   ||' 
    @ 2,78 SAY "||" 
    @ 3,0 SAY "||" 
    @ 3,78 SAY "||" 
    @ 4, 0 SAY "||  Enter zip range if desired. ----------(ALL)-" +;
    "        through-              ||" 
    @ 5, 0 SAY "||  Enter update range if desired. -------(ALL)-" +;
    "   /  /   through-   /  /     ||" 
    @ 6, 0 SAY "||  Enter letter range if desired. -------(ALL)-" +;
    "   through-                   ||" 
    @ 7, 0 SAY "||" 
    @ 7,78 SAY "||" 
    @ 8, 0 SAY "||" 
    @ 8,78 SAY "||" 
    @ 9, 0 SAY "||" 
    @ 9,78 SAY "||" 
    @ 10, 0 SAY "|===============================================" +;
    "===============================|" 
    SET inte OFF
    @ 11,15 SAY '* * * * Enter "@" to return to main menu. * * * *' 
    SET inte ON
    @ 13,9 SAY mcl1
    @ 14,9 SAY mcl2
    @ 15,9 SAY mcl3
    @ 16,9 SAY mcl4
    @ 17,9 SAY mcl5
    @ 18,9 SAY mcl6
    @ 19,9 SAY mcl7
    @ 20,9 SAY mcl8
    @ 21,9 SAY mcl9
    @ 22,9 SAY mcl10
    @ 23,0 SAY '  ctl-X down | ctl-E up | ctl-D -> | ctl-S <- ' +;
    '| ctl-G del char | ctl-V insert' 
   ENDIF
   @ 3,4 GET locstring
   &con
   READ
   &coff
   IF $(locstring,1,1)= '@' 
    ERASE
    SET inte OFF
    @ 13,25 SAY '*** ONE MOMENT PLEASE ***  ' 
    SET inte ON
    STORE f TO open
    RELEASE abort,blank,checkthis,d1,d2,datafile,date1,date2,dotline,howmany,;
    ia1,ia2,ia3,ib1,ib2,ib3,ic1,ic2,ic3,iz1,iz2,iz3,l1,l2,lno,locstring
    RELEASE mname,mphone,newpage,nnn,noloca,number,page,pgbreak,point,;
    pr96,preset,proff,pron,quest,recno,shouldi,showcl,showit,specs,srt,stop
    RELEASE str1,str2,str3,str4,tempfile,thismany,tophead,typ,wanted,;
    where,which,yes,z1,z2,batch,right,prn,sure,nohead,srt1,srt2
    USE &a1 INDEX &a2
    SELECT seco
    USE &b1 INDEX &b2
    SELECT PRIMARY
    RETURN
   ENDIF
   IF locstring= '  ' 
    SET inte OFF
    @ 2,49 SAY 'ALL                       ' 
    SET inte ON
    STORE f TO checkthis
   ENDIF
   IF .not. '?' $locstring.AND.locstring# '  ' 
    IF test( &locstring .AND.'01'$cl)
     @ 2,49 SAY '                          ' 
     @ 11,3
     @ 12,3
     STORE f TO checkthis
    ELSE
     SET inte OFF
     @ 11,4 SAY '  INVALID ENTRY... Re-enter or type ' +;
     '"?" to see some proper examples.     ' 
     @ 12,4 SAY 'You do not have to delete the entry for help, ' +;
     'just type "?" then <RET>.' 
     SET inte ON
     STORE f TO showit
    ENDIF
   ENDIF
   IF @( '?' ,locstring).AND.FILE( 'dnsrchhl.cmd' )
    DO dnsrchhl
   ENDIF 
  ENDDO WHILE checkthis 
  RELEASE showit,checkthis
  &era
  STORE t TO correct
  DO WHILE correct
   @ 4,49 GET z1
   &con
   READ
   &coff
   SET inte OFF
   IF len(trim(z1))<5.AND.z1# ' ' 
    @ 12,56 SAY 'INVALID ENTRY' 
    LOOP
   ELSE
    @ 12,55 SAY '                ' 
    STORE f TO correct
   ENDIF
  ENDDO WHILE correct 
  IF z1# ' ' 
   STORE z1 TO z2
   @ 4,65 GET z2
   &con
   READ
   &coff
  ELSE
   @ 4,49 SAY 'ALL            ' 
  ENDIF
  @ 5,49 GET d1 PICTURE '99/99/99' 
  &con
  READ
  &coff
  IF d1# ' ' 
   STORE DATE() TO d2
   @ 5,67 GET d2 PICTURE '99/99/99' 
   &con
   READ
   &coff
  ELSE
   @ 5,49 SAY 'ALL                       ' 
  ENDIF
  @ 6,49 GET l1 PICTURE 'A' 
  &con
  READ
  &coff
  IF l1# ' ' 
   STORE 'Z' TO l2
   @ 6,60 GET l2 PICTURE 'A' 
   &con
   READ
   &coff
   STORE !(l1) TO l1
   STORE !(l2) TO l2
  ELSE
   @ 6,49 SAY 'ALL        ' 
  ENDIF
  SET inte ON
  IF answer= '2' 
   DO dnlists
  ELSE
   STORE ' ' TO quest
   SET colon ON
   @ 12,4 SAY 'If incorrect or you would like to abort type "A" ' +;
   'or <RET> to continue. ' GET quest
   &con
   READ
   &coff
   &era
   SET colon OFF
  ENDIF
  SET inte OFF
  IF !(quest)# 'A' 
   @ 12,27 SAY "*** ONE MOMENT PLEASE ***  " 
   STORE f TO specs
  ELSE
   STORE t TO specs
   STORE t TO wanted
   LOOP
  ENDIF
  SET inte ON
 ENDDO WHILE specs 
 IF !(quest)# 'A' 
  DO dnsrchlo
 ENDIF
ENDDO WHILE t 
RETURN