mvi	c,aetx
	call	colpt
pwait:	call	ciptr
	cpi	aack
	jnz	pwait
	ret

count:	db	50

;**********************************ontroller (all	*
; revs). Handles diskettes with sector sizes of 128 bytes	*
; single density, 256, 512, 1024 bytes double density.		*
;								*
; Written by Bobby Dale Gifford.				*
; 9/1/79							*
;								*
; Disk Map of sectors used by Cold Boot, Warm Boot, Firmware,	*
; and CP/M:							*
;								*
; trk 0 sec  1 = First sector of cold boot.		e700h	*
;     0      2 = Cold boot 256.				  80h	*
;     0      3 = Cold boot 512.				  80h	*
;     0      4 = Cold boot 1024.			  80h	*
;     0      5 = Warm boot 256.				  80h	*
;     0      6 = Warm boot 512.				  80h	*
;     0      7 = Warm boot 1024.			  80h	*
;     0      8 = Cold/Warm boot.			3200h	*
;     0      9 = Firmware.				e400h	*
;     0     10 = Firmware+80h.				e480h	*
;     0     11 = Firmware+100h				e500h	*
;     0     12 = Firmware+180h.				e580h	*
;     0     13 = Firmware+200h.				e600h	*
;     0     14 = Firmware+280h.				e680h	*
;     0     15 = Firmware+300h.				e700h	*
;     0     16 = Firmware+380h.				e780h	*
;     0     17 = CCP.					2d00
;     0     10 = CCP+80h.				2d80h	*
;     0     12 = CCP+100h.				2e00h	*
;     0     14 = CCP+180h.				2e80h	*
;     0     16 = CCP+200h.				2f00h	*
;     0     18 = CCP+280h.				2f80h	*
;     0     20 = CCP+300h.				3000h	*
;     0     22 = CCP+380h.				3080h	*
;     0     24 = CCP+400h.				3100h	*
;     0     26 = CCP+480h.				3180h	*
;     1        = Rest of CP/M.			  3200h-4fffh	*
;								*
;****************************************************************

	title	'*** Cbios For CP/M Ver. 2.2 ***'

;****************************************************************
;								*
; The following revision number is in reference to the CP/M	*
; 2.0 Cbios. 							*
;								*
;****************************************************************

revnum	equ	31		;Cbios revision number
cpmrev	equ	22		;CP/M revision number

;****************************************************************
;								*
; The following equates relate the Thinker Toys 2D controller.	*
; If the controller is non standard (0E000H) only the ORIGIN	*
; equate need be changed. This version of the Cbios will work	*
; with 2D controller boards rev 0, 1, 3, 3.1, 4.		*
;								*
;****************************************************************

origin	equ	0f800H
djram	equ	origin+400h	;Disk Jockey 2D RAM address
djcin	equ	djram+3h	;Disk Jockey 2D character input routine
djcout	equ	djram+6h	;Disk Jockey 2D character output routine
djhome	equ	djram+9h	;Disk Jockey 2D track zero seek
djtrk	equ	djram+0ch	;Disk Jockey 2D track seek routine
djsec	equ	djram+0fh	;Disk Jockey 2D set sector routine
djdma	equ	djram+012h	;Disk Jockey 2D set DMA address
djread	equ	djram+15h	;Disk Jockey 2D read routine
djwrite	equ	djram+18h	;Disk Jockey 2D write routine
djsel	equ	djram+1bh	;Disk Jockey 2D select drive routine
djtstat	equ	djram+21h	;Disk Jockey 2D terminal status routine
djstat	equ	djram+27h	;Disk Jockey 2D status routine
djerr	equ	djram+2ah	;Disk Jockey 2D error, flash led
djden	equ	djram+2dh	;Disk Jockey 2D set density routine
djside	equ	djram+30h	;Disk Jockey 2D set side routine

;****************************************************************
;								*
; CP/M system equates. If reconfiguration of the CP/M system	*
; is being done, the changes can be made to the following	*
; equates.							*
;								*
;****************************************************************

msize	equ	62
bias	equ	(msize-20)*1024	;Memory offset from 20k system
ccp	equ	2d00h+bias	;Console command processor
bdos	equ	ccp+800h	;BDOS address
bios	equ	ccp+1600h	;CBIOS address
cdisk	equ	4		;Address of last logged disk
buff	equ	80h		;Default buffer address
tpa	equ	100h		;Transient memory
intioby	equ	0		;Initial IOBYTE
iobyte	equ	3		;IOBYTE location
wbot	equ	0		;Warm boot jump address
entry	equ	5		;BDOS entry jump address

