R: Morrow Designs Micro-Menu system - Rev 3.5F (1_Aug_84)
R: Module - MDINST.PIL  Special release for MD.5E
R: Copyright 1984 Morrow Designs, Inc.
R: All Rights Reserved
R: Written by John VanderWood 
R:
r: Revised 8_Aug_84 by Namdar Bolour:
r:   1. Run INIT.COM if not using MDT-60/70.
r:   2. Some messages added.
r:   3. Install as MDT-60/70 if Level IV (change install string).
r: Revised 17_Sept_84 by John Zalabak
r:   1. changed 'press any key' to 'press the Return key'
DI:
*SELECT
CLRS:
LF:2
T:         { - I N S T A L L I N G    Y O U R    P R O G R A M S -}
LF: 3
T:   "Installing your software" is traditionally a complex and irritating
T:   process, fraught with dangers for the computer novice.  
T:
T:   That is why Morrow has programmed the MD-5E to install your software 
T:   for you.  The only decision that you  have to make during this phase 
T:   is selecting your printer from a list of popular makes and models.
T:
T:   Some things may whip by on the screen faster than you can read them,
T:   but don't let this bother you.  The screen will "freeze" any crucial 
T:   information and wait for you to press a key before it continues.
LF: 2
T:        {Don't press any  keys on the keyboard  during this whole 
T:         process, unless everything stops and you're specifically 
T:         asked to type something.}
LF: 2
TNR:   Press the Return key to continue:  
INMAX: 1
A:

r:=======================================================================
clrs:
cur: 0, 10
t:         {Are you using either a Morrow MDT-60 or MT-70 terminal?}

