*
* FILE:  BIGFIND.QM  --   "Big Find":  Find all instances of a given
*                         string, and let the user select one and hit
*                         return.  Uses DOS's FIND, or other search utility.
* Author:   Tim Farley
* Written:  8/21/89
* Revised:  9/6/89    (Separate macro for each find utility).
*
* (1) Pick one of the three macros below, based on which search program you
*     use.  Delete the other two.
*
*       ^f5  MS/PC-DOS's own FIND command
*       ^f6  Chris Dunford's FGREP, available free on BBS's
*       ^f7  Borland's Turbo GREP (comes with Turbo Pascal, Assembler and C)
*            or Microsoft's MEGREP (comes with Microsoft language products)
*
* (2) Use QMAC to convert this file to a QEdit binary macro:
*
*       QMAC BIGFIND.MAC BIGFIND.QM B N
*
* (3) Then load BIGFIND.MAC into QEdit (using MacroRead or /L) to use this.

* Control-F5 uses DOS's FIND command.  Its output looks like this:
*
* ---------- D:\PATH\FILENAME.EXT
* [xx]actual line of text
*
^f5  MacroBegin UnMarkBlock DropAnchor                                       &
     EditFile 'FIND.OUT' Return KillFile Quit GotoBlockBeg UnMarkBlock       &
     Dos 'FIND /N "' Pause '" >FIND.OUT ' CurrentFilename Return Return      &
     EditFile Return Pause BegLine CursorRight                               &
     MarkWord Copy Quit GotoLine Paste Return MakeCtrOfScreen

* Control-F6 uses Chris Dunford's FGREP.  Its output looks like this:
*
* **File d:\path\FILENAME.EXT
*     xx: actual line of text
*
* (Chris Dunford's FGREP is available for free, including from
*  SemWare's BBS at (404) 641-8968.  Look for FGREP170.ZIP.).
*
^f6  MacroBegin UnMarkBlock DropAnchor                                       &
     EditFile 'FIND.OUT' Return KillFile Quit GotoBlockBeg UnMarkBlock       &
     Dos 'fgrep -l "' Pause '" >FIND.OUT ' CurrentFilename Return Return     &
     EditFile Return Pause BegLine WordRight                                 &
     MarkWord Copy Quit GotoLine Paste Return MakeCtrOfScreen

* Control-F7 uses Borland Turbo GREP, or any search utility that
*    produces "Unix style" output, which looks like this:
*
* D:\PATH\FILENAME.EXT   xx      actual line of text
*
* For Microsoft's MEGREP, replace 'grep -o+n+r- "' below with 'megrep "'.
* If you use another grep, you may need different command line switches.
*
^f7  MacroBegin UnMarkBlock DropAnchor                                       &
     EditFile 'FIND.OUT' Return KillFile Quit GotoBlockBeg UnMarkBlock       &
     Dos 'grep -o+n+r- "' Pause '" >FIND.OUT ' CurrentFilename Return Return &
     EditFile Return Pause                                                   &
     BegLine Find ' ' Return 'I' Return WordRight                            &
     MarkWord Copy Quit GotoLine Paste Return MakeCtrOfScreen

*
* EOF: BIGFIND.QM