* DATE 04/27/85  08:30
SKIP -1
STOR code TO code1
STOR author TO author1
STOR title1 TO title11
STOR title2 TO title21
STOR journal TO journal1
STOR publdat TO publdat1
IF *
 STOR 'Deleted' TO deleted1
ELSE
 STOR '       ' TO deleted1
ENDI
SKIP
STOR code TO code2
STOR author TO author2
STOR title1 TO title12
STOR title2 TO title22
STOR journal TO journal2
STOR publdat TO publdat2
IF *
 STOR 'Deleted' TO deleted2
ELSE
 STOR '       ' TO deleted2
ENDI
STOR t TO more
DO WHIL more
 ERAS
 STOR '<C>ontinue, <D>elete/Recall, <E>dit, <P>rint, <Q>uit' TO prompt
 STOR 'Possible Duplicate Records' TO mode
 STOR '?' TO command
 STOR '?' TO record
 @ 00,25 SAY mode
 @ 01,00 SAY '+--------------------'
 @ 01,20 SAY '---------------------'
 @ 01,40 SAY '---------------------'
 @ 01,60 SAY '-------------------+'
 @ 02,05 SAY 'Code:'
 @ 03,03 SAY 'Author:'
 @ 04,02 SAY 'Title 1:''
 @ 06,02 SAY 'Title 2:'
 @ 07,00 SAY 'Jrnl Cite:'
 @ 08,00 SAY 'Publ Data:'
 @ 09,00 SAY '+--------------------'
 @ 09,20 SAY '---------------------'
 @ 09,40 SAY '---------------------'
 @ 09,60 SAY '-------------------+'
 @ 10,05 SAY 'Code:'
 @ 11,03 SAY 'Author:'
 @ 12,02 SAY 'Title 1:'
 @ 14,02 SAY 'Title 2:'
 @ 15,00 SAY 'Jrnl Cite:'
 @ 16,00 SAY 'Publ Data:'
 @ 17,00 SAY '+--------------------'
 @ 17,20 SAY '---------------------'
 @ 17,40 SAY '---------------------'
 @ 17,60 SAY '-------------------+'
 @ 18,17 SAY prompt
 @ 01,67 SAY ' Record-A '
 @ 02,11 SAY code1
 @ 02,67 SAY deleted1
 @ 03,11 SAY author1
 @ 04,11 SAY $(title11,1,60)
 @ 05,11 SAY $(title11,61,60)
 @ 06,11 SAY title21
 @ 07,11 SAY journal1
 @ 08,11 SAY publdat1
 @ 09,67 SAY ' Record-B '
 @ 10,67 SAY deleted2
 @ 10,11 SAY code2
 @ 11,11 SAY author2
 @ 12,11 SAY $(title12,1,60)
 @ 13,11 SAY $(title12,61,60)
 @ 14,11 SAY title22
 @ 15,11 SAY journal2
 @ 16,11 SAY publdat2
 @ 20,24 SAY 'WHAT NEXT?'
 @ 20,35 GET command picture '!'
 READ
 IF command = 'D' .OR. command = 'E' .OR. command = 'P'
  DO WHIL .NOT. (record = 'A' .OR. record = 'B')
   @ 22,24 SAY 'Which Record ' GET record PICTURE '!'
   READ
  ENDD
 ENDI
 IF record = 'A'
  SKIP -1
 ENDI
 DO CASE
 CASE command = 'C' .OR. command = 'Q'
  STOR f to more
 CASE command = 'D'
  IF *
   RECA
  ELSE
   DELE
  ENDI
  IF record = 'A'
   IF deleted1 = 'Deleted'
    STOR '       ' TO deleted1
   ELSE
    STOR 'Deleted' TO deleted1
   ENDI
  ENDI
  IF record = 'B'
   IF deleted2 = 'Deleted'
    STOR '       ' TO deleted2
   ELSE
    STOR 'Deleted' TO deleted2
   ENDI
  ENDI
 CASE command = 'E'
  SAVE TO temp1
  RELE ALL
  REST FROM temp
  DO edit.ref
  SAVE TO temp
  RELE ALL
  REST FROM temp1
  IF record = 'A'
   STOR author TO author1
   STOR title1 TO title11
   STOR title2 TO title21
   STOR auth1  TO auth11
   STOR journal TO journal1
   STOR publdat TO publdat1
   IF *
    STOR 'Deleted' TO deleted1
   ELSE
    STOR '       ' TO deleted1
   ENDI
  ELSE
   STOR author TO author2
   STOR title1 TO title12
   STOR title2 TO title22
   STOR journal TO journal2
   STOR publdat TO publdat2
   IF *
    STOR 'Deleted' TO deleted
   ELSE
    STOR '       ' TO deleted
   ENDI
   STOR deleted TO deleted2
  ENDI
 CASE command = 'P'
  DO print.ref
 ENDC
 IF record = 'A'
  SKIP
 ENDI
ENDD
IF command = 'C'
 STOR t TO more
 ERAS
 @ 07,22 SAY 'Looking for duplicate records'
ENDI