* **************************  DNSRCHLO COMMAND FILE  *************************
*
*                                  dNAMES 1.1
*                   (c) Copyright 1982 Data Based Solutions
*                             All Rights Reserved
* ****************************************************************************
SELECT seco
USE &b1
SELECT PRIMARY
IF locstring# ' ' 
 STORE locstring TO str1
ELSE
 STORE ' ' TO str1
ENDIF 
RELEASE locstring
IF z1# ' ' 
 IF str1= ' ' 
  IF z1=z2
   STORE 'ZIP=Z1' TO str2
  ELSE
   STORE '(ZIP>=Z1.AND.ZIP<=Z2)' TO str2
  ENDIF
 ELSE
  IF z1=z2
   STORE '.AND.ZIP=Z1' TO str2
  ELSE
   STORE '.AND.(ZIP>=Z1.AND.ZIP<=Z2)' TO str2
  ENDIF
 ENDIF
ELSE
 STORE ' ' TO str2
ENDIF
IF d1# ' ' 
 STORE $(d1,1,2)+$(d1,4,2)+$(d1,7,2) TO d1
 STORE $(d2,1,2)+$(d2,4,2)+$(d2,7,2) TO d2
 IF str1= ' ' .AND.str2= ' ' 
  IF d1=d2
   STORE 'DATE=D1' TO str3
  ELSE
   STORE '(DATE>=D1.AND.DATE<=D2)' TO str3
  ENDIF
 ELSE
  IF d1=d2
   STORE '.AND.DATE=D1' TO str3
  ELSE
   STORE '.AND.(DATE>=D1.AND.DATE<=D2)' TO str3
  ENDIF
 ENDIF
ELSE
 STORE ' ' TO str3
ENDIF
IF l1# ' ' 
 IF str1= ' ' .AND.str2= ' ' .AND.str3= ' ' 
  IF l1=l2
   STORE '$(NAME,1,1)=!(L1)' TO str4
  ELSE
   STORE '($(NAME,1,1)>=!(L1).AND.$(NAME,1,1)<=!(L2))' TO str4
  ENDIF
 ELSE
  IF l1=l2
   STORE '.AND.$(NAME,1,1)=!(L1)' TO str4
  ELSE
   STORE '.AND.($(NAME,1,1)>=!(L1).AND.$(NAME,1,1)<=!(L2))' TO str4
  ENDIF
 ENDIF
ELSE
 STORE ' ' TO str4
ENDIF
IF str1= ' ' .AND.str2= ' ' .AND.str3= ' ' .AND.str4= ' ' 
 STORE t TO noloca
ELSE
 STORE f TO noloca
ENDIF
IF !(answer)= '2' 
 DO dnlistfi
ELSE
 SELECT PRIMARY
 USE &a1
 IF noloca
  GO TOP
 ELSE
  LOCATE FOR &str1 &str2 &str3 &str4 
 ENDIF
 IF eof
  SET inte OFF
  @ 11,4 SAY "I can't find any records that meet those specifications." 
  @ 12,4 SAY "Press any key to continue.                              " 
  SET inte ON 
  SET consol OFF
  WAIT
  SET consol ON
  RETURN
 ELSE
  STORE # TO recno
  SELECT seco
  GO recno
  SELECT PRIMARY
  DO dnscan
 ENDIF
ENDIF
RETURN