10 REM  ====>  IBM-PC JUKEBOX -- MAIN PROGRAM
20 SCREEN 0,1: WIDTH 80: COLOR 7,0,1: KEY OFF: LOCATE ,,0: CLS
30 GOSUB 690: REM  ====>  PROGRAM TITLE
40 GOSUB 230: REM  ====>  MENU OUTLINE
50 COLOR 15: LOCATE 13,3: PRINT "===> SELECTION:    <===";
60 SONG$=INKEY$: IF SONG$="" THEN 60
70 COLOR 23: LOCATE 13,20: PRINT SONG$;: COLOR 7
75 IF SONG$="G" OR SONG$="g" THEN GOTO 210: 'END PROGRAM
80 GOSUB 550: REM  ====>  KEYBOARD
90 IF SONG$="A" OR SONG$="a" THEN CHAIN "JUKEDOWN.MUS"
100 IF SONG$="B" OR SONG$="b" THEN CHAIN "JUKEGARO.MUS"
110 IF SONG$="C" OR SONG$="c" THEN CHAIN "JUKESATI.MUS"
120 IF SONG$="D" OR SONG$="d" THEN CHAIN "JUKESOUN.MUS"
130 IF SONG$="E" OR SONG$="e" THEN CHAIN "JUKECARA.MUS"
140 IF SONG$="F" OR SONG$="f" THEN CHAIN "JUKEIMPO.MUS"
150 IF SONG$="G" OR SONG$="g" THEN GOTO 210: 'END PROGRAM
160 IF SONG$="H" OR SONG$="h" THEN CHAIN "JUKESUNR.MUS"
170 IF SONG$="J" OR SONG$="j" THEN GOTO 210: 'CHAIN "JUKEMOON.MUS"
180 IF SONG$="K" OR SONG$="k" THEN CHAIN "JUKESECO.MUS"
190 IF SONG$="L" OR SONG$="l" THEN CHAIN "JUKETHIR.MUS"
200 IF SONG$="M" OR SONG$="m" THEN CHAIN "JUKETAKE.MUS"
210 CLS:GOTO 20
220 REM  ====>  MENU OUTLINE
230 COLOR 7
240 LOCATE 1,1: PRINT CHR$(201)+STRING$(25,205)+CHR$(203)+STRING$(25,205)+             CHR$(203)+STRING$(25,205)+CHR$(187);
250 FOR R=2 TO 11: C=1: FOR K=1 TO 4
260 LOCATE R,C: PRINT CHR$(186);: C=C+26
270 NEXT: NEXT
280 LOCATE 12,1: PRINT CHR$(200)+STRING$(25,205)+CHR$(202)+STRING$(25,205)+            CHR$(202)+STRING$(25,205)+CHR$(188);
290 GOSUB 340: REM  ====>  CLASSICAL SELECTIONS
300 GOSUB 410: REM  ====>  MUSICAL SELECTIONS
310 GOSUB 480: REM  ====>  POPULAR SELECTIONS
320 RETURN
330 REM  ====>  CLASSICAL SELECTIONS  (A-H)
340 COLOR 7: LOCATE 2,11: PRINT "POPULAR": COLOR 7
350 LOCATE 4,3: PRINT "A -- Downtown"
360 LOCATE 6,3: PRINT "B -- Garota de Ipanema"
370 LOCATE 8,3: PRINT "C -- Satisfaction"
380 LOCATE 10,3: PRINT "D -- Sounds of Silence"
390 RETURN
400 REM  ====>  MUSICAL SELECTIONS  (J-R)
410 COLOR 7: LOCATE 2,37: PRINT "MUSICAL": COLOR 7
420 LOCATE 4,29: PRINT "E -- Cabaret"
430 LOCATE 6,29: PRINT "F -- Impossible Dream"
440 LOCATE 8,29: PRINT "G -- Return Main Menu"
450 LOCATE 10,29: PRINT "H -- Sunrise, Sunset"
460 RETURN
470 REM  ====>  POPULAR SELECTIONS  (S-Z)
480 COLOR 7: LOCATE 2,60: PRINT "MISCELLANEOUS": COLOR 7
490 LOCATE 4,55: PRINT "J -- Moonlight Sonata"
500 LOCATE 6,55: PRINT "K --    second movement"
510 LOCATE 8,55: PRINT "L --    third movement"
520 LOCATE 10,55: PRINT "M -- Take Five"
530 RETURN
540 REM  ====>  KEYBOARD
550 COLOR 15
560 FOR K=1 TO 38: FOR R=15 TO 23
570 LOCATE R,2*K: PRINT CHR$(222)+CHR$(219);
580 NEXT: NEXT
590 COLOR 7,0
600 FOR K=1 TO 37: FOR R=15 TO 19
610 IF (K MOD 7)=2 OR (K MOD 7)=5 THEN 630
620 LOCATE R,2*K+1: PRINT CHR$(221)+CHR$(32);
630 NEXT: NEXT
640 COLOR 7,0
650 LOCATE 25,2: FOR O=1 TO 5: PRINT " A B C D E F G";: NEXT: PRINT " A B C";
660 COLOR 7
670 RETURN
680 REM  ====>  PROGRAM TITLE
690 COLOR 7
700 LOCATE 14,1: PRINT CHR$(201)+STRING$(77,205)+CHR$(187);
710 FOR R=15 TO 23
720 LOCATE R,1: PRINT CHR$(186);: LOCATE ,79: PRINT CHR$(186);
730 NEXT
740 LOCATE 24,1: PRINT CHR$(200)+STRING$(77,205)+CHR$(188);
750 COLOR 7,0
760 FOR I=1 TO 64
770 R=15+(8.5*RND-.49999): C=3+(73.5*RND-.49999)
780 LOCATE R,C: PRINT CHR$(14);
790 NEXT
800 COLOR 7,0
810 LOCATE 18,23: PRINT CHR$(32)+CHR$(201)+STRING$(31,205)+CHR$(187)                   +CHR$(32);
820 LOCATE 19,23: PRINT CHR$(32)+CHR$(186)+" I B M - P C   J U K E   B O X "           +CHR$(186)+CHR$(32);
830 LOCATE 20,23: PRINT CHR$(32)+CHR$(200)+STRING$(31,205)+CHR$(188)                   +CHR$(32);
840 COLOR 7,0
850 RETURN