comment {

These LSystems are designed to be run from FRACTINT.  No compilation is
necessary, just copy this file to the FRACTINT directory and run FRACTINT.

The following nonperiodic tilings were written by Herb Savage based on the
book "Penrose Tiles to Trapdoor Ciphers" by Martin Gardner.  The Penrose
tilings are based on Roger Penrose's rhombuses.

}

Penrose1 {
  Angle 10
  Axiom +WF--XF---YF--ZF
  W=YF++ZF----XF[-YF----WF]++
  X=+YF--ZF[---WF--XF]+
  Y=-WF++XF[+++YF++ZF]-
  Z=--YF++++WF[+ZF++++XF]--XF
  F=
}

ForcedPenrose1 {
;; Uses color to show the edge matching rules to force nonperiodicy
  Angle 10
  Axiom +WC2FC4F--XC3FC2F---YC2FC3F--ZC4FC2F
  W=YC2FC3F++ZC4FC2F----XC3FC2F[-YC2FC3F----WC2FC4F]++
  X=+YC2FC3F--ZC4FC2F[---WC2FC4F--XC3FC2F]+
  Y=-WC2FC4F++XC3FC2F[+++YC2FC3F++ZC4FC2F]-
  Z=--YC2FC3F++++WC2FC4F[+ZC4FC2F++++XC3FC2F]--XC3FC2F
  F=
  C=
}

ColorPenrose1 {
;; Uses color to show similar lines
  Angle 10
  Axiom +WC2F--XC4F---YC4F--ZC2F
  W=YC4F++ZC2F----XC4F[-YC4F----WC2F]++
  X=+YC4F--ZC2F[---WC2F--XC4F]+
  Y=-WC2F++XC4F[+++YC4F++ZC2F]-
  Z=--YC4F++++WC2F[+ZC2F++++XC4F]--XC4F
  F=
  C=
}

Penrose2 {
  Angle 10
  Axiom ++ZF----XF-YF----WF
  W=YF++ZF----XF[-YF----WF]++
  X=+YF--ZF[---WF--XF]+
  Y=-WF++XF[+++YF++ZF]-
  Z=--YF++++WF[+ZF++++XF]--XF
  F=
}

Penrose3 {
  Angle 10
  Axiom [X]++[X]++[X]++[X]++[X]
  W=YF++ZF----XF[-YF----WF]++
  X=+YF--ZF[---WF--XF]+
  Y=-WF++XF[+++YF++ZF]-
  Z=--YF++++WF[+ZF++++XF]--XF
  F=
}

Penrose4 {
  Angle 10
  Axiom [Y]++[Y]++[Y]++[Y]++[Y]
  W=YF++ZF----XF[-YF----WF]++
  X=+YF--ZF[---WF--XF]+
  Y=-WF++XF[+++YF++ZF]-
  Z=--YF++++WF[+ZF++++XF]--XF
  F=
}

DoublePenrose {
;; This is Penrose3 and Penrose4 superimposed
  Angle 10
  Axiom [X][Y]++[X][Y]++[X][Y]++[X][Y]++[X][Y]
  W=YF++ZF----XF[-YF----WF]++
  X=+YF--ZF[---WF--XF]+
  Y=-WF++XF[+++YF++ZF]-
  Z=--YF++++WF[+ZF++++XF]--XF
  F=
}

Sphinx {
;; This is an example of a "reptile"
  Angle 6
  Axiom X
  X=+FF-YFF+FF--FFF|X|F--YFFFYFFF|
  Y=-FF+XFF-FF++FFF|Y|F++XFFFXFFF|
  F=GG
  G=GG
}