Comment
=======================================================

Color Menu
This menu displays color combinations.

On monochrome monitors and color monitors set in BW mode, MarxMenu
will map the colors in such a way as to maintain a high degree of
compatibility between mono and color systems. The suggested colors
are the most safe generic colors to choose on a non-color screen.
These are the colors the rest are mapped to.

This menu will let you see what all the colors look like on your
screen. If you are running a composite monitor, or and LCD screen,
you might want to use the command "MODE BW80" in you AUTOEXEC.BAT
file. This will put MarxMenu (and many other programs) into the
black and white mode.

Note on monochrome screens the color BLUE becomes underline.

=======================================================
EndComment

ClearScreen

Var ForeColor BackColor St

Procedure PrintColor
   TextColor ForeColor BackColor
   Write '  '
   if ForeColor < 10 then Write ' '
   Write ForeColor
   Write Char(4)
   Write BackColor '  '
EndProc

Procedure GotoPrintColor
   GotoXY((BackColor * 8 + 1),ForeColor + 2)
   PrintColor
EndProc

Procedure SuggestColor
   PrintColor
   TextColor Grey Black
   Write ' '
EndProc

if not ColorScreen
   GotoXY(5,3)
   TextColor Grey Black
   Write 'Suggested Colors: '
   ForeColor = Grey
   BackColor = Black
   SuggestColor
   ForeColor = White
   BackColor = Black
   SuggestColor
   ForeColor = Black
   BackColor = Grey
   SuggestColor
   ForeColor = White
   BackColor = Grey
   SuggestColor
   if VideoMode and $FF = 7
      ForeColor = Blue
      BackColor = Black
      SuggestColor
      ForeColor = LBlue
      BackColor = Black
      SuggestColor
   endif
endif

Forecolor = 0
BackColor = 0

SingleLineBox
BoxBorderColor Green Black
BoxInsideColor Black Black
DrawBox 5 4 69 20

While Forecolor < 16
    While BackColor < 8
       GotoPrintColor
       BackColor = BackColor + 1
    EndWhile
    BackColor = 0
    ForeColor = ForeColor + 1
EndWhile

While not KbdReady
EndWhile
St = ReadKey