Variable      FColor,1
Variable      BColor,1
Variable      CAttr,1
Variable      Use2Flop,1,"Y"
Variable      UseHD,1,"N"
Variable      Source,79,"A:"
Variable      Target,79,"B:"
Variable      WorkDisk,79
Variable      DelWork,1,"N"
Variable      Work,79
Variable      Msg,80
Variable      InChar,1
?Color        FColor,BColor,CAttr       ;save curr colors
Clear                                   ;clear the screen
WriteLine     "This PowerBatch program will produce an evaluation copy of PowerBatch for you"
WriteLine     "to give to a friend or associate. If you have 2 floppy disk drives, both will"
WriteLine     "be utilized to make the copy. If you have only one drive, enter A for both"
WriteLine     "source and destination and the files will be copied to your hard disk and from"
WriteLine     "your hard disk to a new disk in your floppy drive."
WriteLine     ""
Write         "Enter the source drive letter containing the PowerBatch files "
ReadUpKey     Source
WriteLine     ""
Write         "Enter the source directory name "
ReadStr       Work
WriteLine     ""
Write         "Enter the target drive letter to receive the PowerBatch files "
ReadUpKey     Target
WriteLine     ""
Compare       Source,Target,2Drives,2Drives
Concat        Source,":"              ;ie A:
Concat        Source,Work             ;A:\Work...
Write         "Enter the Drive letter to be used as a work drive "
ReadUpKey     WorkDisk
WriteLine     ""
Concat		  WorkDisk,":"            ;use this as a work dir
Concat        Work,"Copy PowerBatch from ",Source
Concat		  Work," to "
Concat		  Work,Target
Concat		  Work,": using work drive "
Concat		  Work,WorkDisk
Concat		  Work," [Y/N] "
Write		  Work
ReadUpKey	  InChar
WriteLine	  ""
Compare 	  InChar,"Y",Finis,Finis
Concat		  WorkDisk,"\{PB$WRK}"   ;use this as a work dir
?DirExist     WorkDisk,WorkExist      ;does it exist
SetVar        DelWork,"Y"             ;delete it when were done
Write         "Making directory "
WriteLine     WorkDisk
MKDIR         WorkDisk                ;create the work dir

Label         WorkExist
Concat        Work,Source," "         ;cmd line parms are delimited by spaces
Concat        Work,WorkDisk
WriteLine     "Copy PowerBatch files to work directory"
MoveSub       Work                    ;execute subroutine
Compare       ErrorLevel,0,Finis
Concat        Msg,"Remove PowerBatch disk from ",Source
Concat        Msg," and replace with blank disk. Press Y when ready."
ReadYN        Msg,InChar
WriteLine     ""
Concat        Work,WorkDisk," "      ;build cmd line for copy
Concat        Work,Target
Concat        Work,":"
MoveSub       Work                    ;now copy from work disk to floppy
Compare       ErrorLevel,0,Finis
WriteLine     ""
Write         "The disk in "
Write         Target
WriteLine     " is now a copy of PowerBatch."
WriteLine     "You may remove and label the disk while I clean up the work disk."
WriteLine     ""
GoTo          CopyExit

Label         2Drives
Concat        Source,":"              ;add : to drive letter
Concat        Target,":"
Concat        Source,Work             ;add the dir to drive on source
Concat		  Work,"Copy PowerBatch from ",Source
Concat		  Work," to "
Concat		  Work,Target
Concat		  Work," [Y/N] "
Write		  Work
ReadUpKey	  InChar
WriteLine	  ""
Compare 	  InChar,"Y",Finis,Finis
Concat        Work,Source," "         ;build entire command in work
Concat        Work,Target
MoveSub       Work
Compare       ErrorLevel,0,Finis
Write         "The disk in "
Write         Target
WriteLine     " is now a copy of PowerBatch."
WriteLine     ""
GoTo          Finis

Label         CopyExit
WriteLine     "Delete files from work disk"
Concat        Work,WorkDisk,"\README.1ST"
Erase         Work
Concat        Work,WorkDisk,"\PBINSTAL.EXE"
Erase         Work
Concat        Work,WorkDisk,"\POWERMAK.EXE"
Erase         Work
Concat        Work,WorkDisk,"\SMLMODEL.MDL"
Erase         Work
Concat		  Work,WorkDisk,"\KEYID.EXE"
Erase		  Work
Concat        Work,WorkDisk,"\POWERBAT.DOC"
Erase         Work
Concat        Work,WorkDisk,"\DOSEX1.BAT"
Erase         Work
Concat        Work,WorkDisk,"\*.PWR"
Erase         Work
Concat        Work,WorkDisk,"\DELETEPB.EXE"
Erase         Work
Concat        Work,WorkDisk,"\*.FRM"
Erase         Work
Concat        Work,WorkDisk,"\VENDOR.DOC"
Erase         Work
Concat        Work,WorkDisk,"\SYSOP.DOC"
Erase         Work
Compare       DelWork,"Y",Finis,Finis
WriteLine     "Remove work directory"
RMDIR         WorkDisk

Label         Finis