;	MICRO-DECSION
;	BOOT LOADER REV 1.4
;	COPYRIGHT 1982
;	MORROW DESIGNS, INC.
;	05/26/83
;
;********************************************************************
;	DOUBLE SIDED
;********************************************************************
;
BOOT	EQU 0FE00H
;
	.Z80
	.PHASE BOOT
;
;
REVNUM	EQU 22H
;
MEMSIZE	EQU 64
;
CPM	EQU (MEMSIZE-9)*1024
BIOS	EQU CPM+1600H
;
MTOFF	EQU 26
;
REVADD	EQU 7FDH
;
HSTSEC	EQU 2
HSTTRK	EQU 1
HSTBUF	EQU 5
SECCNT	EQU 3
ERFLAG	EQU 7
SECSIZ	EQU 12
;
ROM	EQU 0
;
RDHST	EQU ROM+9
BTERR	EQU ROM+18H
MESG	EQU ROM+3
;
CR	EQU 0DH
LF	EQU 0AH
;
START:	LD A,(REVADD)
	CP REVNUM
	JP NZ,REVERR
;
	PUSH IY			;CALC. MTAB POSITION
	POP HL
	LD DE,MTOFF
	ADD HL,DE
;
	EX DE,HL		;MOVE MTAB INTO RAMDATY
	LD HL,BTAB
	LD BC,9
	LDIR
;
	LD (IX+HSTSEC),2
	LD (IX+SECCNT),8
	LD (IX+SECSIZ+1),81H
	LD (IX+HSTBUF+1),HIGH CPM
;
	CALL RDHST
;
	LD A,(IX+ERFLAG)
	OR A
	JP NZ,BTERR
;
	LD (IX+HSTSEC),1
	LD (IX+HSTTRK),1
	LD (IX+SECCNT),9
	LD (IX+HSTBUF+1),HIGH CPM + 16
;
	CALL RDHST
;
	LD A,(IX+ERFLAG)
	OR A
	JP NZ,BTERR
;
	JP BIOS
;
	DS (BOOT+80H-$),0
;
BTAB:	DB 21H
	DB 0DCH
	DB 125
	DB 4
	DB 0AFH
	DB 3
	DB 5
	DB 28
	DB 0FFH
;
	DW 40
	DB 4
	DB 15
	DB 1
	DW 194
	DW 191
	DB 0E0H
	DB 0
	DW 48
	DW 2
	DB 43H
;
REVERR:	LD DE,RVMSG
	CALL MESG
	JP BTERR
;
RVMSG:	DB CR,LF,'Wrong revision of ROM. This version of CP/M requires ROM Rev. 2.2',CR,LF,0
;
	END