; Patch for DosDisk (CP/M 2.2 version) to correct bug which causes
; dates >= 2001 to be incorrectly represented in the files copied
; to a MSDOS-formatted 5.25" diskette.  The code is correct through
; the year 2000, but represents 2001 as 2029 (!).
; Assemble this to a .HEX file as:
;
;	ZMAC DOSDISK.PAT /H
;	
; then overlay the resulting DOSDISK.HEX onto DOSDISK.COM with MYLOAD
; (or equivalent).  Suggest that the resulting file be renamed as:
;
;	MYLOAD DDTEST.COM=DOSDISK.COM,DOSDISK.HEX
;
; After testing the resulting DDTEST program, you may either rename it
; to DOSDISK.COM, or to another working name of your choosing.
;
; Harold F. Bower, 20 July 2001.
;
; CP/M Standard Equates
;
TPA	EQU	0100H
;
; ----------- Begin Patch File -----------
;
	  ORG  TPA+1B05H
				; was:
	CP	80		;   OR    A
	JR	C,Cent21	;   JR    Z,Cent21
	SUB	100		;   SUB   80
				;   RLA
Cent21:	ADD	A,20		;   LD    D,A
	LD	D,A		;   INC   HL
	INC	HL		;   LD    A,(HL)
	LD	A,(HL)		;   BIT   3,A
	ADD	A,A		;   JR    Z,2$
	ADD	A,A		;   SET   0,D
	ADD	A,A		;2$:AND   00000111B
	ADD	A,A		;   RRA
	LD	E,A		;   RRA
	EX	DE,HL		;   RRA
	ADD	HL,HL		;   RRA
	EX	DE,HL		;   LD    E,A
	NOP			;  --- last byte at TPA+1B1AH ---
	NOP
	NOP
;  --- last byte at TPA+1B1AH ---
;
	END