*YNPrompt
cur: 50, 12
r: Type blanks to wipe out invalid answer.
t:     
cur: 19, 12
u: YesOrNo
r: Error flag from YesOrNo is 1 if invalid answer.
j(#YNError): *YNPrompt

cpmn:INIT *|

R:===============================================
*NEWWORD
CLRS:
LF:2
T:			  {INSTALLING NEWWORD}
LF: 2
T: Before NewWord  can be installed for your system, you must select your
T: printer type from the list below.  If you are not sure what to choose,
T: talk to your dealer.  If you have no idea how to respond and no-one is
T: around to help, select "2  Draft Printer."
T:
T: {1}  Simple                            {8}  NEC Spinwriter 2000 series
T: {2}  Draft printer                     {9}  NEC Spinwriter 3500 series
T: {3}  Typewriter printer               {10}  NEC Spinwriter 5500 series
T: {4}  Qume Sprint 11                   {11}  Okidata Microline 84 (step 2)
T: {5}  Silver Reed EXP550 (Morrow)      {12}  Okidata models 92/93
T: {6}  Diablo 1610/20/40/50             {13}  Epson MX80/100 & FX80/100
T: {7}  Diablo 630                       {14}  C.Itoh Prowriter
T:                                       {15}  Mannesmann Tally MT-160L
T:
T:                                       {16   Morrow's MP100/200/300 series}

*again
CUR:0,20
T:                                                                        
CUR:0,20
TNR:}Please select your printer and press RETURN: { 
INMAX:3
A: #ptr
M: 1 , 2 , 3 , 4 , 5 , 6 , 7 , 8 , 9 , 10 , 11 , 12 , 13 , 14 , 15 , 16 ,
BELLN:
JN:*again
*again1
CUR: 0,20
TNR:                                                                      
CUR: 0,20
TNR:}You selected printer number{#ptr.} Is that correct?  Type{Y}or{N}:  
INMAX: 1
A:
M:Y,N
BELLN:
JN: *again1
M: N
JY: *again

CASE (#ptr):*1,*DRAFT,*3,*4,*5,*6,*7,*8,*9,*10,*11,*12,*13,*14,*15,*16

*1
DEF: $PRINT byanxn
J: *SELTERM
*2
DEF: $PRINT bybnxn
J: *SELTERM
*3
DEF: $PRINT bycnxn
J: *SELTERM
*4
DEF: $PRINT bydnxn
J: *SELTERM
*5
DEF: $PRINT byenxn
J: *SELTERM
*6
DEF: $PRINT byfnxn
J: *SELTERM
*7
DEF: $PRINT bygnxn
J: *SELTERM
*8
DEF: $PRINT byhnxn
J: *SELTERM
*9
DEF: $PRINT byinxn
J: *SELTERM
*10
DEF: $PRINT byknxn
J: *SELTERM
*11
DEF: $PRINT bylnxn
J: *SELTERM
*12
DEF: $PRINT bymnxn
J: *SELTERM
*13
DEF: $PRINT bynnxn
J: *SELTERM
*14
DEF: $PRINT byonxn
J: *SELTERM
*15
DEF: $PRINT bypnxn
J: *SELTERM
*16
DEF: $PRINT xn
J: *selterm

*SELTERM
c:a=@9-3
j(a):*lvl4nw
c:a=a+1
j(a):*lvl3nw
c:a=a+1
j(a):*lvl2nw
c:a=a+1
j(a):*lvl1nw
C:a=a+1
j(a):*lvl0nw
*lvl4nw
r: Was ayonha.....
def: $TERM aypnha'M'i'c'r'o' 'D'e'c'i's'i'o'n' 'L'e'v'e'l' 'I'V' 'T'e'r'm'i'n'a'l0d0a00xxdiynx
j:*install
*lvl3nw
def: $TERM ayonha'M'i'c'r'o' 'D'e'c'i's'i'o'n' 'L'e'v'e'l' 'I'I'I' 'T'e'r'm'i'n'a'l0d0a00xx
j:*install
*lvl2nw
def: $TERM aynnha'M'i'c'r'o' 'D'e'c'i's'i'o'n' 'L'e'v'e'l' 'I'I' 'T'e'r'm'i'n'a'l0d0a00xx
j:*install
*lvl1nw
def: $TERM ayrnha'M'i'c'r'o' 'D'e'c'i's'i'o'n' 'L'e'v'e'l' 'I' 'T'e'r'm'i'n'a'l0d0a00xx
j:*install
*lvl0nw
def: $TERM ayknha'M'i'c'r'o' 'D'e'c'i's'i'o'n' 'L'e'v'e'l' '0' 'T'e'r'm'i'n'a'l0d0a00xx
j:*install

*DRAFT
CLRS:
LF: 7
T:}  With{2}, your printer is going to be installed as a{DRAFT PRINTER.}
T:   This will be fine for general-purpose printing; however, there may 
T:   be some printing features (like superscripting) that will not work 
T:   unless you reinstall NewWord with the NWINSTAL.COM program.  Refer 
T:   to the{Nuts & Bolts}section of the NewWord User's Guide for details
T:   on reinstalling NewWord for a specific printer.
LF:2
TNR:   Press the Return key to continue: {
INMAX: 1
A:
J: *2

*install
CLRS:
LF: 11
T:}
T:Preparing to install NewWord . . .{
T:Don't press any keys unless I ask you to!}
WAIT:
CPM:nwinstal;nwu;nw;$TERM$PRINT
R: The next lines are the only way I could come up with to branch on a Morrow
R: printer selection; it HAS to be the highest numbered item on the list.
C:b=(#ptr) - 15
J(b):*MPINST
*FLOW
CPM:pip;a:[g1]=practice.doc[r];A:[g1]=sample1.doc[r];a:[g1]=sample2.doc[r];;
CPM:era practice.doc;era sample1.doc;era sample2.doc;era nw.key;ren nw.key=nw2.key;

CLRS:
LF: 9
T:{
T:NewWord is now installed for your terminal and printer.}
T:Your sample documents have been placed in drawer 1
T:of your NewWord filing cabinet (user number 1).
T:{
T:On to BackField . . .}
WAIT:
J: *BACKFIELD

*MPINST
CPM: nwinstal;nw;nw;byenh3a'M'o'r'r'o'w' 'M'P'1'0'0'/'2'0'0'/'3'0'0' 'S'e'r'i'e's' 'P'r'i'n't'e'r0D0A00.xxxn
J: *FLOW

*BACKFIELD
CLRS:
T:}   The next operation creates a {Backfield Working Diskette}from a new, 
T:    blank diskette.   The  working diskette  enables you to rebuild your 
T:    hard disk  in case of the unlikely,  but  conceivable catastrophe of 
T:    wiped-out-data.
T: 
T:    This is possible only if you{BACKUP YOUR HARD DISK FILES ON A REGULAR
T:    BASIS!} We can't overstress the importance of doing so. The Backfield
T:    programs are a very convenient way of doing this. So . . .
T:
T:{        |||||||     /||\     ||||||   ||   ||   ||    ||   |||||||  
T:         ||    ||   //  \\   ||        ||  //    ||    ||   ||    ||   
T:         |||||||   ||||||||  ||        ||||      ||    ||   |||||||    
T:         ||    ||  ||    ||  ||        ||  \\    ||    ||   ||         
T:         |||||||   ||    ||   ||||||   ||   ||    \||||/    ||         
T:
T:         |||||\      /||\     |||   |||     ||    ||   |||  |||  |||
T:         ||   \\    //  \\    |||   |||      \\  //    |||  |||  |||
T:         ||    ||  ||||||||   |||   |||       \|/      \|/  \|/  \|/
T:         ||   //   ||    ||   |||   |||       |||
T:         |||||/    ||    ||   |||   |||||||   |||      |||  |||  |||
LF: 2
TNR:        }Press the Return key when you're sure you've gotten the message: 
INMAX: 1
A:
CLRS:
LF: 10
T:Please insert the{new, blank}diskette into the drive and close the latch.
TNR:Press the Return key when you're ready:    
INMAX: 1
A:
CPM: format b d; pip; B:=restore.com[r]; B:profile.sub=profbak.sub[r];;
CPM: pip; B:=pip.com[r]; B:=setdef.com[r]; B:=format.com[r];; 
CPM: pip; B:=bf?.com[r]; B:=cpm3f.sys[r];; copysys sysldrf.com B:;n;
CPM: pip; B:=copysys.com[r]; B:=sysldr.com[r]; B:=submit.com[r]; B:=suxims.com[r];;
CLRS:
LF:9
T:}
T:Your Backfield diskette is now ready in case 
T:you ever need to restore your whole hard disk.{
LF:2
TNR:Press the Return key to continue: 
INMAX: 1
A:

CLRS:
LF: 10
T:     Okay; Just a few housekeeping chores remain.  You don't have  to do 
T:     anything from here on.  When I'm finished, the "Co-Pilot Main Menu"
T:     should be on your screen, ready to go to work.
WAIT:

cpm: ren startup.pil=init.pil
R: Old Line -> CPM: set *.*[sys]; era hdl1.com; era hdl2.com; era profile.sub;
CPM: set *.*[sys]; era hdl.com; era profile.sub;
CPM: ren profile.sub=prof3.sub; set *.com [ro]; set *.ovr [ro];set *.ovl[ro];
CH: micro.pil

r:========================== Subroutines =================================

r:------------------------------------------------------------------------
r: Subroutine to prompt user for a Y or N answer, and return with match
r: flag set to "yes" if answer was Y, or "no" if answer was N.  In both
r: these cases, the error flag YNError returns set to zero, indicating no
r: error.  If the answer was not Y, y, N, or n, then YNError returns set
r: to one to indicate an invalid answer.

*YesOrNo

inmax: 1
*GetAnswer
tnr:{(Answer Y for Yes, N for No):}
a:
c: YNError = 0

m: Y , y ,
ey:

m: N , n ,
jn: *YNError

r:Set match flag to "no" before return, since response was N.
m: y ,
e:

*YNError
c: YNError = 1
e:

r:*************************** End of Program *************************