**************************************************************************
*** Program:.... APP_PDWN.PRG:  Application's Pulldown Menus
*** Updated:.... April 3, 1991
*** Programmer:. R. Paulk 
*** Notice:..... Copyright (c) Ingenuity, Inc., 1990
****************************************************************************
PARAMETER pdn_key
cur_prg = IIF(pdn_key = -99, "", cur_prg)
pdn_actnx = pdn_actn
mnu_pdmax = 10
DO WHILE pdn_key <> 0 .OR. EMPTY(pdn_actn)
  SETCOLOR(sys_unsl)
  @ 00, 00 SAY  "  Next   Apps   Ency   Docs    Test    Source    Data   Locate   Tags   System  "
  SAVE SCREEN TO box_mnu
  CTR_STR(23, "", sys_menu)
  mnu_pdnew = mnu_pulldn
  menu_title = "Primary System Functions Menu"
  *  Next   Apps   Ency   Docs    Test    Source    Data   Locate   Tags   System"
  @ 00, 02 PROMPT "Next"
  @ 00, 09 PROMPT "Apps"
  @ 00, 16 PROMPT "Ency"
  @ 00, 23 PROMPT "Docs"
  @ 00, 31 PROMPT "Test"
  @ 00, 39 PROMPT "Source"
  @ 00, 49 PROMPT "Data"
  @ 00, 56 PROMPT "Locate"
  @ 00, 65 PROMPT "Tags"
  @ 00, 72 PROMPT "System"
  KEYBOARD CHR(13)
  MENU TO mnu_pulldn
  SET KEY 22 TO pdn_ins     && Ins Key
  SET KEY 19 TO pdn_left    && Left Arrow
  SET KEY 4 TO pdn_right    && Right Arrow
  SET KEY 272 TO pdn_quit   && Alt-Q To Quit
  DO CASE
  CASE mnu_pulldn = 0           && Escaped out of menu
    pdn_key = 0
  CASE mnu_pulldn = 1
    *********************************************************************
    * What To Do Next - Functions Menu
    *********************************************************************
    menu_title = "What To Do Next Menu"
    SETCOLOR(sys_warn)
    @ 01, 00, 15, 24 BOX("ÉÍ»º¼ÍȺ ")
    @ 03, 00 SAY "Ç" + REPLICATE("Ä", 23) + "¶"
    @ 05, 00 SAY "Ç" + REPLICATE("Ä", 23) + "¶"
    @ 08, 00 SAY "Ç" + REPLICATE("Ä", 23) + "¶"
    @ 12, 00 SAY "Ç" + REPLICATE("Ä", 23) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 02 PROMPT "What Do I Do Next   " MESSAGE "Review/Select Next Action Recommended/Required"
    @ 04, 02 PROMPT "Execute Action      " MESSAGE 'Execute The Current Action Item Then Return To "What Next" Screen'
    @ 06, 02 PROMPT "Choose Scenario     " MESSAGE 'Choose Operations Scenario That Will Accomplish Your Needs'
    @ 07, 02 PROMPT "Develop Scenario Seq" MESSAGE 'Develop Operations Scenarios & Associated Sequence Lists'
    @ 09, 02 PROMPT "Predecessors        " MESSAGE IIF(sys_appdev, "Select/", "") +;
                        "Review Predecessors To The Current Action Item"
    @ 10, 02 PROMPT "Successors          " MESSAGE IIF(sys_appdev, "Select/", "") +;
                        "Review Successors To The Current Action Item"
    @ 11, 02 PROMPT "Re-Sequence         " MESSAGE "Re-Sequence Action Items Base On Predecessor/Successor Relationships"
    @ 13, 02 PROMPT "Build Apps Next List" MESSAGE 'Develop "What Next" List For ' + sys_acrnym
    @ 14, 02 PROMPT "Update Next List    " MESSAGE "Analyze System Files & Documentation For Executable Action Items"
    MENU TO mnu_pd1
    IF mnu_pulldn = mnu_pdnew
      DO CASE
      CASE mnu_pd1 = 1
        pdn_actn = "Next Action Recommended/Required"
      CASE mnu_pd1 = 2 .AND. !sys_appbld .AND. pdn_actnx = "Next Action Recommended/Required"
        STORE .T. TO sys_exeact
      CASE mnu_pd1 = 3
        pdn_actn = "Choose Operations Scenario"
      CASE mnu_pd1 = 4
        pdn_actn = "Develop Operations Scenarios"
      CASE mnu_pd1 = 5 .AND. pdn_actnx = "Next Action Recommended/Required"
        STORE .T. TO sys_shpred
      CASE mnu_pd1 = 6 .AND. pdn_actnx = "Next Action Recommended/Required"
        STORE .T. TO sys_shsucc
      CASE mnu_pd1 = 7 .AND. sys_ccdev .AND. pdn_actnx = "Next Action Recommended/Required"
        STORE .T. TO sys_nxtrsq
      CASE mnu_pd1 = 8 .AND. sel_system .AND. pdn_actnx = "Next Action Recommended/Required"
        STORE .T. TO sys_appbld
      CASE mnu_pd1 = 9
        pdn_actn = "What Next Update Analysis"
      ENDCASE
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 2
    *********************************************************************
    * Setup Application To Process - Functions Menu
    *********************************************************************
    menu_title = "Application Systems SetUp Menu"
    SETCOLOR(sys_warn)
    @ 01, 00, 12, 22 BOX("ÉÍ»º¼ÍȺ ")
    @ 04, 00 SAY "Ç" + REPLICATE("Ä", 21) + "¶"
    @ 06, 00 SAY "Ç" + REPLICATE("Ä", 21) + "¶"
    @ 10, 00 SAY "Ç" + REPLICATE("Ä", 21) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 02 PROMPT "Select Application" MESSAGE "Select/Review/Edit Applications Systems Available For Clip CASE Processing"
    @ 03, 02 PROMPT "Create/Update App " MESSAGE "Create New Application -=OR=- Update Existing Application"
    @ 05, 02 PROMPT "Baseline Capture  " MESSAGE "Capture Baseline Values Throughout Selected Application"
    @ 07, 02 PROMPT "Compile/Link Info " MESSAGE "Information Required For Compiling & Linking Applications"
    @ 08, 02 PROMPT "Memory Map Display" MESSAGE "Review Memory Map Of Selected Application"
    @ 09, 02 PROMPT "Analyze Memory Map" MESSAGE "Analyze Selected Application's Memory Map"
    @ 11, 02 PROMPT "Function Libraries" MESSAGE "Enter/Edit Information On Function Libraries Used"
    MENU TO mnu_pd2
    IF mnu_pulldn = mnu_pdnew
      DO CASE
      CASE mnu_pd2 = 1
        pdn_actn = "Select Application"
      CASE mnu_pd2 = 2 .AND. cur_prg = "CC_APSEL"
        STORE .T. TO new_system
      CASE mnu_pd2 = 3
        pdn_actn = "Capture Baseline Values"
      CASE mnu_pd2 = 4
        pdn_actn = "Update Compile/Link Information"
      CASE mnu_pd2 = 5
        pdn_actn = "Overlay Management & Memory Map"
      CASE mnu_pd2 = 6
        pdn_actn = "Memory Map Analysis"
      CASE mnu_pd2 = 7
        pdn_actn = "Function Libraries"
      ENDCASE
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 3
    *********************************************************************
    * Ency - Functions Menu -- Displays and performs menu actions.
    *********************************************************************
    menu_title = "Data Encyclopedia Menu"
    SETCOLOR(sys_warn)
    @ 01, 06, 09, 33 BOX("ÉÍ»º¼ÍȺ ")
    @ 04, 06 SAY "Ç" + REPLICATE("Ä", 26) + "¶"
    @ 07, 06 SAY "Ç" + REPLICATE("Ä", 26) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 08 PROMPT "Data Encyclopedia      " MESSAGE "Review, Edit, & Process System Data Encyclopedia"
    @ 03, 08 PROMPT "System Data Bases      " MESSAGE "Review, Edit, & Process System Data Bases Master List"
    @ 05, 08 PROMPT "Update Dbf Structures  " MESSAGE "Incorporate Data Base & Data Element Structure Modifications"
    @ 06, 08 PROMPT "Inventory Data Bases   " MESSAGE "Inventory Data Bases & Incorporate Into Data Encyclopedia"
    @ 08, 08 PROMPT "Create B/L Data Element" MESSAGE "Create Mirror Image Data Eelement For Capture Of Baseline Information"
    MENU TO mnu_pd3
    IF mnu_pulldn = mnu_pdnew
      DO CASE
      CASE mnu_pd3 = 1
        pdn_actn = "Data Encyclopedia"
      CASE mnu_pd3 = 2
        pdn_actn = "System Data Bases Master List"
      CASE mnu_pd3 = 3
        pdn_actn = "Data Base Validation & Management"
      CASE mnu_pd3 = 4
        pdn_actn = "Inventory Application System Data Bases"
      CASE mnu_pd3 = 5 .AND. cur_prg = "CC_DENC"   && Create B/L Data Element
        STORE .T. TO bl_clone
      ENDCASE
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 4
    *********************************************************************
    * Document - Functions Menu -- Displays and performs menu actions.
    *********************************************************************
    menu_title = "Documentation & Context Sensitive Help"
    SETCOLOR(sys_warn)
    @ 01, 17, 09, 34 BOX("ÉÍ»º¼ÍȺ ")
    @ 03, 17 SAY "Ç" + REPLICATE("Ä", 16) + "¶"
    @ 07, 17 SAY "Ç" + REPLICATE("Ä", 16) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 19 PROMPT "Run Reports  " MESSAGE "Select & Publish Report With Desired Format, Features, And View Of Data"
    @ 04, 19 PROMPT "User's Manual" MESSAGE "Review, Edit, Format The " + M->sys_acrnym + " User's Manual Data"
    @ 05, 19 PROMPT "Tech Manual  " MESSAGE "Review, Edit, Format The " + M->sys_acrnym + " Technical Manual Data"
    @ 06, 19 PROMPT "Help Screens " MESSAGE "Review, Edit, Format " + M->sys_acrnym + " Help Screens Data"
    @ 08, 19 PROMPT "Requirements " MESSAGE M->sys_acrnym + " Functional Requirements Specifications"
    MENU TO mnu_pd4
    IF mnu_pulldn = mnu_pdnew
      DO CASE
      CASE mnu_pd4 = 1
        pdn_actn = "Reports Management & Generation"
      CASE mnu_pd4 = 2
        pdn_actn = "Edit User's Manual"
      CASE mnu_pd4 = 3
        pdn_actn = "Edit Technical Manual"
      CASE mnu_pd4 = 4
        pdn_actn = "Edit Help Screens"
      CASE mnu_pd4 = 5           && Functional Requirements Specifications
      ENDCASE
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 5
    *********************************************************************
    * Test - Functions Menu -- Displays and performs menu actions.
    *********************************************************************
    menu_title = "Unit & Integration Tests Menu"
    SETCOLOR(sys_warn)
    @ 01, 17, 09, 48 BOX("ÉÍ»º¼ÍȺ ")
    @ 05, 17 SAY "Ç" + REPLICATE("Ä", 30) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 19 PROMPT "Results & Status Of Tests    " MESSAGE "Enter Test Results, Review & Publish Status"
    @ 03, 19 PROMPT "Scenario Tests               " MESSAGE "Develop Scenario Tests Of Overall System Operations"
    @ 04, 19 PROMPT "Test Schedule & Assignments  " MESSAGE "Assign Alpha & Beta Test Responsibilities & Publish Test Schedule & Plan"
    @ 06, 19 PROMPT "System Performance Tests Plan" MESSAGE "Review, Edit, & Publish System Tests Plan"
    @ 07, 19 PROMPT "Integration Test Guide       " MESSAGE "Generate Integration Test Guide Based On Unit Tests & Source Code Analysis"
    @ 08, 19 PROMPT "Unit Test Procedures         " MESSAGE "Define, Review, & Edit Unit Tests For Individual Functional Modules"
    MENU TO mnu_pd5
    IF mnu_pulldn = mnu_pdnew
      DO CASE
      CASE mnu_pd5 = 1
        pdn_actn = "Results & Status Of Ops. Tests"
      CASE mnu_pd5 = 2
        pdn_actn = "System Scenario Tests Report"
      CASE mnu_pd5 = 3
        pdn_actn = "Test Schedule & Assignments"
      CASE mnu_pd5 = 4
        pdn_actn = "System Performance Tests Plan"
      CASE mnu_pd5 = 5
        pdn_actn = "Integration Test Guide"
      CASE mnu_pd5 = 6
        pdn_actn = "Unit Test Procedures"
      ENDCASE
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 6
    *********************************************************************
    * Source Code - Functions Menu -- Displays and performs menu actions.
    *********************************************************************
    menu_title = "Source Code Functions Menu"
    SETCOLOR(sys_warn)
    @ 01, 28, 13, 56 BOX("ÉÍ»º¼ÍȺ ")
    @ 03, 28 SAY "Ç" + REPLICATE("Ä", 27) + "¶"
    @ 05, 28 SAY "Ç" + REPLICATE("Ä", 27) + "¶"
    @ 09, 28 SAY "Ç" + REPLICATE("Ä", 27) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 30 PROMPT "Source Code Analysis    " MESSAGE "Analyze " + M->sys_acrnym + " Source Code To Update System Documentation"
    @ 04, 30 PROMPT "Cross References & Flow " MESSAGE "Perform Cross References & Program Flow Analysis On " + M->sys_acrnym + " Source Code"
    @ 06, 30 PROMPT "Generate Screen Template" MESSAGE "Generate Template Code For Screen As Defined & Designed"
    @ 07, 30 PROMPT "Screen Design & Layout  " MESSAGE "Design Screen Appearance - Data Placement, Text Constants, Etc."
    @ 08, 30 PROMPT "Screen Definition       " MESSAGE "Define Screen Contents - Data Elements Used, Filters, Indexes, Etc."
    @ 10, 30 PROMPT "Generate Report Template" MESSAGE "Generate Template Code For Report As Defined & Designed"
    @ 11, 30 PROMPT "Report Design & Layout  " MESSAGE "Design Report Appearance - Data Placement, Text Constants, Etc."
    @ 12, 30 PROMPT "Report Definition       " MESSAGE "Define Report Contents - Data Elements Used, Filters, Indexes, Etc."
    MENU TO mnu_pd6
    IF mnu_pulldn = mnu_pdnew
      DO CASE
      CASE mnu_pd6 = 1 .AND. !EMPTY(cur_prg)
        pdn_actn = "Source Code Analysis"
      CASE mnu_pd6 = 2 .AND. !EMPTY(cur_prg)
        pdn_actn = "System Architecture/Flow Analysis"
      CASE mnu_pd6 = 3 .AND. !EMPTY(cur_prg)          && Generate Screen Template
        DO no_op WITH .T.
      CASE mnu_pd6 = 4 .AND. !EMPTY(cur_prg)          && Screen Design & Layout
        DO no_op WITH .T.
      CASE mnu_pd6 = 5 .AND. !EMPTY(cur_prg)          && Screen Definition
        DO no_op WITH .T.
      CASE mnu_pd6 = 6 .AND. !EMPTY(cur_prg)          && Generate Report Template
        DO no_op WITH .T.
      CASE mnu_pd6 = 7 .AND. !EMPTY(cur_prg)          && Report Design & Layout
        DO no_op WITH .T.
      CASE mnu_pd6 = 8 .AND. !EMPTY(cur_prg)          && Report Definition
        DO no_op WITH .T.
      ENDCASE
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 7
    *********************************************************************
    * Data - Functions Menu -- Displays and performs menu actions.
    *********************************************************************
    menu_title = "Data Management Functions Menu"
    SETCOLOR(sys_warn)
    @ 01, 35, 14, 67 BOX("ÉÍ»º¼ÍȺ ")
    @ 05, 35 SAY "Ç" + REPLICATE("Ä", 31) + "¶"
    @ 08, 35 SAY "Ç" + REPLICATE("Ä", 31) + "¶"
    @ 11, 35 SAY "Ç" + REPLICATE("Ä", 31) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 37 PROMPT "Add New Record [Alt-A]      " MESSAGE "Append New Record To Data Base & Edit Same"
    @ 03, 37 PROMPT "Edit Record [Alt-E]         " MESSAGE "Begin Edit Of A Data Screen/Data Field"
    @ 04, 37 PROMPT "Delete/Undelete Record [Del]" MESSAGE "Toggles Record Deletion Flag -- Pack To Permanently Remove"
    @ 06, 37 PROMPT "View Criteria, Select       " MESSAGE "Establish Criteria (Select Filter) For Data To Be Viewed/Processed"
    @ 07, 37 PROMPT "Create View Criteria        " MESSAGE "Create/Edit/Delete Filters Used To Control Record View Criteria"
    @ 09, 37 PROMPT "Master Index, Select        " MESSAGE "Select Indexes To Control Viewing Order Of Records"
    @ 10, 37 PROMPT "Index Criteria, Define      " MESSAGE "Create/Edit/Delete Indexes Used To Control Viewing Order Of Records"
    @ 12, 37 PROMPT "Sort Data Base              " MESSAGE "Sort Data Base On Index #1 Key Fields"
    @ 13, 37 PROMPT "Pack Data Base              " MESSAGE "Permanently Removes Deleted Records From Data Base"
    MENU TO mnu_pdd
    IF mnu_pulldn = mnu_pdnew
      IF mnu_pdd = 5 .AND. cur_prg <> "SYS_FLTR"
        pdn_actn = "View Criteria Development & Management"
      ELSEIF mnu_pdd = 7 .AND. cur_prg <> "SYS_NTXS"
        pdn_actn = "Index Criteria Definition"
      ELSEIF mnu_pdd = 3 .AND. !EMPTY(cur_prg)
        recall_rec = DELETED()
        del_rec = !DELETED()
      ELSEIF !EMPTY(cur_prg)
        new_rec = IIF(mnu_pdd = 1, .T., .F.)    && Add New Record
        edit_rec = IIF(mnu_pdd = 2, .T., .F.)   && Edit Record
        fltr_selct = IIF(mnu_pdd = 4, .T., .F.) && Install View Criteria/Filter
        set_order = IIF(mnu_pdd = 6, .T., .F.)  && Index Selection
        sort_dbf = IIF(mnu_pdd = 8, .T., .F.)   && Sort Data Base
        pack_dbf = IIF(mnu_pdd = 9, .T., .F.)   && Pack Data Base
      ENDIF
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 8
  *********************************************************************
  * Locate-Functions Menu -- Displays and performs menu actions.
  *********************************************************************
    menu_title = "Data Location Functions Menu"
    SETCOLOR(sys_warn)
    @ 01, 46, 10, 69 BOX("ÉÍ»º¼ÍȺ ")
    @ 04, 46 SAY "Ç" + REPLICATE("Ä", 22) + "¶"
    @ 08, 46 SAY "Ç" + REPLICATE("Ä", 22) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 48 PROMPT "Key Word/Text Query" MESSAGE "Query Data Base On Key Words/Text Strings -- Any/All Data Elements"
    @ 03, 48 PROMPT "Locate Record      " MESSAGE "Query/Locate Record Based On Selected Data Element"
    @ 05, 48 PROMPT "Top Of Data Base   " MESSAGE "Go To First Record In Data Base -=- Same As: ^Home"
    @ 06, 48 PROMPT "Bottom Of Data Base" MESSAGE "Go To Last Record In Data Base -=- Same As: ^End"
    @ 07, 48 PROMPT "Go To Record #     " MESSAGE "Enter Desired Record Number"
    @ 09, 48 PROMPT "Redisplay Records  " MESSAGE "Redisplay Records In Current View/Index Sequential Order"
    MENU TO mnu_pdl
    IF mnu_pulldn = mnu_pdnew
      sf_selrec = IIF(mnu_pdl >= 3, .T., sf_selrec)
      DO CASE
      CASE mnu_pdl = 1 .AND. !EMPTY(cur_prg)   && Key Word/Text String Search
        str_sch = .T.
      CASE mnu_pdl = 2 .AND. !EMPTY(cur_prg)   && Fast Locate Record Finder
        fast_locate = .T.
      CASE mnu_pdl = 3 .AND. !EMPTY(cur_prg)   && Go To Top
        GOTO TOP
        BEEP("done")
      CASE mnu_pdl = 4 .AND. !EMPTY(cur_prg)   && Go To Bottom
        GOTO BOTTOM
        BEEP("done")
      CASE mnu_pdl = 5 .AND. !EMPTY(cur_prg)   && Go To Record #[Input]
        STORE RECNO() TO goto_no, gofrom_no
        SET CURSOR ON
        DO WHILE goto_no = gofrom_no .OR. (goto_no > RECCOUNT() .OR. goto_no < 1)
          CTR_STR(23, "Enter Record Number To Go To: ", sys_msgs)
          BEEP(IIF(goto_no > RECCOUNT() .OR. goto_no < 1, "error", "attn"))
          SETCOLOR(sys_color)
          @ 23, COL() GET goto_no PICTURE "9999999"
          READ
          IF goto_no > RECCOUNT() .OR. goto_no < 1
            CTR_STR(23, "Record Number Entered Is Out Of Range!  Range = 1 Through " + ALLTRIM(STR(RECCOUNT())), sys_msgs)
            INKEY(3)
          ENDIF
        ENDDO
        SET CURSOR OFF
        IF !EMPTY(DBFILTER())
          CTR_STR(23, "Filter Condition Is Engaged -- Seeking Desired Record!", sys_msgs)
          BEEP("attn")
          DO WHILE RECNO() <> goto_no
            SKIP IIF(goto_no < gofrom_no, - 1, 1)
            SETCOLOR(sys_hdhi)
            @ 24, 71 SAY STR(RECNO(),5) PICTURE "99999"
            IF BOF() .OR. EOF()
              CTR_STR(23, "Record Number Entered Does Not Meet Current Filter Contion", sys_msgs)
              BEEP("error")
              INKEY(3)
              goto_no = gofrom_no
            ENDIF
          ENDDO
        ENDIF
        GOTO goto_no
        BEEP("done")
      CASE mnu_pdl = 6   && Redisplay With New Sequence
        IF !EMPTY(DBFILTER()) .OR. !EMPTY(INDEXKEY(0))
          nav_offset = .T.
        ELSE
          CTR_STR(23, "Display Sequence Is Correct -- No View Or Index Criteria Selected", sys_msgs)
          INKEY(3)
        ENDIF
      ENDCASE
      pdn_key = 0
    ENDIF
  CASE mnu_pulldn = 9
    *********************************************************************
    * Tags-Functions Menu -- Displays and performs menu actions.
    *********************************************************************
    menu_title = "Record Tagging Functions Menu"
    SETCOLOR(sys_warn)
    @ 01, 53, 13, 78 BOX("ÉÍ»º¼ÍȺ ")
    @ 03, 53 SAY "Ç" + REPLICATE("Ä", 24) + "¶"
    @ 05, 53 SAY "Ç" + REPLICATE("Ä", 24) + "¶"
    @ 07, 53 SAY "Ç" + REPLICATE("Ä", 24) + "¶"
    @ 10, 53 SAY "Ç" + REPLICATE("Ä", 24) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 55 PROMPT "Toggle Tag ON/OFF    " MESSAGE "Toggles Tag To Opposite Current Condition"
    @ 04, 55 PROMPT "Go To Next Tag       " MESSAGE "Go To And View/Edit Next Tagged Record In Data Base"
    @ 06, 55 PROMPT IIF("!EMPTY(tag)" $ DBFILTER(), "View All Records     ",;
      "View Tagged Records  ") MESSAGE IIF("!EMPTY(tag)" $ DBFILTER(),;
      "Set Filter To View All Tagged & Untagged Records",;
      "Set Filter To View Only Those Records That Have Been Tagged")
    @ 08, 55 PROMPT "Tag All              " MESSAGE "Tag All Records Currently Being Viewed"
    @ 09, 55 PROMPT "UnTag All            " MESSAGE "UnTag All Records -- Should Be Done Prior To New Tagging Operations!"
    @ 11, 55 PROMPT "Copy Tagged Records  " MESSAGE "Copy All Tagged Records To A Temporary Data Base"
    @ 12, 55 PROMPT "Delete Tagged Records" MESSAGE "Mark All Tagged Records For Deletion -- Pack Data Base To Permanently Remove"
    MENU TO mnu_pdt
    IF mnu_pulldn = mnu_pdnew .AND. !EMPTY(cur_prg)
      IF !tag_work
        DECLARE fname[FCOUNT()]
        AFIELDS(fname)
        tag_fld = ASCAN(fname, "TAG")
        IF tag_fld > 0
          PUBLIC tag_all, tag_clear, tag_copy, tag_count, tag_del, tag_fltr
          STORE .T. TO tag_work
          STORE 0 TO tag_count
        ELSE
          mnu_pdt = 0
          DO no_op
        ENDIF
        RELEASE fname
      ENDIF
      IF mnu_pdt = 1 .AND. tag_work   && Toggle Tag ON/OFF
        IF EMPTY(tag)
          REPLACE tag WITH "T"
        ELSE
          REPLACE tag WITH " "
        ENDIF
        sf_selrec = .T.
        SKIP
      ENDIF
      tag_seek = IIF(mnu_pdt = 2 .AND. tag_work, .T., .F.) && Go To Next Tagged Record
      tag_fltr = IIF(mnu_pdt = 3 .AND. tag_work, .T., .F.) && View Tagged Records
      tag_all = IIF(mnu_pdt = 4 .AND. tag_work, .T., .F.)  && Tag All Records In View
      tag_clear = IIF(mnu_pdt = 5 .AND. tag_work, .T., .F.)&& UnTag All Tags
      tag_copy = IIF(mnu_pdt = 6 .AND. tag_work, .T., .F.) && Copy All Tagged Records
      tag_del = IIF(mnu_pdt = 7 .AND. tag_work, .T., .F.)  && Delete All Tagged Records
      pdn_key = 0
    ELSEIF EMPTY(cur_prg)
      mnu_pulldn = IIF(mnu_pulldn = mnu_bfq, mnu_pulldn - 1, mnu_bfq)
    ENDIF
  *********************************************************************
  * System - Functions Menu -- Displays and performs menu actions.
  *********************************************************************
  CASE mnu_pulldn = 10
    menu_title = "System Control Functions Menu"
    SETCOLOR(sys_warn)
    @ 01, 58, 09, 79 BOX("ÉÍ»º¼ÍȺ ")
    @ 03, 58 SAY "Ç" + REPLICATE("Ä", 20) + "¶"
    @ 05, 58 SAY "Ç" + REPLICATE("Ä", 20) + "¶"
    @ 07, 58 SAY "Ç" + REPLICATE("Ä", 20) + "¶"
    SETCOLOR(sys_menu)
    @ 02, 60 PROMPT "Auto Pilot - Quit" MESSAGE "Run System Clean-Up On Auto Pilot, Then Quit To DOS"
    @ 04, 60 PROMPT "User Preferences " MESSAGE "Select System Screen Colors, Defaults & Operating Parameters"
    @ 06, 60 PROMPT "Rolodex          " MESSAGE "Add/Review/Edit Personnel & Organizations"
    @ 08, 60 PROMPT "Quit To DOS      " MESSAGE "Quit System -- Return To DOS"
    MENU TO mnu_pds
    IF mnu_pulldn = mnu_pdnew
      DO CASE
      CASE mnu_pds = 1
        STORE "Quit To DOS" TO pdn_actn, pdn_actnx
        STORE .T. TO sys_autop, return_to
      CASE mnu_pds = 2
        pdn_actn = "System User Preferences"
      CASE mnu_pds = 3
        pdn_actn = "System Rolodex"
      CASE mnu_pds = 4
        STORE "Quit To DOS" TO pdn_actn, pdn_actnx
        return_to = .T.
      ENDCASE
      pdn_key = 0
    ENDIF
  ENDCASE
  IF !return_to .AND. !sys_autop
    RESTORE SCREEN FROM box_mnu
  ENDIF  
ENDDO
SETCOLOR(sys_msgs)
STORE "" TO menu_title
SET KEY 22 TO        && Ins Key
SET KEY 19 TO        && Left Arrow
SET KEY 4 TO         && Right Arrow
SET KEY 272 TO       && Alt-Q
RETURN

PROCEDURE help_do
  STORE .T. TO helping
  KEYBOARD CHR(27)
RETURN

PROCEDURE pdn_ins         && Ins Key Definition For P/D Menus
KEYBOARD CHR(13)
RETURN

PROCEDURE pdn_left        && Left Arrow Key Definition For P/D
mnu_pulldn = IIF(mnu_pulldn > 1, mnu_pulldn - 1, mnu_pdmax)
KEYBOARD CHR(13)
RETURN

PROCEDURE pdn_right       && Right Arrow Key Definition For P/D
mnu_pulldn = IIF(mnu_pulldn < mnu_pdmax, mnu_pulldn + 1, 1)
KEYBOARD CHR(13)
RETURN

PROCEDURE pdn_quit        && Alt-Q Key Definition For P/D Menus
mnu_pulldn = mnu_bfq
return_to = .T.
f_key = 0
KEYBOARD CHR(13)
RETURN