;****************************************************************
;								*
;	Some Sol equates					*
;								*
;****************************************************************

solon	equ	0		; enable solos
soloff	equ	1		; disable solos
 
;****************************************************************
;								*
; The following are internal Cbios equates. Most are misc. 	*
; constants.							*
;								*
;****************************************************************

retries	equ	03		;Max retries on disk i/o before error
acr	equ	0dh		;A carriage return
alf	equ	0ah		;A line feed
aetx	equ	3		;A ETX char
aack	equ	6		;A ACK char
clear	equ	0BH		;Clear screen char on SOL  terminal
maxdisk	equ	4		;Maximum # of disk drives
dblsid	equ	8		;Side bit from controller

;****************************************************************
;								*
; The jump table below must remain in the same order, the 	*
; routines may be changed, but the function executed must be	*
; the same.							*
;								*
;****************************************************************

	org	bios		;CBIOS starting address
	;.phase	bios
	jmp	cboot		;Cold boot entry point
wboote:	jmp	wboot		;Warm boot entry point
	jmp	const		;Console status routine
	jmp	conin		;Console input
cout:	jmp	conout		;Console output
	jmp	list		;List device output
	jmp	punch		;Punch device output
	jmp	reader		;Reader device input
	jmp	home		;Home drive
	jmp	setdrv		;Select disk
	jmp	settrk		;Set track
	jmp	setsec		;Set sector
	jmp	setdma		;Set DMA address
	jmp	read		;Read the disk
	jmp	write		;Write the disk
	jmp	listst		;List device status
	jmp	sectran		;Sector translation
djdrv:	jmp	djsel		;Hook for SINGLE.COM program

;****************************************************************
;								*
; Signon message output during cold boot.			*
;								*
;****************************************************************

prompt:	db	acr,alf,alf
	db	'0'+msize/10		;CP/M memory size
	db	'0'+(msize mod 10)
	db	'K CP/M Vers. '		;CP/M version number
	db	cpmrev/10+'0'
	db	'.'
	db	(cpmrev mod 10)+'0'
	db	', Cbios rev '
	db	revnum/10+'0','.'	;Cbios revision number
	db	revnum mod 10+'0'
	db	acr,alf
	db	'For Thinker Toys Disk Jockey 2D Controller '
	db	'@ 0f800h.'
	db	acr,alf,0

;****************************************************************
;								*
; Utility routine to output the message pointed at by H&L,	*
; terminated with a null.					*
;								*
;****************************************************************

mesg:	mov	a,m		;Get a character of the message
	inx	h		;Bump text pointer
	ana	a		;Test for end
	rz			;Return if done
	push	h		;Save pointer to text
	mov	c,a		;Output character in C
	call	cout		;Output the character
	pop	h		;Restore the pointer
	jmp	mesg		;Continue until null reached

;****************************************************************
;								*
; Cboot is the cold boot loader. All of CP/M has been loaded in	*
; when control is passed here.					*
;								*
;****************************************************************

cboot:	lxi	sp,tpa		;Set up stack
	call	tinit		;Initialize the terminal
	lxi	h,prompt	;Prep for sending signon message
	call	mesg		;Send the prompt
	xra	a		;Select disk A
	sta	cpmdrv
	sta	cdisk

;****************************************************************
;								*
; Gocpm is the entry point from cold boots, and warm boots. It	*
; initializes some of the locations in page 0, and sets up the	*
; initial DMA address (80h).					*
;								*
;****************************************************************

gocpm:	lxi	h,buff		;Set up initial DMA address
	call	setdma
	mvi	a,(jmp)		;Initialize jump to warm boot
	sta	wbot
	sta	entry		;Initialize jump to BDOS
	lxi	h,wboote	;Address in warm boot jump
	shld	wbot+1
	lxi	h,bdos+6	;Address in BDOS jump
	shld	entry+1
	xra	a		;A <- 0
	sta	bufsec		;Disk Jockey buffer empty
	sta	bufwrtn		;Set buffer not dirty flag
	lda	cdisk		;Jump to CP/M with currently selected disk in C
	mov	c,a
	lxi	d,cmndbeg	;Beginning of initial command
	lxi	h,ccp+8		;Command buffer
	mvi	a,cmndend-cmndbeg+1 ;Length of command
	sta	ccp+7
	mov	b,a
	call	movlop
	lda	cwflg
	ana	a
	lda	autofl
	jz	cldbot
	rar
cldbot:	rar
	jc	ccp
	jmp	ccp+3		;Enter CP/M

cwflg:	db	0		;Cold/warm boot flag

