*
* QASCII.QM  --  QEdit macros to implement an ASCII chart in QEdit 2.08
*
* Author:  Tim Farley
* Date:    28-Aug-1989
*
* INSTRUCTIONS:  Convert this file to a QEdit loadable macro file with QMAC:
*
*                QMAC QASCII.MAC QASCII.QM B N
*
*                Then load QASCII.MAC into QEdit using MacroRead or /L, and
*                use the keys as indicated below.
*
*
* NOTES:   (1) The QASCII.LST file can be free form, but it should have
*              ONE ascii character per line, and the character itself should
*              appear between parentheses, like this: (*).  The rest of the
*              line can contain anything you like: other representations of
*              that character, numeric conversions, etc.
*          (2) In the macros below, be sure to edit 'QASCII.LST' to reflect
*              the full path specification to your ASCII chart on your disk.
*          (3) You could add both of these to your QCONFIG.DAT file.  This
*              would make them a permanent part of your Q.EXE, always at
*              the ready.
*          (4) You might want to mark your ASCII chart read-only in DOS to
*              prevent accidentally editing it while using these macros.
*          (5) These macros absolutely require QEdit 2.08 (or QEdit for OS/2)
*              to operate correctly.
*
*
* Control-F2 will bring up the QASCII.LST file in a window below the current
*            one, with the current character highlighted.
*
^f2 MacroBegin UnMarkBlock DropAnchor DropAnchor Copy DropAnchor DropAnchor HorizontalWindow EditFile BegLine DelToEol 'QASCII.LST' Return BegFile BegLine Find '(' Paste ')' Return ' ' Return CursorRight DropAnchor MakeCtrOfScreen PrevWindow

*
*
* Control-F3 is a variation:  it will bring the description of the character
*            under the cursor up onto the screen in a "box" near the cursor
*            line.  The user can press Return or Escape to continue editing.
*
* NOTE:  This macro is near maximum length for QCONFIG.  Take care editing it.
*
^f3 MacroBegin UnMarkBlock DropAnchor Copy HorizontalWindow EditFile BegLine DelToEol 'QASCII.LST' Return BegFile BegLine Find '(' Paste ')' Return ' ' Return BegLine CursorRight DropAnchor GotoColumn '61' Return Copy CloseWindow Find Paste Pause Escape

*
*
* Control-F4 is the reverse:  bring up the ASCII chart, move the cursor to
*            the character you want, press RETURN, and that character will
*            be inserted into the original file.  The user can also press
*            Escape to abort.
*
^f4 MacroBegin HorizontalWindow EditFile BegLine DelToEol 'QASCII.LST' Return GotoLine '6' Return GotoColumn '24' Return Pause GotoColumn '24' Return UnMarkBlock DropAnchor Copy CloseWindow Paste UnMarkBlock CursorRight

*
* EOF: QASCII.QM