Echo off
  CLS
  Echo One moment, please...
  IF "%@%"=="12345678901" goto Env OK
  Ctty NUL:
  Set @=12345678901
  Ctty CON:
  IF "%@%"=="12345678901" goto Env OK
  IF NOT "%@%"=="12345678901" %COMSPEC% /c %0 %1 %2 %3
  goto EXIT

:Env OK
  Set @=
  Set XD=C:
  Set XF=A:
  IF NOT "%1"=="?" GoTo Check parm
  Echo.
  Echo %0.BAT will copy BMW to your fixed disk drive.

:Syntax
  Echo.
  Echo To use %0.BAT:
  Echo.
  Echo Type:       %0 c: FROM a:
  Echo.
  Echo Where c: is your fixed disk drive letter (usually C:), 
  Echo   and a: is your floppy disk drive letter (usually A: or B:).
  Echo.
  Echo and press [ENTER].
  Echo.
  GoTo Exit

:Check parm
  IF NOT "%1"=="" SET XD=%1
  IF "%2"=="" GoTo Ready to Copy
  Set XF=%2
  For %%w in (from FROM From fROM) do if "%2"=="%%w" set XF=F
  IF %XF%==F IF "%3"=="" goto Syntax
  IF %XF%==F SET XF=%3
  For %%d in (a A b B c C d D e E f F g G h H i I) do if "%XF%"=="%%d:" GoTo Ready to copy
  For %%d in (j J k K l L m M n N o O p P q Q r R) do if "%XF%"=="%%d:" GoTo Ready to copy
  For %%d in (s S t T u U v V w W x X y Y z Z    ) do if "%XF%"=="%%d:" GoTo Ready to copy
  Echo %XF% - parameter not recognized.
  GoTo Syntax

:Ready to Copy
  Echo.
  Echo Copying files from %XF% to %XD%\BMW
  Echo Press SPACEBAR to continue, or CONTROL-C to stop.
  Echo (Press CONTROL-C and use "%0 ?" for more information.)
  pause > NUL:
  Echo.
  Ctty NUL:
  IF NOT EXIST %XD%\BMW\*.* MkDir %XD%\BMW
  Ctty CON:
  Copy %XF%BMW.* %XD%\BMW
  IF EXIST %XD%\BMW\BMW.TLB GOTO FINI

:Error while copying
  Echo.
  Echo Error copying to %XD%\BMW directory!
  Echo There is probably not enough room on the disk.
  Echo.
  Echo Installation not completed.
  Goto EXIT

:FINI
  Echo.
  Echo To run the program:
  Echo     1. Type   %XD%		and press ENTER.
  Echo     2. Type   CD \BMW		and press ENTER.
  Echo     3. Type   BMW		and press ENTER.
  Echo.

:EXIT
  Set XD=
  Set XF=
  Set @=