;****************************************************************
;								*
; The following byte determines if an initial command is to be	*
; given to CP/M on warm or cold boots. The value of the byte is	*
; used to give the command to CP/M:				*
;								*
; 0 = never give command.					*
; 1 = give command on cold boots only.				*
; 2 = give the command on warm boots only.			*
; 3 = give the command on warm and cold boots.			*
;								*
;****************************************************************

autofl:	db	1		;Auto command feature

;****************************************************************
;								*
; If there is a command inserted here, it will be given if the	*
; auto feature is enabled.					*
;	For Example:						*
;								*
;	cmndbeg	db	'MBASIC MYPROG'				*
;	cmndend	db	0					*
;								*
; will execute microsoft basic, and mbasic will execute the	*
; "MYPROG" basic program.					*
;								*
;****************************************************************

cmndbeg:	db	''		;Initial command goes here
cmndend:	db	0

;****************************************************************
;								*
; Wboot loads in all of CP/M except the CBIOS, then initializes	*
; system parameters as in cold boot. See the Cold Boot Loader	*
; listing for exactly what happens during warm and cold boots.	*
;								*
;****************************************************************

wboot:	lxi	sp,tpa		;Set up stack pointer
	mvi	a,1
wflg	equ	$-1		;Test if beginning or
	ana	a		;	ending a warm boot
	mvi	a,1
	sta	wflg
	sta	cwflg		;Set cold/warm boot flag
	jz	gocpm		
	xra	a
	sta	wflg		
	mov	c,a
	call	djdrv		;Select drive A
	mvi	c,0		;Select single density
	call	djden
	mvi	c,0		;Select side 0
	call	djside
	mvi	a,15		;Initialize the sector to read
	sta	newsec
	lxi	h,ccp-100h	;And the DMA address
	shld	newdma
	call	warmlod		;Read in CP/M
	lxi	b,ccp+500h	;Load address for rest of warm boot
	call	djdma
	mvi	c,8
	call	djsec
	call	warmrd
	jmp	ccp+503h

warmlod:	mvi	a,15		;Previous sector
newsec	equ	$-1
	inr	a		;Update the previous sector
	inr	a
	cpi	27		;Was it the last ?
	jc	nowrap
	sui	9		;Yes
	cpi	19
	rz
	lhld	newdma
	lxi	d,-480h
	dad	d
	shld	newdma
nowrap:	sta	newsec		;Save the new sector to read
	mov	c,a
	call	djsec
	lxi	h,ccp-100h	;Get the previous DMA address
newdma	equ	$-2
	lxi	d,100h		;Update the DMA address
	dad	d
	shld	newdma		;Save the DMA address
	mov	b,h
	mov	c,l
	call	djdma		;Set the DMA address
	call	warmrd
	jmp	warmlod

warmrd:	lxi	b,retries*100h+0;Maximum # of errors
wrmread:	push	b
	call	djtrk		;Set the track
	call	djread		;Read the sector
	pop	b
	rnc			;Continue if successful
	dcr	b
	jnz	wrmread		;Keep trying
	jmp	djerr

;****************************************************************
;								*
; Setsec just saves the desired sector to seek to until an	*
; actual read or write is attempted.				*
;								*
;****************************************************************

setsec:	mov	a,c		;Save the sector number
	sta	cpmsec		;CP/M sector #
	ret

;****************************************************************
;								*
; Setdma saves the DMA address for the data transfer.		*
;								*
;****************************************************************

setdma:	mov	h,b		;hl <- bc
	mov	l,c
	shld	cpmdma		;CP/M dma address
	ret

;****************************************************************
;								*
; Home is translated into a seek to track zero.			*
;								*
;****************************************************************

home:	mvi	c,0		;Track to seek to

;****************************************************************
;								*
; Settrk saves the track # to seek to. Nothing is done at this	*
; point, everything is deffered until a read or write.		*
;								*
;****************************************************************

settrk:	mov	a,c		;A <- track #
	sta	cpmtrk		;CP/M track #
	ret

;****************************************************************
;								*
; Sectran translates a logical sector # into a physical sector	*
; #.								*
;								*
;****************************************************************

sectran:	inx	b
	push	d		;Save table address
	push	b		;Save sector #
	call	getdpb		;Get DPB address into HL
	mov	a,m		;Get # of CP/M sectors/track
	ora	a		;Clear cary
	rar			;Divide by two
	sub	c
	push	psw		;Save adjusted sector
	jm	sidetwo
sidea:	pop	psw		;Discard adjusted sector
	pop	b		;Restore sector requested
	pop	d		;Restor address of xlt table
