10 ' ANITRA = Music          from  P. Fraundorf         2/83
20 ' anitra.bas: Anitra's Dance from "Peer Gynt" by Edvard Grieg
30 CLS
40 LOCATE 12,30
50 PRINT "A N I T R A ' S   D A N C E"
60 PRINT
70 PRINT
80 PRINT
90 ' ----------------------define manuscript phrases----------------------
100 A$ = "MLO5e2. e4p2 MSO1a4O3c4dd O1a4O3e4ff O1a4O3e4dd O1a4O3c4"
110 B1$ = "O3e4 MLa64b64a16.MSg#abO4cd MLeae4Xtd$; cac4O3Xtb$; MNa2p4"
120 B2$ = "MLaO4cO3a4Xtg$; f#O4cO3MNf#2 MLfO4cO3f4Xte$; d#bMNd#2"
130 B3$ = "MSba#f#baf bg#ebgd# bf#dbfc# becbd#O2b"
140 B4$ = "MLO3e64f#64e16.MSd#ef#ga bO4eO3bagf# ef#gab4 O4e4p4"
150 B$ = B1$ + B2$ + B3$ + B4$
160 C1$ = "MLf4.MNeMLeMNd MLd4.MNeMLeMNf f2. MSe4p2 p8O3fdcO2bMLO3f"
170 C2$ = "MSdcO2bO3dO2ba g#MLO3dMSO2bag#b g#fedcO1b"
180 C3$ = "O4MLb-4.MNaMLaMNg MLg4.MNaMLaMNb- b-2. MSa4p2 p8O3b-gfeMLb-"
190 C4$ = "MSgfeged c#MLgMSedc#e c#O2b-agfe"
200 C$ = C1$ + C2$ + C3$ + C4$
210 D1$ = "MSO2d4O3f#4g4 O2d4O3a4b4 O2d4O3a4a4 O4d64e64d16.c#def#g"
220 D2$ = "MLaO5dO4a4Xtg$; f#O5dO4f#4Xte$; MNd2."
230 D3$ = "MSO2d4O3f4g4 O2d4O3a4b-4 O2d4O3a4a4 O4d64e64d16.c#defg"
240 D4$ = "MLaO5dO4a4Xtg$; fO5dO4f4Xte$; MNd2."
250 D$ = D1$ + D2$ + D3$ + D4$
260 E1$ = "MSO1d-O2e-aO3cfO4c MLf64g64f16.MSefgab- MLO5cfcMSO3gab-"
270 E2$ = "MLO4cfc2 MSO1fO2f#aO3ceO4e MLa64b64a16.MSg#abO5cd"
280 E3$ = "MLeaeMSO3bO4cd MLeae2 MSO1bO2bO3d#f#ab MLO4f#64g64f#16.MSff#gab"
290 E$ = E1$ + E2$ + E3$
300 F1$ = "MLO5cO4cf#MSO3g#ab MLO4cO3cf#2 MSO1eO2eg#bO3de"
310 F2$ = "T=T2; MLb64O4c64O3b16.MSa#bO4cde"
320 F3$ = "T=T3; MLfO3fbMScde T=T4; MLfO2fb4MNO3e4"
330 F$ = F1$ + F2$ + F3$
340 G1$ = "T=T1; MLa64b64a16.MSg#abO4cd MLeae4Xtd$; cec4O3Xtb$; MNa2."
350 G2$ = "MLO4aO5cO4a4Xtg$; f#O5cO4f#2 fO5cO4f4Xte$; d#bd#2 dfd4Xtc$;"
360 G3$ = "O3bO4fO3b2 b-O4fo3b-4Xta$; g#O4eO3g#2 MSO4ed#O3bO4edO3b-"
370 G4$ = "O4ec#O3aO4ecO3g# O4eO3bgO4eO3a#f# O4eO3afO4eO3g#e"
380 G$ = G1$ + G2$ + G3$ + G4$
390 H$ = "MLa64b64a16.MSg#abO4cd eaedcO3b abO4cde4 a4p4"
400 ' -------------------define qtr-note trill substrings------------------
410 TA$ = "a16b32a32b32a32b32a32"
420 TB$ = "b16O4c32O3b32O4c32O3b32O4c32O3b32"
430 TC$ = "c16d32c32d32c32d32c32"
440 TD$ = "d16e32d32e32d32e32d32"
450 TE$ = "e16f32e32f32e32f32e32"
460 TG$ = "g16a32g32a32g32a32g32"
470 ' ----------------------------determine tempo--------------------------
480 INPUT "tempo (80-255 qtr notes/min, rtn=160)";T1
490 IF T1 = 0 THEN T1 = 160
500 T2 = .8 * T1
510 T3 = .6 * T1
520 T4 = .4 * T1
530 ' ----------------------------play the dance---------------------------
540 I$ = "p4"
550 PLAY "T=T1; L8"
560 PLAY A$
570 PLAY B$
580 PLAY B$ + "p4"
590 FOR I = 1 TO 2
600   PLAY C$
610   PLAY D$
620   PLAY E$
630   PLAY F$
640   PLAY G$
650   PLAY H$
660   PLAY I$
670   I$ = "O1E4 O0A4P2 MLO4A2. A4"
680 NEXT
690 PRINT " Play it again? (Y/N) ";
700 ANS$ = INPUT$(1)
710 IF ANS$ = "Y" OR ANS$ = "y" THEN 480