echo off
cls
echo ------------------------------------------------------------------------------
echo          -- INSTALLATION PROGRAM FOR TURBO PASCAL 6.0 SYSTEM UNIT --
echo             Copyright (c) 1990,1991 by Eagle Performance Software
echo ------------------------------------------------------------------------------
if not exist TURBO.TPL    goto NOLIB
if not exist SYS60.TPU    goto NOTPU
if     exist TPL-EPS.TPL  goto ALREADY
if     exist TPL-BOR.TPL  goto ALREADY
if     exist SYSTEM.TPU   goto CLEANUP
tpumover nul.tpl -nul.tpu >nul
if not errorlevel 1 goto NOMOVER
echo   Making backup copy of TURBO.TPL into TPL-BOR.TPL...
copy turbo.tpl tpl-bor.tpl >nul
echo   Creating new  copy of TURBO.TPL into TPL-EPS.TPL...
copy turbo.tpl tpl-eps.tpl >nul
echo   Deleting Turbo's SYSTEM.TPU...
tpumover tpl-eps.tpl -system
if errorlevel 1 goto BADMOVER1
ren  sys60.tpu system.tpu
echo   Adding Eagle's   SYSTEM.TPU...
tpumover tpl-eps.tpl +system
if errorlevel 1 goto BADMOVER2
del  system.tpu
echo   Installing updated library TURBO.TPL ...
copy tpl-eps.tpl turbo.tpl >nul
echo ------------------------------------------------------------------------------
echo               Installation complete!  Enjoy your faster programs.
echo                 -- Shareware by Eagle Performance Software --
echo ------------------------------------------------------------------------------
goto EXIT

:NOLIB
echo Your TURBO.TPL library cannot be found...
goto HALT
:NOTPU
echo Your SYS60.TPU unit cannot be found...
goto HALT
:NOMOVER
echo Your TPUMOVER.EXE program cannot be found...
goto HALT
:CLEANUP
echo The SYSTEM.TPU has not been moved out of your directory...
goto HALT
:BADMOVER2
ren system.tpu sys60.tpu
:BADMOVER1
echo The TPUMOVER program maybe the wrong version...
echo   Deleting TPL-BOR.TPL and TPL-EPS.TPL...
del tpl-bor.tpl
del tpl-eps.tpl
goto HALT
:ALREADY
echo The library already exists...

:HALT
echo ----------------- The installation has NOT been completed. -------------------

:EXIT