sideone:	xchg			;hl <- &(translation table)
	dad	b		;bc = offset into table
	mov	l,m		;hl <- physical sector
	mvi	h,0
	ret

sidetwo:	lxi	b,15		;Offset to side bit
	dad	b
	mov	a,m
	ani	8		;Test for double sided
	jz	sidea		;Media is only single sided
	pop	psw		;Retrieve adjusted sector
	pop	b
	cma			;Make sector request positive
	inr	a
	mov	c,a		;Make new sector the requested sector
	pop	d
	call	sideone
	mvi	a,80h		;Side two bit
	ora	l		;	and sector
	mov	l,a
	ret

;****************************************************************
;								*
; Setdrv selects the next drive to be used in read/write	*
; operations. If the drive has never been selected before, a	*
; parameter table is created which correctly describes the 	*
; diskette currently in the drive. Diskettes can be of four	*
; different sector sizes:					*
;	1) 128 bytes single density.				*
;	2) 256 bytes double density.				*
;	3) 512 bytes double density.				*
;	4) 1024 bytes double density.				*
;								*
;****************************************************************

setdrv:	mov	a,c		;Save the drive #
	sta	cpmdrv
	cpi	maxdisk		;Check for a valid drive #
	jnc	zret		;Illegal drive #
	mov	a,e		;Test if drive ever logged in before
	ani	1
	jnz	setdr1		;Bit 0 of E = 0 -> Never selected before
	mvi	a,1		;Select sector 1 of track 1
	sta	truesec
	sta	cpmtrk
	call	fill		;Flush buffer and refill
	jc	zret		;Test for error return
	call	djstat		;Get status on current drive
	ani	0ch		;Strip off unwanted bits
	push	psw		;Used to select a DPB
	rar
	lxi	h,xlts		;Table of XLT addresses
	mov	e,a
	mvi	d,0
	dad	d
	push	h		;Save pointer to proper XLT
	call	getdpb		;Get DPH pointer into DE
	xchg			;
	pop	d
	mvi	b,2		;Number of bytes to move
	call	movlop		;Move the address of XLT
	lxi	d,8		;Offset to DPB pointer
	dad	d		;HL <- &DPH.DPB
	push	h
	lhld	origin+7	;Get address of DJ terminal out routine
	inx	h		;Bump to look at address of
				;	uart status location
	mov	a,m		
	xri	3		;Adjust for proper rev DJ
	mov	l,a
	mvi	h,(origin+300h)/100h
	mov	a,m
	ani	dblsid		;Check double sided bit
	lxi	d,dpbs128	;Base for single sided DPB's
	jnz	sideok
	lxi	d,dpbd128	;Base of double sided DPB's
sideok:	xchg			;HL <- DBP base, DE <- &DPH.DPB
	pop	d		;Restore DE (pointer into DPH)
	pop	psw		;Offset to correct DPB
	ral
	ral
	mov	c,a
	mvi	b,0
	dad	b
	xchg			;Put DPB address in DPH
	mov	m,e
	inx	h
	mov	m,d
setdr1:	call	getdpb		;Get address of DPB in HL
	lxi	b,15		;Offset to sector size
	dad	b
	mov	a,m		;Get sector size
	ani	7h
	sta	secsiz
	mov	a,m
	rar
	rar
	rar
	rar
	ani	0fh
	sta	secpsec
	xchg			;HL <- DPH
	ret

zret:	lxi	h,0		;Seldrv error exit
	ret

;****************************************************************
;								*
; Getdpb returns HL pointing to the DPB of the currently	*
; selected drive, DE pointing to DPH.				*
;								*
;****************************************************************

getdpb:	lda	cpmdrv		;Get drive #
	mov	l,a		;Form offset
	mvi	h,0
	dad	h
	dad	h
	dad	h
	dad	h
	lxi	d,dpzero	;Base of DPH's 
	dad	d
	push	h		;Save address of DPH
	lxi	d,10		;Offset to DPB
	dad	d
	mov	a,m		;Get low byte of DPB address
	inx	h
	mov	h,m		;Get low byte of DPB
	mov	l,a
	pop	d
	ret

;****************************************************************
;								*
; Xlts is a table of address that point to each of the xlt	*
; tables for each sector size.					*
;								*
;****************************************************************

xlts:	dw	xlt128		;Xlt for 128 byte sectors
	dw	xlt256		;Xlt for 256 byte sectors
	dw	xlt512		;Xlt for 512 byte sectors
	dw	xlt124		;Xlt for 1024 byte sectors

;****************************************************************
;								*
; Write routine moves data from memory into the buffer. If the	*
; desired CP/M sector is not contained in the disk buffer, the	*
; buffer is first flu