10 REM KAY'S ALGORITHM WITH 1+A AS DISCOUNTING FACTOR
20 DIM V(30), P(30)
30 PRINT
40 PRINT "KAY'S ALGORITHM BY TIMO SALMI"
50 PRINT "WITH 1+A AS DISCOUNTING FACTOR"
60 PRINT
70 PRINT "IDENTIFICATION";
80 INPUT A$
90 PRINT
100 PRINT "GIVE THE NUMBER OF YEARS, AND THE FIRST YEAR   ";
110 INPUT N, M
120 PRINT "GIVE THE BOOK VALUES"
130 FOR I = 1 TO N
140   PRINT M + I - 1; "     ";
150   INPUT V(I)
160 NEXT I
170 PRINT "GIVE THE OPERATING INCOMES"
180 FOR I = 1 TO N
190   PRINT M + I - 1; "     ";
200   INPUT P(I)
210 NEXT I
220 REM SECANT METHOD
230 LET A1 = 0
240 LET A2 = .2
250 FOR I = 1 TO 30
260   LET A = A1
270   GOSUB 430
280   LET F1 = F
290   LET A = A2
300   GOSUB 430
310   LET F2 = F
320   LET A = (A1 * F2 - A2 * F1) / (F2 - F1)
330   LET A1 = A2
340   LET A2 = A
350   LET L = I
360   IF ABS(A2 - A1) < .000001 THEN GOTO 400
370 NEXT I
380 PRINT "ALGORITHM FAILED IN 30 ITERATIONS"
390 END
400 PRINT "ESTIMATED INTERNAL RATE OF RETURN A ="; 100 * A2; "%"
410 PRINT "NUMBER OF ITERATIONS ="; L
420 END
430 REM SUBPROGRAM FOR THE FUNCTION OF SUMS
440 LET F = 0
450 FOR T = 0 TO N - 1
460 LET F = F + (P(T + 1) - A * V(T + 1)) / (1 + A) ^ T
470 NEXT T
480 RETURN
490 END