40 PRINT CHR$(4)
50 PRINT"THIS IS THE GAME OF CHASE"
60 PRINT"WANT INSTRUCTIONS";
70 INPUT A$
80 IF LEFT$(A$,1)="N" THEN 200
100 PRINT"YOU ARE IN A HIGH VOLTAGE MAZE WITH 5"
110 PRINT"SECURITY MACHINES '+' TRYING TO DESTROY YOU"
120 PRINT"YOU MUST MANEUVER THE SECURITY MACHINES INTO"
130 PRINT"THE MAZE 'X' TO SURVIVE, GOOD LUCK"
140 PRINT"THE MOVES ARE 1,2,3"
150 PRINT"              8,*,4   0 IS NO MOVE"
160 PRINT"              7,6,5   9 TO END THE GAME"
161 PRINT:PRINT
170 PRINT"PRESS ANY KEY TO START GAME"
180 WAIT 138,64
200 DIM A(10,20),E(21),F(21)
210 G=0
220 FOR B=1 TO 10
230 FOR C=1 TO 20
240 A(B,C)=0
250 IF B=1 THEN A(B,C)=1
260 IF B=10 THEN A(B,C)=1
270 IF C=1 THEN A(B,C)=1
280 IF C=20 THEN A(B,C)=1
290 NEXT C
300 NEXT B
310 FOR D=1 TO 21
320 B=INT(RND(1)*8)+2
330 C=INT(RND(1)*18)+2
340 IF A(B,C)<>0 THEN 320
350 A(B,C)=1
360 IF D<6 THEN A(B,C)=2
370 IF D=6 THEN A(B,C)=3
380 E(D)=B
390 F(D)=C
400 NEXT D
500 PRINT CHR$(4)
501 FOR B=1 TO 10
510 FOR C=1 TO 20
520 IF A(B,C)=0 THEN PRINT" ";
530 IF A(B,C)=1 THEN PRINT"X";
540 IF A(B,C)=2 THEN PRINT"+";
550 IF A(B,C)=3 THEN PRINT"*";
560 NEXT C
570 PRINT
580 NEXT B
600 B=E(6)
610 C=F(6)
620 A(B,C)=0
630 INPUT Y
640 IF Y=0 THEN 800
650 ON Y GOTO 660,660,660,690,680,680,680,690,1400
660 B=B-1
670 GOTO 690
680 B=B+1
690 ON Y GOTO 700,800,720,720,720,800,700,700
700 C=C-1
710 GOTO 800
720 C=C+1
800 IF A(B,C)=1 THEN 1500
810 IF A(B,C)=2 THEN 1600
820 A(B,C)=3
830 E(6)=B
840 F(6)=C
850 FOR D=1 TO 5
860 IF A(E(D),F(D))<>2 THEN 960
870 A(E(D),F(D))=0
880 IF E(D)<B THEN E(D)=E(D)+1
890 IF E(D)>B THEN E(D)=E(D)-1
900 IF F(D)<C THEN F(D)=F(D)+1
910 IF F(D)>C THEN F(D)=F(D)-1
920 IF A(E(D),F(D))=3 THEN 1600
930 IF A(E(D),F(D))<>0 THEN G=G+1
940 IF A(E(D),F(D))=0 THEN A(E(D),F(D))=2
950 IF G=5 THEN 1700
960 NEXT D
970 GOTO 500
1400 PRINT"SORRY TO SEE YOU QUIT"
1410 GOTO 1710
1500 PRINT"YOU TOUCHED THE FENCE !!!!!!"
1510 GOTO 1710
1600 PRINT"**YOU HAVE BEEN DESTROYED BY A LUCKY COMPUTER**"
1610 GOTO 1710
1700 PRINT"YOU ARE LUCKY**YOU DESTROYED ALL OF THE ENEMY**"
1710 PRINT"WANT TO PLAY AGAIN";
1720 INPUT A$
1730 IF LEFT$(A$,1)="Y" THEN 210
1740 PRINT"HOPE YOU DON'T FEEL FENCED IN."
1750 PRINT"TRY AGAIN SOMETIME"

1720 INPUT A$
1730 IF