10 ON ERROR GOTO 770
20 DIM SL$(200):CLS
30 PRINT "(C)Copyright Frederick W. Kantor 1991. All rights reserved."
40 PRINT "For use with FWKCS(TM) Contents_Signature System, Version 1.12."
50 PRINT "Your use of this program is at solely your own risk."
60 PRINT STRING$(24,"-") " C A V E A T   O P E R A T O R " STRING$(24,"-")
70 PRINT
80 INPUT "list of filenames (with or without descriptions) = ",INLIST$
90 PRINT:PRINT"format is bit_mapped, as the sum of three format_options:"
100 PRINT" 1  date format (0,1)"
110 PRINT" 2  cs_line letter_case (0,2)"
120 PRINT" 4  suppress cs_line in graphic mode (0,4):"
130 U0$=". YEAR-MO-DY, ":U1$=". MO-DY-YR, ":V0$=" UPPER_CASE":V1$="lower_case"
140 W1$=", suppress cs_line in graphics mode":PRINT
150 PRINT"0" U0$ V0$:PRINT"1" U1$ V0$:PRINT"2" U0$ V1$:PRINT"3" U1$ V1$
160 PRINT"4" U0$ V0$ W1$:PRINT"5" U1$ V0$ W1$
170 PRINT"6" U0$ V1$ W1$:PRINT"7" U1$ V1$ W1$:PRINT
180 PRINT"press one key, 0...7, without <ENTER>; to quit, press q"
190 T$=INPUT$(1):IF T$="Q" OR T$="q" THEN CLOSE:SYSTEM
200 IF T$<"0" OR T$>"7" THEN GOTO 190
210 LOCALMAC=0:OPEN "LOCALMAC" AS 1 LEN=1:LEN1=LOF(1):CLOSE 1:IF LEN1=0 THEN KILL "LOCALMAC":GOTO 230
220 LOCALMAC=1
230 OPEN INLIST$ FOR INPUT AS 1:I=0:FIRST=1
240 OPEN "WORKBAT.BAT" FOR OUTPUT AS 3:PRINT #3,"@echo off"
250 IF EOF(1) THEN GOTO 350
260 LINE INPUT #1,A$:IF LEN(A$)=0 THEN GOTO 250
270 IF (LEFT$(A$,1)<>" " AND FIRST=0) THEN GOSUB 520
280 FIRST=0:GOSUB 500:IF LEFT$(A$,1)=" " THEN GOTO 250
290 F$=LEFT$(A$,12):N=INSTR(F$,"."):M=INSTR(F$," "):IF M=0 THEN M=LEN(F$)+1
300 GOSUB 720
310 IF N=0 THEN N=M
320 IF N<=1 THEN GOTO 350
330 G$=LEFT$(A$,N-1)+"."+"DSC"
340 GOTO 250
350 IF G$>"" AND I>0 THEN GOSUB 520
360 PRINT #3,"echo " STRING$(64,"-") " >> process.rpt"
370 PRINT #3,"echo " STRING$(72,"~")
380 PRINT #3,"if exist PCBFAIL.TXT del PCBFAIL.TXT > nul"
390 PRINT #3,"if exist PCBPASS.TXT del PCBPASS.TXT > nul":CLOSE:S3$=STRING$(30," ")
400 S78$=STRING$(78," "):LOCATE 8,1:FOR IC=1 TO 16:PRINT S78$:NEXT:PRINT S78$;
410 LOCATE 9,1:PRINT"created WORKBAT.BAT " DATE$ " " TIME$ S3$
420 PRINT:PRINT "number of file descriptions found (with files) =" FOUND
430 PRINT:PRINT "number of file descriptions, defective or no file =" MISSED
440 CLOSE:OPEN "MISSING.LST" AS 1 LEN=1:LEN1=LOF(1):CLOSE
450 IF LEN1<=3 THEN KILL "MISSING.LST"
460 SYSTEM
470 PRINT "nothing to do":GOTO 490
480 PRINT:PRINT "too many lines"
490 PRINT:PRINT "i quit":PRINT:CLOSE:SYSTEM
500 I=I+1:IF I>200 THEN GOTO 480
510 SL$(I)=A$:RETURN
520 IF ((INSTR(SL$(I),"CS|")>0 OR INSTR(SL$(I),"cs|")>0) AND I>1) THEN I=I-1
530 IF MISSING=0 THEN GOTO 560
540 OPEN "MISSING.LST" FOR APPEND AS 2:FOR J=1 TO I:PRINT #2,SL$(J):NEXT
550 CLOSE 2:I=0:MISSED=MISSED+1:MISSING=0:GOTO 710
560 OPEN G$ FOR OUTPUT AS 2:FOR J=1 TO I:PRINT #2,SL$(J):NEXT:CLOSE 2:I=0
570 FOUND=FOUND+1
580 PRINT #3,"echo " STRING$(72,"~")
590 PRINT #3, "echo -"
600 PRINT #3, "echo - process " F$ " and description " G$
610 PRINT #3, "echo -"
620 IF LOCALMAC=1 GOTO 640
630 H$="FWKCS "+F$+" UPLOAD "+G$+" /a5[cdef]g1,"+T$:GOTO 650
640 H$="FWKCS "+F$+" UPLOAD "+G$+" /a5[+localmac]g1,"+T$
650 PRINT #3,H$:PRINT #3,"echo " STRING$(64,"~") " >> process.rpt"
660 PRINT #3,"if exist PCBPASS.TXT type PCBPASS.TXT >> process.rpt"
670 PRINT #3,"if exist PCBFAIL.TXT type PCBFAIL.TXT >> process.rpt"
680 PRINT #3,"if exist PCBFAIL.TXT ren " G$ " *.rej"
690 PRINT #3,"if exist " G$ " type " G$ " >> JOINLIST"
700 PRINT #3,"if exist " G$ " del " G$ " > nul"
710 RETURN
720 IF RIGHT$(F$,1)=" " THEN F$=LEFT$(F$,LEN(F$)-1):GOTO 720
730 MISSING=0:OPEN F$ AS 2 LEN=1:LEN2=LOF(2):CLOSE 2:IF LEN2>0 THEN GOTO 760
740 KILL F$
750 MISSING=1
760 RETURN
770 IF (ERR=64)AND(ERL=730) THEN RESUME 750
780 ON ERROR GOTO 0