; --- This is WSRUN.WBT (a Batch Builder file that restores a named
;     WorkSpace to the desktop).  WSMAKE.WBT (a Batch Builder file that
;     obtains WorkSpace information, storing it in a private INI file)
;     is paired with WSRUN.WBT to complete WorkSpacer.

; --- WiGuys Software
;     19 Rushbrook Drive,
;     Kitchener, ON N2E 3C1 Canada
;     (519) 745-9717
;     Gregg Hommel, CIS # 72537,552
; --- WorkSpacer is freeware.

; --- Does WSPACE.LIB exist. If not, call WSMAKE.WBT to create it.

WinHide ( "WBT" )
If FileExist ( "wspace.lib" ) Then GoTo start
CallExt ( "wsmake.wbt", "" )
Return

:start         ; choose a workspace
space = TextBox ( "Select a WorkSpace", "wspace.lib" )
If !StrICmp ( space, "" ) == 0 Then GoTo wsname
Message ( "WorkSpacer Warning", "Nothing was selected!" )
GoTo start

:wsname
count = 1
maxrun = 4     ; --- Default for maximum # of applications.

:checkappdata       ; Read WSPACE.INI for app data
getapp = StrCat ( "App", count )
app = IniReadPvt ( space, getapp, "None", "wspace.ini" )
If !StrICmp ( app, "None" ) == 0 Then GoTo readinirest
If count == 1 Then GoTo oops
GoTo fini

:readinirest
getpos = StrCat ( "Pos", count )
pos = IniReadPvt ( space, getpos, "None", "wspace.ini" )
getwin = StrCat ( "Win", count )
winame = IniReadPvt ( space, getwin, "None", "wspace.ini" )

If !WinExist ( winame) Then Run (app, "")     ; Load the app
WinPlace ( %pos%, winame )
If count == maxrun Then GoTo fini
count = count + 1
GoTo checkappdata

:oops          ; Error message
Message ( "Sorry", "The INI file does not list the correct information." )

:fini
Return