R: Morrow Designs Micro-Menu system - Rev 2.3
R: single sided version
R: Module - MDWORK.PIL
R: Copyright 1982, 1983 Morrow Designs, Inc.
R: All Rights Reserved
R: Written by Harrison Schreppel for Morrow Designs
R: Modified by Steve Tai and John VanderWood for NewWord 12/9/83
R:
ESC:*return
CLRS:
R: change this from lower to left depending on the position of drive 
R: A.
DEF:$POSITION left
LF:1
T:                   {CREATE A WORKING DISKETTE}
T:
T:     This  option  creates a  "working  diskette"  for any  of the
T:supplied software.  When done, you will have a diskette  with  all
T:the necessary files  for a particular application  program, and it
T:will be installed for your terminal -- automatically! In addition,
T:your distribution  copies of the software will  be backed-up,  and
T:can be put away for safe keeping.  
T:
T:     You  must  have  a spare diskette for each  of  the  working 
T:diskettes to be created.  The diskette doesn't have to be  blank, 
T:but any information on it will be erased.
T:
T:     Creating  a working diskette requires the use of three  disk 
T:drives. The Micro Decision's unique Virtual Drive feature, allows 
T:you  to create working diskettes regardless of how  many physical 
T:disk drives you actually have.
T:
T:              Press {RETURN} when you're ready to go
T:              Press {ESC} to go back to the main menu
A:
*MAIN
U:*MSG
*SELECT
CLRS:
T: The following is a list of the programs included with your  Micro 
T: Decision. To  create  a working diskette  containing one of these 
T: programs, enter its number after the{OPTION}prompt.
T:
LF:2 
T:   {1}   NewWord
T:   {2}   LogiCalc
T:   {3}   Correct-It
T:   {4}   Personal Pearl
T:   {5}   BaZic
T:   {6}   MBASIC
T: {ESC}   Return to{MAIN MENU}
T:   {R}   To Review instructions
T: 
T: {OPTION}:
*action
cur: 10,15
inmax:1
a:
m: 1 , 2 , 3 , 4 , 5 , 6 , R ,
jn:*action
cur:0,15
M: R ,
JY:*MAIN
CLRS:
M:1
JY:*newWord
M:2
JY:*logicalc
M:3
JY:*correct
M:4
JY:*pearl
M:5
JY:*bazic
M:6
JY:*mbasic

*newWord
T: This operation will create a  NewWord Working Diskette  containing  either
T: the  Novice  or  Advanced  version of NewWord, but not both versions.  You 
T: must select  NewWord  twice from the  Create Working Diskettes menu if you
T: want both versions.   Label the  blank  diskette  "NewWord  Novice Working
T: Diskette" or "NewWord Advanced Working Diskette," whichever is appropriate.
T:
T:
TNR: Press any key to continue ....
a:                  
CLRS:
T:Please select a printer for NewWord:
T:
T: {A}  Simple                            {H}  NEC Spinwriter 2000 series
T: {B}  Draft printer                     {I}  NEC Spinwriter 3500 series
T: {C}  Typewriter printer                {K}  NEC Spinwriter 5500 series
T: {D}  Qume Sprint 11                    {L}  Okidata Microline 84 (step 2)
T: {E}  Silver Reed EXP550                {M}  Okidata models 92/93
T: {F}  Diablo 1610/20/40/50              {N}  Epson MX80/100 & FX80/100
T: {G}  Diablo 630                        {O}  C.Itoh Prowriter
T:                                        
T: {P}  Morrow MP 100/200/300 series      {X}  Do not want to select now
T:                                             or None of the above
T:
*again
CUR:0,13
INMAX:1
A:$ptr
M: A , B , C , D , E , F, G , H , I , K , L , M , N , O , P , X ,
JN:*again

DEF: $STR nh
M:P
DEFy: $STR nh3a'M'P' '1'0'0'/'2'0'0'/'3'0'0' 'p'r'i'n't'e'r0d0a0d0a00.x1
DEFy: $ptr E

