@echo off
   set VCSPEC=
   set VCRESP=
   cls
   md 4DVCDLET >&! NUL
   @del /qy 4DVCDLET\*.* >&! NUL
:TESTPARMS
   if "%1" EQ "" goto WRAPUP
   iff not exist 4DVC%1.ZIP then
      shift
      goto TESTPARMS
   endiff
   for %%Z in (4DVC%1.zip) do gosub LOOP
   shift
   goto TESTPARMS
:WRAPUP
   iff not exist 4DVCDLET\4DVCDLET.0    then
      cls
      echo 4DVCDLET: No archive files found with extensions provided.
      pause
   endiff
   @del /qy 4DVCDLET\*.* >&! NUL
   rd 4DVCDLET >&! NUL
   cls
   quit
rem *******************************************************************
rem
rem Loop to obtain all entries in the .ZIP file and their descriptions
rem
rem At end of loop, the SELECT command is processed against the files.
rem
rem *******************************************************************
:LOOP
   cls
   echo Processing archive file %@upper[%Z]. Please wait a moment.
   pkzip -q-vcbn %Z >&! 4DVCDLET\4DVCDLET.0
   set VCRCD=8
   gosub LOOPTOP
   return
:LOOPTOP
   if %@len[%@line[4DVCDLET\4DVCDLET.0,%VCRCD]] EQ 0 goto LOOPEND
   if "%@substr[%@line[4DVCDLET\4DVCDLET.0,%VCRCD],1,6]" EQ "------" goto LOOPIN
:LOOPOUT
   set VCRCD=%@eval[%VCRCD + 1]
   goto LOOPTOP
:LOOPIN
   set VCRCD=%@eval[%VCRCD + 1]
   if "%@substr[%@line[4DVCDLET\4DVCDLET.0,%VCRCD],1,6]" EQ "------" goto LOOPOUT
   set VCNAM=%@substr[%@line[4DVCDLET\4DVCDLET.0,%VCRCD],46,12]
   set VCRCD=%@eval[%VCRCD + 1]
   set VCCOM=%@substr["%@line[4DVCDLET\4DVCDLET.0,%VCRCD]                                                   ",10,41]
   echo %Z >&! 4DVCDLET\%VCNAM
   describe 4DVCDLET\%VCNAM "%VCCOM"
   set VCCOM=
   set VCNAM=
   goto LOOPIN
:LOOPEND
   set VCRCD=
   except (4DVCDLET\4DVCDLET.0) iff filesize 4DVCDLET\*.* GT 3 then
      keystack !
      except (4DVCDLET\4DVCDLET.0) select /Or call 4DVCDLT2 (4DVCDLET\*.???)
      keystack 00
      except (4DVCDLET\4DVCDLET.0) @del /qy 4DVCDLET\*.* >&! NUL
   else
      echo No files found in archive %@upper[%Z]. If you think this is
      echo an error, try running PKZIP -q-vcbn %Z manually from the
      echo command line. If there are files present, then there is some
      echo problem writing to your disk (password/write protection, not
      echo enough space, etc.). Resolve the problem and try again.
      pause
      cls
   endiff
   return