'LIGHTS.DAT
'==========
'essentials as always
INPUT,  see03.sc1
OUTPUT, test.sc1
DIR

'Here we'll discuss the elementary aspects of sticking lights in
'your scenery.  First we cover road lighting:

'From the coloring  discussion we learned among other things how to
'add dusk/night coloring to roads and lines.  Reviewing this:

FIND, COLOR, 12         
COLOR, 12, 4, 13       
LINE                   

FIND, COLOR, 12      
COLOR, 12, 4, 13      
ROAD                 

'But now let's say we wanted the roads (or lines that represent roads)
'to show up as lights at night.  We can add a command to do this:

LIGHTS
COLOR, 5, 10, 0
FIND, COLOR, 5
ROAD

'This tells SEE to locate all light gray (color code = 5) roads
'and give them dusk colors but instead of the night color rendition
'depict these roads as a string of yellow lights (the night color
'code doesn't apply here and can be anything) at night. If the
'you want the lights to be a different color you may change it
'using the LIGHTCOLOR command.

'Lines work the same way:

LIGHTS
LIGHTCOLOR,4
FIND, COLOR, 0
COLOR, 15, 5, 10
LINE

'This converts all black lines into white lines at day;
'light gray lines at dusk; and orange lights at night.

'If you leave out the COLOR statement then the dusk color will
'be set according to the current settings in the color map.
LIGHTS
FIND, COLOR, 3
LINE

'You may control the spacing between lights using the DOTS
'command (larger values mean larger spaces -- experiment!):

DOTS,300
FIND, COLOR, 10
LIGHTS
ROAD


'Runway and taxiway lighting
'But remember that lines will not show through runways so another
'twist to this procedure is required to do runway lighting and
'taxiways.  Draw your lines where you want them (down the center
'of a runway, for example) using ASD.  The will of course immediately
'disappear upon exiting the editor; covered by the runway (but they
'are there).  Then do the following in your DAT file:

COLOR, 9, 9, 9
FIND, COLOR, 9
TAXI

'(This isn't part of the lesson but it helps to darken the runway
'at non-day to see the lights; so here's how:)
FIND, ALL
RUNWAY

'Tip: if you don't want your lights to show at all during the day
'when using TAXI just add the command
DAYOFF
'and you'll just get the lights at dusk and night
COLOR, 6, 6, 6
FIND, COLOR, 6
TAXI


'OK; that's enough for this lesson. 
SAVE
END

Discussion:  SEE will normally only alter something once.  Therefore if
your first set of commands changes ALL the lines to have dusk and night
colors, you are not going to be able to then change all the blue lines to
taxiway lights (because as far as SEE's concerned there are no longer
'any (pure) blue lines to change.  So the moral of this story is that you
must do the most specific changes first before doing the general ones.