M:X
DEFY: $ptr B
CLRS:
T: 
TY: With {X}, your printer is going to be installed as a {DRAFT PRINTER.}
TY: There may be some  printing features  that  will  not  work properly 
TY: unless you reinstall NewWord with the  NWINSTAL. COM program.  Refer 
TY: to the{Nuts & Bolts}section of the NewWord User's Guide for detailed 
TY: instructions on reinstalling NewWord for a specific printer.
TY:
TNRY: Press any key to continue ....
AY:
T:
*loop
CLRS:
T: What NewWord version do you want this Working Diskette to contain ?
T:
T:
CUR:0,3
TNR: Type{A}for Advanced or{N}for Novice: 
a:
M: A , N
T:
jn:*loop
M:A
defy: $OVR OVR
defy: $PROG NWU
defy: $NAME NEWWORD ADVANCED VERSION

defn: $OVR NVC
defn: $PROG NWNOVICU
defn: $NAME NEWWORD NOVICE VERSION

def: $INSTALL NWINSTAL

T:
*uh
CUR:0,6
TNRy: Advanced version selected.  OK ? (Y/N)
TNRn: Novice version selected.  OK ? (Y/N)
A:
M: Y , N
jn:*uh
M:N
jy:*loop
T:
T:
u:*check
u:*format

