10 ON ERROR GOTO 440
20 CLS:LOCATE 1,38:PRINT "Copyright (C) 1989 by Frederick W. Kantor."
30 LOCATE 2,60:PRINT "All rights reserved."
40 LOCATE 1,1:PRINT "FWKC17D(tm) Deletion Program"
50 LOCATE 2,1:PRINT "Version 1.00"
60 LOCATE 4,1:PRINT "Your use of this program is at solely your own risk:"
70 PRINT "Please have proper backup(s): THIS IS A DELETION PROGRAM."
80 LOCATE 8,27:PRINT "C A V E A T   O P E R A T O R"
90 LOCATE 17,9:PRINT "input file: MULTIS  (annotated with 'd'(s) in column 17 (decimal))"
100 LOCATE 11,1:PRINT "This is a special-purpose program; it's in interpretive 'basic' and/or the"
110 PRINT "like, and (mostly) spread out for relatively easy reading and modification."
120 PRINT "It's its own DOCs. It reads a special annotated file MULTIS, looking for a"
130 PRINT "lower_case 'd' in column 17 (decimal) of each line with a file for deletion,"
140 PRINT "deletes specifically that file, and logs each (sans 'd') in DELETED.LOG."
150 LOCATE 19,1
160 OPEN "multis" FOR INPUT AS 1
170 OPEN "deleted.log" FOR APPEND AS 2
180 WHILE NOT EOF(1)
190 LINE INPUT #1,A$
200 IF MID$(A$,17,1)<>"d" THEN GOTO 340
210 MID$(A$,17,1)=" "
220 P$=MID$(A$,44)
230 GOSUB 410
240 S1$=P$
250 P$=MID$(A$,18,12)
260 GOSUB 410
270 S$=S1$+"\"+P$
280 IF S$=" " OR S$="  " THEN GOTO 340
290 OPEN S$ AS 3 LEN=1:CLOSE 3:KILL S$
300 PRINT #2,A$
310 PRINT A$ STRING$(79-LEN(A$)," ")
320 PRINT S$ STRING$(79-LEN(S$)," ")
330 LOCATE 19,1
340 WEND
350 PRINT STRING$(79," ")
360 PRINT STRING$(79," ")
370 LOCATE 19,1
380 PRINT "done"
390 CLOSE
400 SYSTEM
410 IF RIGHT$(P$,1)=" " AND LEN(P$)>1 THEN P$=LEFT$(P$,LEN(P$)-1):GOTO 410
420 IF LEFT$(P$,1)=" " AND LEN(P$)>1 THEN P$=MID$(P$,2):GOTO 420
430 RETURN
440 IF ERL= 160 AND ERR=53 THEN LOCATE 17,1:PRINT ">-->>":LOCATE 19,1:PRINT "i need that file...  i quit.":RESUME 390
450 RESUME 390