@echo off
;Copyright 1990, 1991 Steve Waskow
cls
echo Prepare to print the ALLY documentation to printer port PRN (LPT1) by:
echo.
echo   1. Making sure that you have at least 35 pages of paper in your printer.
echo   2. Check that your printer is on line and the paper is properly aligned.
echo   3. To use the DOS PRINT.COM program for background printing, you must
echo      install it first, otherwise the DOS copy command is used for printing.
echo   4. To print on laser or inkjet printers which require a 60 lines per page
echo      format, or on a printer which cannot print the IBM extended characters
echo      used to draw lines and borders, or to substitute hard form feeds instead
echo      of blank lines for the bottom boarder, run the DOCFMT program first. It
echo      will create a special version of ALLY.DOC named ALLY.FMT, formatted to
echo      your needs.  If ALLY.FMT exists, it is printed rather than ALLY.DOC.
echo.
echo If you're not ready, press Ctrl-C and terminate the batch job, otherwise
pause
echo.
if not exist ISPRINT.EXE goto UseCOPY
;ISPRINT.EXE returns ERRORLEVEL 1 if PRINT.COM is not installed
IsPrint
if errorlevel 1 goto UseCOPY
echo Using the DOS PRINT command to print documentation.
if exist ALLY.FMT goto prnFmtP
  echo Submitting ALLY.DOC ...
  print ALLY.DOC >nul
  echo Submitting READ.ME ...
  print READ.ME >nul
  echo Submitting WHATS.NEW ...
  print WHATS.NEW >nul
  echo Submitting VENDOR.DOC ...
  print VENDOR.DOC >nul
  echo Submitting REGISTER.NOW ...
  print REGISTER.NOW >nul
  goto finP
:prnFmtP
  echo Submitting ALLY.FMT ...
  print ALLY.FMT >nul
:finP
  echo All documents are queued for printing.
  goto end
:UseCopy
echo Using the DOS COPY command to print documentation, please wait...
if exist ALLY.FMT goto prnFmtC
  echo Printing ALLY.DOC ...
  copy ALLY.DOC prn >nul
  echo Printing READ.ME ...
  copy READ.ME prn >nul
  echo Printing WHATS.NEW ...
  copy WHATS.NEW prn >nul
  echo Printing VENDOR.DOC ...
  copy VENDOR.DOC prn >nul
  echo Printing REGISTER.NOW ...
  copy REGISTER.NOW prn >nul
  goto finC
:prnFmtC
  echo Printing ALLY.FMT ...
  copy ALLY.FMT prn >nul
:finC
  echo Document printing is completed.
:end