DEF: $cmmd1 PIP;B:=C:*.COM;B:=C:*.DOC;B:=C:*.$OVR
DEF: $cmmd2 ;;B:NWINSTAL;B:$PROG
DEF: $cmmd3 ;B:NW;AY
DEF: $cmmd4 NBY
DEF: $cmmd5 XXN;ERA B:NWINSTAL.COM;ERA B:$PROG
DEF: $cmmd6 .COM;
c:a=@9 - 2
DEF(a): $ter O
DEF(a): $trstr a'L'e'v'e'l' 'I'I'I' 't'e'r'm'i'n'a'l0d0a00.x
j(a):*lvlnw
c: a=a+1
DEF(a): $ter N
DEF(a): $trstr a'L'e'v'e'l' 'I'I' 't'e'r'm'i'n'a'l0d0a00.x
j(a):*lvlnw
c: a=a+1
DEF(a): $ter R
DEF(a): $trstr a'L'e'v'e'l' 'I' 't'e'r'm'i'n'a'l0d0a00.x
j(a):*lvlnw
T:
T: Your NewWord working diskette will be installed for a{MINIMUM}terminal.
T: Most likely your terminal  will  perform  adequately,  but not at peak 
T: efficiency.  Refer to  {Appendix B}  of the  NewWord Encyclopedia  for
T: detailed instructions on running the installation program  NWINSTAL to
T: enhance the terminal display.
T:
T: Press{RETURN}to create your working diskette of $NAME.
A:
DEF: $ter K
DEF: $trstr a'L'e'v'e'l' '0' 'o'r' 'U'n'i'n's't'a'l'l'e'd' 't'e'r'm'i'n'a'l0d0a00.x
*lvlnw
TNR:}
T:
T: Remember, when you see:
T:
T:      {Your $POSITION drive is being re-assigned as drive C.}
T:      {Exchange diskette and press [RETURN]}
T:
T: You must put the $NAME Distribution Diskette in 
T: the $POSITION drive and press [RETURN].
T:
T: Likewise, when I re-assign the $POSITION drive back to drive A, you
T: then put the CP/M diskette back to the $POSITION drive and press [RETURN].
T:
TNR:{
cpm:$cmmd1$cmmd2$cmmd3$ter$cmmd4$ptr$STR$trstr$cmmd5$cmmd6;
DEF: $PROG NW
J:*complete

*logicalc
def: $PROG LC
def: $NAME LogiCalc
def: $INSTALL LCSET
u: *check
u:*format
TNR:{
c:a=@9 - 2
j(a):*lvl3lc
c: a=a+1
j(a):*lvl2lc
c: a=a+1
j(a):*lvl1lc
u:*levelmsg
cpm:PIP;B:=C:LC*.*;B:=C:BALSHEET.LCF;
j:*complete
*lvl1lc
cpm:PIP;B:termcap.sys=C:termcap1.sys;B:=C:lc*.*;B:=C:balsheet.lcf;;era b:lcset.*;
j:*complete
*lvl2lc
cpm:PIP;B:termcap.sys=C:termcap2.sys;B:=C:lc*.*;B:=C:balsheet.lcf;;era b:lcset.*;
j:*complete
*lvl3lc
cpm:PIP;B:termcap.sys=C:termcap3.sys;B:=C:lc*.*;B:=C:balsheet.lcf;;era b:lcset.*;
j:*complete


*correct
def: $PROG CORRECT
def: $NAME Correct-It
u: *check
u:*format
TNR:{
cpm:PIP B:=C:*.*
j:*corcom


*pearl
clrs:
T:
T: Personal Pearl is a very powerful application program.   In making it so
T: versatile however, the user is faced with what may seem to be an endless
T: installation procedure.   We  have tried to make his procedure as clean,
T: and  straight-forward as possible.   If you follow all the instructions,
T: you should end up with configured working  copies of the  Personal Pearl
T: data base management program.
T:
T: This is a lengthy procedure,  so you  should have at least  half an hour
T: set aside.  If you do  not want to make working copies of Personal Pearl
T: at this time, press {ESC.}
TNR:               To make working copies, press {RETURN} 
A:
clrs:
T:
T: You will need eleven blank diskettes  to make a  working  copy of  Personal
T: Pearl.  First they will all be initialized.  You will then use the Personal 
T: Pearl installation program to make a personalized copy for your use.
T:
T: Before getting started, you should label the eleven diskettes exactly as
T: shown here:
T:
T:	{1}	Pearl disk 1 backup
T:	{2}	Welcome
T:	{3}	Starter Library--Calendar programs
T:	{4}	Starter Library--People programs
T:	{5}	Starter Library--Cash programs
T:	{6}	Sort
T:	{7}	Design Reports
T:	{8}	Design Forms
T:	{9}	File Maintenance
T:	{10}	Enter Data
T:	{11}	Produce Reports
T:
TNR: {After}labeling the diskettes, you should press {RETURN.}
A:
C: a=11
*formatloop
CLRS:
T:
TNR: Insert disk #a in in your upper disk drive, and press {RETURN.}
A:
TNR:{
CPM:FORMAT B D|SYSGEN;A;B;;
C:a=a-1
J(a):*formatloop
CLRS: 
T: Still with me? Good. Let's go!
T:
T: Be sure to follow the instructions, we can't afford mistakes.
T:
*wrong
T: Insert your initialized diskette labelled{Pearl disk 1 backup} in your 
T:{UPPER} disk drive.
T:
T: You will then be told to insert your "SOURCE" diskette in drive A. When
T: this happens, insert the diskette labelled {PERSONAL PEARL DISTRIBUTION
T: DISKETTE ... DISK 1 OF 5} in the {LOWER} disk drive. 
T:
T: The  system will then make  a copy of  the diskette.  When the  copy is
T: complete,  insert your {CP/M SYSTEM DISKETTE} in  your lower drive, and
T: press {RETURN.}
T:
TNR: With your {Pearl disk 1 backup} in your{upper}drive, press {RETURN.}
A:
EXIST:B:WELCOME.COM
JN:*backuppearl
CLRS:
BELL:
T:
T: Sorry, but you put the wrong disk in the {UPPER} disk drive. be sure to
T: read these instructions carefully:
J:*wrong
*backuppearl
TNR:{
cpm:backup|SYSGEN;A;B;;PIP B:=A:RETURN.COM;
CLRS:
T:
T: So far, so good. You will now be put in the hands of Personal Pearl's
T: Personalization program.
T:
T: After telling  Personal Pearl what kind of terminal you have, you will
T: be presented with three choices.  Personalize,  Demonstrate, or  Exit. 
T: Feel free to try the demonstration out. it's sort of a "test drive" if
T: you will. When you have satisfied your curiosity, select the option to
T: Personalize Pearl.  This will allow Personal Pearl to complete the job
T: you so innocently started.
T:
T: You will be using your {Pearl disk 1 backup} disk in your lower drive.
T: Insert it when requested.
T:
TNR: Press{RETURN}to continue.
A:
CLRS:
T:{Have a nice trip.....
TNR:{
CPM:PAUSE WELCOME "Backup"|WELCOME|A:RETURN|
CLRS:
T:
T: I trust you had no major problems. There is now just one step remaining.
T:
T: You will need to insert each of your ten   personalized Pearl  diskettes
T: in  the {UPPER} disk drive one by one.  After placing a  diskette in the
T: disk drive, press{RETURN.}
T:
T: Insert your Welcome disk in the{UPPER} disk drive at this time, and press
TNR:{RETURN.}
U:*copyreturn
T: Insert your Starter Library - Calendar disk in the {UPPER}disk drive, and
T: press {RETURN.}
U:*copyreturn
T: Insert your Starter Library - People disk in the {UPPER}disk drive, and
T: press {RETURN.}
U:*copyreturn
T: Insert your Starter Library - Cash disk in the {UPPER}disk drive, and
T: press {RETURN.}
U:*copyreturn
T: Insert your Sort disk in the {UPPER}disk drive, and press {RETURN.}
U:*copyreturn
T: Insert your Design Reports disk in the {UPPER}disk drive, and press
T:{RETURN.}
U:*copyreturn
T: Insert your Design Forms disk in the {UPPER}disk drive, and press
T:{RETURN.}
U:*copyreturn
T: Insert your File Maintenance disk in the {UPPER}disk drive, and press
T:{RETURN.}
U:*copyreturn
T: Insert your Enter Data disk in the {UPPER}disk drive, and press {RETURN.}
U:*copyreturn
T: Insert your Produce Reports disk in the {UPPER}disk drive, and press
T:{RETURN.}
U:*copyreturn
J:*pearldone

*copyreturn
A:
TNR:{
CPM:PIP B:=A:RETURN.COM;
CLRS:
e:

*pearldone
T:
T: Congratulations! You have completed the Personal Pearl installation.
T:
T: Now is a good time to take a nice, long, well deserved break. I promise
T: that no other supplied software is as slow to install.
T: 
T: If you press{RETURN}, you will find yourself back at the long forgotten
TNR: Working Diskettes Menu.
A:
J:*SELECT


*bazic
def: $PROG BAZIC08
def: $NAME baZic
u: *check
u:*format
TNR:{
cpm:PIP;B:=C:BAZ*.com;B:=C:CRT.002;
def: $PROG BAZIC
j:*complete


*mbasic
def: $PROG MBASIC
def: $NAME MBASIC
u: *check
u:*format
TNR:{
cpm:PIP;B:=C:MBASIC.COM;B:=C:OBASIC.COM;B:=C:RANTEST.BAS;
j:*complete

r:===============================================================
r:Subroutines referenced above
*check
c:a = @8-1
t(a): Place the $NAME distribution diskette in drive C.
j(a):*OVER
t: When your{$POSITION drive}is re-assigned as{drive C,} put in your
t:{$NAME}Distribution Diskette.
t:
t: When the drive is assigned back as{drive A,}put in the{CP/M System}
t:{Diskette.}
*OVER
exist: C:$PROG.com
clrsn:
belln:
tn:You  didn't  put in the right diskette.  We will go  back  and 
tn:review which diskette goes in which drive.
Tn:
CPMN:
Tn:When you are ready to review the instructions, press{[RETURN].}
an:
un:*MSG
jn:*check
t:
t: O.K. you have the correct Distribution Diskette, 
t: press{[RETURN]}to continue ....
a:
e:

*format
CLRS:
C:A=@8
T(A):Place the {SPARE} diskette in drive B (right drive).
J(A):*GO
T: {When the $POSITION drive is re-assigned as drive B,  Be sure to 
T:remove the CPM SYSTEM diskette  and replace it  with the SPARE 
T:diskette.} The SPARE diskette will then be formatted. {Failure 
T:to replace the system diskette will cause it to be erased.}When 
T:the  formatting  is complete, and you get the message that the 
T:drive is being re-assigned as drive A, place the  CP/M  SYSTEM 
T:diskette back in the drive.
*GO
T:Press{[RETURN]}to continue.
A:
TNR:{
CPM:FORMAT B D|
E:


*MSG
C: A=@8-1
U(A):*DRIVE3
E(A):
C:A=A+1
U(A):*DRIVE2
E(A):
U:*DRIVE1
E:

*DRIVE1
CLRS:
T:     You  have  a single drive Micro Decision.  Because of  this, 
T:when  creating  working diskettes,  extensive use of the  Virtual 
T:Drive feature will take place.  You will be instructed at various 
T:times  to  exchange  the  diskette  in  the  drive  with  another 
T:diskette.  It  is very important that you follow the instructions 
T:as they appear on the screen, and place the diskette requested in 
T:the drive.
T:
T:     Whenever I re-assign the drive to be{Drive  A,} 
T: place your{CP/M  SYSTEM  DISKETTE}in the drive.
T:
T:     Whenever I re-assign the drive to be{Drive  B,}
T: place the{SPARE}diskette in the drive.
T:
T:     Whenever I re-assign the drive to be{Drive  C,}
T: place the{DISTRIBUTION}diskette in the drive.
T:
T:     Press{[RETURN]}to continue.
A:
E:

*DRIVE2
CLRS:
T:
T:     You have a dual drive Micro Decision.  Because of this, when 
T:creating working diskettes, {Drive A}will be re-assigned at times 
T:to  become {Drive  C.} It is very important that  you  place  the 
T:correct diskette in the $POSITION drive when it is re-assigned.
T:
T:     Whenever I re-assign the drive to be{Drive A, ($POSITION drive)}
T: place your{CP/M SYSTEM DISKETTE}in the drive.
T:
T:     Whenever I re-assign the drive to be{Drive C, ($POSITION drive)}
T: place  your{DISTRIBUTION}diskette in the drive.
T:
T:     Drive B (right drive) should always have the {SPARE} diskette in it.
T:
TNR:     Press{[RETURN]}to continue.
A:
E:

*DRIVE3
CLRS:
T:
T:Place the {SPARE} diskette in Drive B (upper drive), and place the 
T:appropriate {DISTRIBUTION} diskette in Drive C ($POSITION drive).
T: 
T:Press {[RETURN]} to continue.
A:
E:

*levelmsg
CLRS:
T:
T: You have a {LEVEL 0} terminal. When done creating your working diskette of
T: $NAME, you must run $INSTALL to set up the program for your terminal. 
T:
T: Press {RETURN} to create your working diskette of $NAME.
A:
E:

*corcom
TNR:{
CPM:SYSGEN;A;B;;AUTO *B: $PROG;PIP B:=RETURN.COM;
j:com1

*complete
TNR:{
CPM:SYSGEN;A;B;;AUTO *B: $PROG;PIP;B:=RETURN.COM;B:=PIP.COM;B:=STAT.COM;
*com1
CLRS:
CUR:0,12
T:Function complete.
T:You now have a{$NAME}working diskette. 
T:Put the Distribution copy away for safe keeping.  
T:You shouldn't need it  unless something happens to
T:the working copy you just made.
CUR:0,22
T:Press{RETURN}to go back to the working diskette menu.
inmax:1
A:
J:*SELECT

*return
CLRS:
T:Returning to main menu, please stand by...
ch: micro