REM 			THIS IS THE PROGRAM 'ELTPOD'
REM 		WRITTEN BY CAPT R.A.GREGOIRE CAP PAWG GROUP 30
REM
PRINT "THIS PROGRAM CALCULATES THE VARIOUS ELT SEARCH POD'S FOR"
PRINT "VARIOUS SEARCH ALTITUDES AND TRACK SPACINGS."
PRINT "THERE ARE 4 TABLES, ONE FOR EACH TYPE OF TERRAIN"
PRINT
DIM A(5)
PRINT
INPUT "DO YOU WANT THE 'STANDARD' LISTING OR THE 'CUSTOM' ONE";K$
LET C=0
IF LEFT$(K$,1)="C" THEN GOTO 50
10 LET C=C+1
READ A1,A2,X1,S1,S2
DATA 0,1500,100,.5,2.5
DATA 0,5000,100,.5,2.5
DATA 0,10000,200,1,5
DATA 0,25000,500,5,25
GOTO 70
50 INPUT "WHAT IS THE LOWEST ALTITUDES TO BE CONSIDERED (FEET AGL)";A1
INPUT "WHAT IS THE HIGHEST ALTITUDES TO BE CONSIDERED (FEET AGL)";A2
INPUT "WHAT IS THE THE ALTITUDE INCREMENTS (FEET)";X1
INPUT "WHAT IS THE SMALLEST TRACK SPACING (IN NAUTICAL MILES)";S1
INPUT "WHAT IS THE LARGEST TRACK SPACING (IN NAUTICAL MILES)";S2
70 PRINT CHR$(12):PRINT:PRINT:PRINT:PRINT CHR$(12)
PRINT:PRINT
PRINT"TABLE OF ELT POD'S FOR VARIOUS SEARCH ALTITUDES AND TRACK SPACINGS"
LET T=1.0
PRINT
PRINT TAB(14);" THIS TABLE IS FOR ELT SEARCH OF OPEN TERRAIN"
GOSUB 80
REM
LET T=.5
PRINT:PRINT
PRINT TAB(13);" THIS TABLE IS FOR ELT SEARCH OF MODERATE COVER"
GOSUB 80
REM
LET T=.25
PRINT:PRINT
PRINT TAB(15);" THIS TABLE IS FOR ELT SEARCH OF HEAVY COVER"
GOSUB 80
REM
LET T=.15
PRINT:PRINT
PRINT TAB(14);" THIS TABLE IS FOR ELT SEARCH OF ROCKY TERRAIN"
GOSUB 80
PRINT CHR$(12)
IF C>0 AND C<4 THEN GOTO 10
STOP
REM
80 PRINT
90 PRINT "ALTITUDE";TAB(12);"SPACING";TAB(24);"SPACING";TAB(36);\
         "SPACING";TAB(48);"SPACING";TAB(60);"SPACING"
LET SA=(S2-S1)/4
PRINT "  (FT)";TAB(14);S1;"NM";TAB(26);S1+SA;"NM";TAB(38);S1+2*SA;\
      "NM";TAB(50);S1+3*SA;"NM";TAB(62);S2;"NM"
PRINT " ------";TAB(13);"------";TAB(25);"------";TAB(37);"------";\
      TAB(49);"------";TAB(60);"------"
PRINT
FOR H=A1 TO A2 STEP X1
REM H=ALTITUDE IN FEET, W=SWEEP WIDTH, S=TRACK SPACING, T=TERRAIN FACTOR
W=T*1.144*SQR(H)/4
S=S1
FOR Q=1 TO 5
A(Q)=INT(1000*(1-EXP(-W/S))+.5)/10
S=S+(S2-S1)/4
NEXT Q
PRINT " ";H;TAB(14);A(1);"%";TAB(26);A(2);"%";TAB(38);A(3);"%";\
      TAB(50);A(4);"%";TAB(62);A(5);"%"
NEXT H
PRINT CHR$(12):RETURN
END
